BIO-NL.bc

1000 A=500:GOTO20:REM BIORITME
1010 GOSUB2030
1020 REM
1030 REM       HOOFDPROGRAMMA
1040 REM
1050 DIMC(12),A(2),B(2),F(2)
1060 GOSUB100:PRINT"Met dit programma kunt u zelf de "
1070 PRINT"stand van uw bioritme bepalen."
1080 HO=0:VE=6:GOSUB110:PRINT"Hoe wilt u de biorythmische";
1090 PRINT" standen ?"
1100 HO=8:VE=9:GOSUB110:PRINT"1 - In woorden"
1110 VE=11:GOSUB110:PRINT"2 - Grafiek op het scherm"
1120 VE=13:GOSUB110:PRINT"3 - Of wilt u een uitleg"
1130 VE=15:GOSUB110:PRINT"4 - Of wilt u stoppen"
1140 HO=5:VE=21:GOSUB110:PRINT"DRUK NA DE UITVOERING RETURN"
1150 HO=8:VE=17:GOSUB110:INPUTZ
1160 IFZ=4 THEN950:REM stoppen
1170 IF(Z<1)OR(Z>3) THEN GOSUB1230:GOTO1150
1180 ONZ GOSUB3030,4030,2030
1190 GOTO1060
1200 REM
1210 REM        FOUTE INVOER
1220 REM
1230 HO=8:VE=17:GOSUB110:PRINT"Niet bekend!"
1240 SD=20:GOSUB450:REM wacht 2 s
1250 HO=8:VE=17:GOSUB110:PRINT"            ":RETURN
2000 REM
2010 REM         INLEIDING
2020 REM
2030 GOSUB100
2040 PRINTTAB(10);"***************"
2050 PRINTTAB(10);"* BIORYTHMIEK *"
2060 PRINTTAB(10);"***************"
2070 PRINT:PRINT"Bij de BIORYTHMIEK gaat men er vanuit "
2080 PRINT"dat bij de geboorte van een mens drie"
2090 PRINT"ritmes van start gaan. Namelijk:"
2100 PRINT"- het LICHAAMSRITME."
2110 PRINT"(met een lengte van 23 dagen)"
2120 PRINT"- HET GEVOELSRITME."
2130 PRINT"(met een lengte van 28 dagen)"
2140 PRINT"- HET INTELLIGENTIERITME."
2150 PRINT"(met een lengte van 33 dagen)"
2160 PRINT"Vanaf de geboorte gaan alle drie de"
2170 PRINT"ritmes naar een optimale toestand "
2180 PRINT"(positief) waarna ze naar een minimum"
2190 PRINT"dalen. Telkens wanneer een ritme van"
2200 PRINT"positief naar negatief (of anders om)"
2210 PRINT"overgaat is het ritme KRITISCH."
2220 PRINT"DWZ. dat de persoon wat dat ritme "
2230 PRINT"betreft instabiel is."
2240 PRINT:PRINTTAB(25);"druk <RETURN>"
2250 GOSUB200:IFIN<>13 THEN2250
2260 RETURN
3000 REM
3010 REM     STAND IN WOORDEN
3020 REM
3030 GOSUB5030
3040 GOSUB100:PRINT"de bioritmische standen:"
3050 PRINT:PRINT"het lichaamsritme is ";
3060 E=INT((D/23-INT(D/23))*23+.5)
3070 IF(E=0)OR(E=1)OR(E=12) THENPRINT"KRITISCH":GOTO3100
3080 IF(E>1)AND(E<12) THENPRINT"POSITIEF":GOTO3100
3090 PRINT"NEGATIEF"
3100 PRINT:PRINT"het gevoelsritme is ";
3110 E=INT((D/28-INT(D/28))*28+.5)
3120 IF(E<2)OR(E=14)OR(E=15) THENPRINT"KRITISCH":GOTO3150
3130 IF(E>0)AND(E<14) THENPRINT"POSITIEF":GOTO3150
3140 PRINT"NEGATIEF"
3150 PRINT:PRINT"en het intelligentieritme is ";
3160 E=INT((D/33-INT(D/33))*33+.5)
3170 IF(E=0)OR(E=1)OR(E=17) THENPRINT"KRITISCH":GOTO3200
3180 IF(E>0)AND(E<17) THENPRINT"POSITIEF":GOTO3200
3190 PRINT"NEGATIEF"
3200 PRINT:PRINT:PRINT"Ieder mens heeft een dag waarop alle"
3210 PRINT"ritmes door het kritische punt gaan."
3220 PRINT:Z=21252-D:IFZ<0 THEN3260
3230 PRINT"die dag is voor u op:"
3240 F(0)=B(0):F(1)=B(1):F(2)=B(2):GOSUB5700
3250 PRINT:PRINTF(0);"-";F(1);"-";F(2)
3260 IFZ<0 THENPRINT"Die dag heeft u al gehad"
3270 PRINT:PRINTTAB(25);"druk <RETURN>"
3280 GOSUB200:IFIN<>13 THEN3280
3290 FORT=0 TO2:A(T)=0:B(T)=0:F(T)=0:NEXTT
3300 RETURN
4000 REM
4010 REM   GRAFIEK
4020 REM
4030 GOSUB5030
4040 GOSUB600
4050 D=D-B(0):Z=C(B(1))
4060 HO=0:VE=10/191:CN=0:GOSUB620
4070 HO=0:VE=180/191:CN=0:GOSUB630
4080 HO=0:VE=100/191:CN=0:GOSUB620
4090 HO=6*Z/191:VE=100/191:CN=0:GOSUB630
4100 A$="1-":SR=B(1):GOSUB300:A$=A$+SR$
4110 A$=A$+"-":SR=B(2):GOSUB300:A$=A$+SR$:SR$=A$
4120 HO=6/191:VE=172/191:CN=0:GOSUB650
4130 FORT=0 TO6*Z-6 STEP6
4140 IFT/42=INT(T/42) THEN4180
4150 HO=T/191:VE=101/191:CN=0:GOSUB620
4160 VE=102/191:GOSUB620
4170 NEXTT:GOTO4210
4180 HO=T/191:VE=101/191:CN=0:GOSUB620
4190 VE=104/191:GOSUB630
4200 NEXTT
4210 CN=0:HO=80/191:VE=1/191:SR$="KOERPER"
4220 GOSUB650
4230 HO=0:VE=100/191:GOSUB620
4240 X=0:FORT=D TOD+Z STEP.5
4250 Y=-SIN(T*2*3.1415927/23)*67
4260 Y=INT(Y+.5)
4270 HO=X/191:VE=(Y+100)/191:GOSUB630
4280 X=X+3
4290 NEXTT
4300 CN=0:HO=80/191:VE=11/191:SR$="GEFUEHL"
4310 GOSUB650
4320 HO=0:VE=85/191:GOSUB620
4330 X=0:FORT=D TOD+Z STEP.5
4340 Y=-SIN(T*2*3.1415927/28)*67
4350 Y=INT(Y+.5)
4360 HO=X/191:VE=(Y+100)/191:GOSUB630
4370 X=X+3
4380 NEXTT
4390 CN=0:HO=80/191:VE=21/191:SR$="INTELLIGENZ"
4400 GOSUB650
4410 HO=0:VE=85/191:GOSUB620
4420 X=0:FORT=D TOD+Z STEP.5
4430 Y=-SIN(T*2*3.1415927/33)*67
4440 Y=INT(Y+.5)
4450 HO=X/191:VE=(Y+100)/191:GOSUB630
4460 X=X+3
4470 NEXTT
4480 GOSUB200:IFIN<>13 THEN4480
4490 FORT=0 TO2:A(T)=0:B(T)=0:F(T)=0:NEXTT
4500 RETURN
5000 REM
5010 REM  GEGEVENS INVOEREN
5020 REM
5030 GOSUB100
5040 PRINT:PRINT"Wat is uw geboorte datum ?"
5050 PRINT:PRINT"Dag ";:INPUTA(0)
5060 PRINT"Maand ";:INPUTA(1)
5070 PRINT"Jaar ";:INPUTA(2)
5080 PRINT:PRINTA(0);"-";A(1);"-";A(2)
5090 PRINT:PRINT"Is dat goed (j/n)";:INPUTA$:PRINT
5100 IF(A(0)=0)OR(A(0)>31) THEN GOSUB5310
5110 IF(A(1)>12)OR(A(1)=0) THEN GOSUB5310
5120 IF(A$="n")OR(A$="N") THEN5040
5130 PRINT:PRINT"Wat is de peildatum ?"
5140 PRINT:PRINT"Dag ";:INPUTB(0)
5150 PRINT"Maand ";:INPUTB(1)
5160 PRINT"Jaar ";:INPUTB(2)
5170 PRINT:PRINTB(0);"-";B(1);"-";B(2)
5180 PRINT:PRINT"Is dat goed (j/n)";:INPUTA$:PRINT
5190 IF(B(0)=0)OR(B(0)>31) THEN GOSUB5310
5200 IF(B(1)>12)OR(B(1)=0) THEN GOSUB5310
5210 IF(A$="n")OR(A$="N") THEN5130
5220 GOSUB5380
5230 GOSUB100
5240 PRINT"Op ";B(0);"-";B(1);"-";B(2);
5250 PRINT" bent u ";D;" dagen oud"
5260 SD=20:GOSUB450
5270 RETURN
5280 REM
5290 REM  FOUTE INVOER (2)
5300 REM
5310 FORT=0 TO2:A(T)=0:B(T)=0:F(T)=0:NEXTT
5320 IF(A$="N")OR(A$="n") THENRETURN
5330 PRINT"Dat kan nooit goed zijn!"
5340 A$="n":RETURN
5350 REM
5360 REM  DAGEN TELLEN
5370 REM
5380 C(1)=31:C(3)=31:C(4)=30:C(5)=31:C(6)=30:C(7)=31:C(8)=31
5390 C(9)=30:C(10)=31:C(11)=30:C(12)=31
5400 GOSUB5990
5410 D=C(A(1))-A(0)+1
5420 IFA(2)=B(2) THEN5540
5430 IF(A(2)+1)=B(2) THEN5600
5440 IFA(1)=12 THEN5460
5450 FORT=(A(1)+1) TO12:D=D+C(T):NEXTT
5460 FORT=(A(2)+1) TO(B(2)-1)
5470 GOSUB6020
5480 NEXTT
5490 GOSUB6050
5500 IFB(1)=1 THEN5520
5510 FORT=1 TO(B(1)-1):D=D+C(T):NEXTT
5520 D=D+B(0):RETURN
5530 REM       A(2)=B(2)
5540 GOSUB5990
5550 IFA(1)=B(1) THEND=(B(0)-A(0))+1:RETURN
5560 IF(A(1)+1)=B(1) THEND=D+B(0):RETURN
5570 FORT=(A(1)+1) TO(B(1)-1):D=D+C(T):NEXTT
5580 D=D+B(0):RETURN
5590 REM      A(2)+1=B(2)
5600 GOSUB5990
5610 IFA(1)=12 THEN5630
5620 FORT=(A(1)+1) TO12:D=D+C(T):NEXTT
5630 GOSUB6050
5640 IFB(1)=1 THEN5660
5650 FORT=1 TO(B(1)-1):D=D+C(T):NEXTT
5660 D=D+B(0):RETURN
5670 REM
5680 REM  DATUM ZOEKEN
5690 REM
5700 C(1)=31:C(3)=31:C(4)=30:C(5)=31:C(6)=30:C(7)=31:C(8)=31
5710 C(9)=30:C(10)=31:C(11)=30:C(12)=31
5720 GOSUB6080
5730 Z=Z-1:IFZ<C(F(1))-F(0) THEN5910
5740 Z=Z-C(F(1))+F(0)-1:F(1)=F(1)+1:F(0)=1
5750 IFZ=0 THENRETURN
5760 FORT=F(1) TO12
5770 IFZ>C(T) THENZ=Z-C(T):F(1)=F(1)+1:GOTO5790
5780 GOTO5910
5790 NEXTT:F(1)=1:F(2)=F(2)+1
5800 G=365
5810 GOSUB6110
5820 IFZ>=G THENZ=Z-G:F(2)=F(2)+1:GOTO5840
5830 GOTO5910
5840 IFZ=0 THENRETURN
5850 GOTO5810
5860 GOSUB6080
5870 IFZ>=C(F(1)) THENZ=Z-C(F(1)):F(1)=F(1)+1:GOTO5890
5880 GOTO5910
5890 IFZ=0 THENRETURN
5900 GOTO5870
5910 IFZ>0 THENZ=Z-1:F(0)=F(0)+1
5920 IFF(0)>C(F(1)) THENF(1)=F(1)+1:F(0)=1
5930 IFF(1)>12 THENF(2)=F(2)+1:F(1)=1:F(0)=1:GOTO5860
5940 IFZ=0 THENRETURN
5950 GOTO5910
5960 REM
5970 REM SCHRIKKELJAAR ?
5980 REM
5990 IF(A(2)/4<>INT(A(2)/4)) THENC(2)=28:RETURN
6000 IF(A(2)/100<>INT(A(2)/100)) THENC(2)=29:RETURN
6010 C(2)=28:RETURN
6020 IF(T/4<>INT(T/4)) THEND=D+365:RETURN
6030 IF(T/100<>INT(T/100)) THEND=D+366:RETURN
6040 D=D+365:RETURN
6050 IF(B(2)/4<>INT(B(2)/4)) THENC(2)=28:RETURN
6060 IF(B(2)/100<>INT(B(2)/100)) THENC(2)=29:RETURN
6070 C(2)=28:RETURN
6080 IF(F(2)/4<>INT(F(2)/4)) THENC(2)=28:RETURN
6090 IF(F(2)/100<>INT(F(2)/100)) THENC(2)=29:RETURN
6100 C(2)=28:RETURN
6110 IF(F(2)/4<>INT(F(2)/4)) THENG=365:RETURN
6120 IF(F(2)/100<>INT(F(2)/100)) THENG=366:RETURN
6130 G=365:RETURN
32000 REM**************************
32010 REM*   door: M. Nitters     *
32020 REM*     Oud-Beyerland      *
32030 REM*     NEDERLAND          *
32040 REM**************************
32050 REM TROS-RADIO dd 871111
32060 REM
32070 REM Erstausstrahlung: Radio DDR
32080 REM 900418