build.gradle

plugins {
    id 'com.gradleup.shadow' version '8.3.5'
    id 'com.github.breadmoirai.github-release' version '2.5.2'
    id 'com.palantir.git-version' version '3.1.0'
    id 'java'
    id 'java-library'
    id 'signing'
}

def gitHubPackagesUser = System.getenv("PACKAGES_USER") ?: ''
def gitHubPackagesToken = System.getenv("PACKAGES_ACCESS_TOKEN") ?: ''
def releaseGradlePluginToken = System.getenv("RELEASE_GRADLE_PLUGIN_TOKEN") ?: ''

repositories {
    mavenLocal()
    maven {
        name = "GitHubPackages"
        url = uri('https://maven.pkg.github.com/bitwarden/sdk')
        credentials {
                username = gitHubPackagesUser
                password = gitHubPackagesToken
            }
    }

    maven {
        url = uri('https://repo.maven.apache.org/maven2/')
    }
}

dependencies {
    api libs.org.cryptomator.integrations.api
    api libs.com.bitwarden.sdk.secrets
    api libs.org.slf4j.slf4j.api
    testImplementation libs.org.slf4j.slf4j.simple
    testImplementation libs.org.junit.jupiter.junit.jupiter.api
    testImplementation libs.org.junit.jupiter.junit.jupiter.engine
    testImplementation libs.org.junit.jupiter.junit.jupiter
}

group = 'org.purejava'
version gitVersion() // version set by the plugin, based on the Git tag
java.sourceCompatibility = JavaVersion.VERSION_20

java {
    withSourcesJar()
    withJavadocJar()
}

test {
    useJUnitPlatform()
    filter {
        includeTestsMatching "BitwardenAccessTest"
    }
}

/*
publishing {
    publications {
        mavenJava(MavenPublication) {
            from(components.java)
            pom {
                name = 'cryptomator-bitwarden'
                description = 'Plug-in for Cryptomator to store vault passwords in Bitwarden'
                url = 'https://github.com/purejava/cryptomator-bitwarden'
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }
                developers {
                    developer {
                        id = 'purejava'
                        name = 'Ralph Plawetzki'
                        email = 'ralph@purejava.org'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/purejava/cryptomator-bitwarden.git'
                    developerConnection = 'scm:git:ssh://github.com/purejava/cryptomator-bitwarden.git'
                    url = 'https://github.com/purejava/cryptomator-bitwarden/tree/develop'
                }
                issueManagement {
                    system = 'GitHub Issues'
                    url = 'https://github.com/purejava/cryptomator-bitwarden/issues'
                }
            }
        }
    }
}
*/

tasks.named('shadowJar', com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar) {
    archiveClassifier.set('')
}

tasks.named('githubRelease') {
    dependsOn('sourcesJar')
    dependsOn('javadocJar')
    dependsOn('signArchives')
}

artifacts {
    archives tasks.named('shadowJar')
    archives tasks.named('sourcesJar')
}

signing {
    useGpgCmd()
    // Sign both the sources JAR and the shadow JAR
    sign configurations.archives
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

githubRelease {
    setToken(releaseGradlePluginToken)
    setTagName("$project.version")
    setReleaseName("$project.version")
    setTargetCommitish('develop')
    setDraft(true)
    setBody("[![Downloads](https://img.shields.io/github/downloads/purejava/cryptomator-bitwarden/latest/cryptomator-bitwarden-${project.version}.jar)](https://github.com/purejava/cryptomator-bitwarden/releases/latest/download/cryptomator-bitwarden-${project.version}.jar)\n" +
            "\n" +
            "- xxx")
    setGenerateReleaseNotes(true)
    releaseAssets = fileTree(dir: "${layout.buildDirectory}/libs", includes: [
            "cryptomator-bitwarden-${version}.jar",
            "cryptomator-bitwarden-${version}.jar.asc",
            "cryptomator-bitwarden-${version}-sources.jar",
            "cryptomator-bitwarden-${version}-sources.jar.asc"
    ]).files
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

tasks.withType(Javadoc) {
    options.encoding = 'UTF-8'
}