build.gradle

plugins {
    id "java"
    id "groovy"
    id 'maven-publish'
    id 'java-library'
    id 'signing'
    id 'io.codearte.nexus-staging' version '0.20.0'
}

sourceCompatibility = '1.8'
targetCompatibility = '1.8'



dependencies {
    compile "com.google.code.findbugs:jsr305:3.0.2"
    testCompile "org.spockframework:spock-core:1.2-groovy-2.5"
}

repositories {
    mavenCentral()
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    classifier = 'sources'
}

task javadocJar(type: Jar) {
    from javadoc
    classifier = 'javadoc'
}


def isReleaseVersion = version.endsWith('SNAPSHOT')

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = group
            artifactId = artifactId
            version = version
            from components.java
            artifact sourcesJar
            artifact javadocJar

            pom {
                name = project.name
                description = 'Fluently build xpath expressions in java'
                url = 'https://github.com/pchudzik/fluentxpath'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }
                developers {
                    developer {
                        name = 'Paweł Chudzik'
                        email = 'pawel.chudzik@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com:pchudzik/fluentxpath.git'
                    developerConnection = 'scm:git:ssh://github.com:pchudzik/fluentxpath.git'
                    url = 'https://github.com/pchudzik/fluentxpath'
                }
            }

            repositories {
                maven {
                    def releases = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
                    def snapshots = 'https://oss.sonatype.org/content/repositories/snapshots'
                    url = isReleaseVersion ? snapshots : releases
                    credentials {
                        username = System.getProperty('nexusUsername')
                        password = System.getProperty('nexusPassword')
                    }
                }
            }
        }
    }
}

nexusStaging {
    username = System.getProperty('nexusUsername')
    password = System.getProperty('nexusPassword')
}

signing {
    useGpgCmd()
    sign publishing.publications.mavenJava
}


javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}