build.gradle

/*
 * Copyright 2019 Amazon.com, Inc. or its affiliates.  All rights reserved.
 *
 * Licensed under the Apache License, Version 2.0 (the "License").
 *  You may not use this file except in compliance with the License.
 * A copy of the License is located at:
 *
 *      http://aws.amazon.com/apache2.0/
 *
 *  or in the "license" file accompanying this file. This file is distributed on an "AS IS" BASIS,
 *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the specific
 *  language governing permissions and limitations under the License.
 */

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.11' apply false
    // https://arturbosch.github.io/detekt/groovydsl.html
    id "io.gitlab.arturbosch.detekt" version "1.0.0-RC16" apply false
}

allprojects {
    repositories {
        mavenCentral()
        jcenter()    // needed for detekt
    }
}

subprojects {
    group = 'org.partiql'
    version = '0.1.1-SNAPSHOT'
}

buildDir = new File(rootProject.projectDir, "gradle-build/" + project.name)

configure(subprojects.findAll { it.name != 'example' }) {
    apply plugin: 'io.gitlab.arturbosch.detekt'
    
    detekt {
        input = files("src/")
        parallel = true                                       // Builds the AST in parallel. Rules are always executed in parallel. Can lead to speedups in larger projects. `false` by default.
        debug = false                                         // Adds debug output during task execution. `false` by default.
        ignoreFailures = true                                 // If set to `true` the build does not fail when the maxIssues count was reached. Defaults to `false`.
        reports {
            html {
                enabled = true                                // Enable/Disable HTML report (default: true)
                destination = file("build/reports/detekt/detekt.html") // Path where HTML report will be stored (default: `build/reports/detekt/detekt.html`)
            }
        }
    }
}

subprojects {
    plugins.withId('java', { _ ->
        sourceSets {
            main.java.srcDirs = ["src"]
            main.resources.srcDirs = ["resources"]
            test.java.srcDirs = ["test"]
            test.resources.srcDirs = ["test-resources"]
        }
    })
    plugins.withId('org.jetbrains.kotlin.jvm', { _ ->
        sourceSets {
            main.kotlin.srcDirs = ["src"]
            test.kotlin.srcDirs = ["test"]
        }
    })
}