build.gradle

import net.ltgt.gradle.errorprone.CheckSeverity

buildscript {
    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
        gradlePluginPortal() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }
    dependencies {
        classpath 'com.palantir.jakartapackagealignment:jakarta-package-alignment:0.5.0'
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.4.0'
        classpath 'com.palantir.baseline:gradle-baseline-java:4.59.0'
        classpath 'com.palantir.gradle.consistentversions:gradle-consistent-versions:1.16.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:0.12.2'
        classpath 'org.unbroken-dome.gradle-plugins:gradle-testsets-plugin:2.2.1'
        classpath 'com.palantir.gradle.conjure:gradle-conjure:4.15.0'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:2.33.0'
    }
}

plugins {
    id 'com.palantir.git-version' version '0.12.2'
}

apply plugin: 'com.palantir.external-publish'
apply plugin: 'com.palantir.baseline'
apply plugin: 'com.palantir.git-version'
apply plugin: 'com.palantir.consistent-versions'

version gitVersion()

allprojects {
    apply plugin: 'com.palantir.java-format'
    apply plugin: 'com.palantir.jakarta-package-alignment'
    version rootProject.version
    group 'com.palantir.docker.compose'

    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'com.palantir.java-format'
    apply plugin: 'com.palantir.external-publish-jar'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    dependencies {
        annotationProcessor 'org.immutables:value'
        compileOnly 'org.immutables:value::annotations'
    }

    tasks.withType(JavaCompile).configureEach {
        options.errorprone {

            check("CatchBlockLogException", CheckSeverity.OFF)
            check("PreconditionsConstantMessage", CheckSeverity.OFF)
            check("PreferSafeLoggableExceptions", CheckSeverity.OFF)
            check("PreferSafeLoggingPreconditions", CheckSeverity.OFF)
            check("Slf4jConstantLogMessage", CheckSeverity.OFF)
            check("ValidateConstantMessage", CheckSeverity.OFF)
            check("PreconditionsConstantMessage", CheckSeverity.OFF)
            check('Slf4jLogsafeArgs', CheckSeverity.OFF)

        }
    }
}