LOGO.bc

1000 A=300:GOTO 20:REM ===ZAHLEN===
1010 DIM ZA(4),EX(4):RE=1000
1020 GOSUB 1560:REM EINLEITUNG**
1030 GOSUB 100:P=1
1040 PRINT "Schwierigkeitsgrad ";SC/3-1
1050 REM GENERATION DER ZAHLEN===
1060 FOR I=1 TO 2 STEP 0
1070 GOSUB 260:RV=INT(RV*SC)+1
1080 WA=1
1090 FOR J=1 TO 4
1100 IF ZA(J)=RV THEN WA=0
1110 NEXT J
1120 IF WA=1 THEN ZA(P)=RV:P=P+1
1130 IF P>4 THEN I=2
1140 NEXT I
1150 REM EINGABE ================
1160 PRINT 
1170 VR=1
1180 HO=0:VE=VR:GOSUB 110
1190 PRINT "VERSUCH:";
1200 PRINT VR;
1210 FOR I=15 TO 27 STEP 4
1220 HO=I:VE=VR:GOSUB 110:GOSUB 210
1230 PRINT IN$;
1240 EX((I-15)/4+1)=VAL(IN$)
1250 NEXT I
1260 REM TEST====================
1270 REM ABSOLUT RICHTIG---------
1280 RI=0
1290 HO=30:GOSUB 110
1300 FOR I=1 TO 4
1310 IF EX(I)<>ZA(I)THEN NEXT I:GOTO 1380
1320 PRINT "*";:RI=RI+1
1330 FOR J=1 TO 4
1340 IF EX(J)=ZA(I)THEN EX(J)=0
1350 NEXT J
1360 NEXT I
1370 REM RELATIV RICHTIG---------
1380 FOR I=1 TO 4
1390 FOR J=1 TO 4
1400 IF EX(I)=ZA(J)THEN PRINT "+";
1410 NEXT J
1420 NEXT I
1430 IF RI=4 THEN 1470
1440 PRINT :VR=VR+1
1450 GOTO 1180
1460 REM AUSWERTUNG==============
1470 PRINT :PRINT "Sie haben ";VR;" Versuche benoetigt."
1480 IF VR<RE THEN RE=VR
1490 PRINT "Der Rekord liegt bei ";RE;" Versuchen."
1500 PRINT :PRINT :PRINT "Noch einmal (N)";
1510 GOSUB 210
1520 FOR J=1 TO 4:ZA(J)=0:NEXT J
1530 IF IN<>78 THEN 1020
1540 GOTO 950
1550 REM EINFUEHRUNG===========
1560 GOSUB100:PRINT:SR$="  ZAHLEN  "
1570 PRINT "           ";:GOSUB 150:PRINT:PRINT
1580 PRINT "Dieses Spiel hat als Vorlage das"
1590 PRINT "Denkspiel 'LOGO'. Zur Einfachheit wird"
1600 PRINT "es hier mit Zahlen gespielt."
1610 PRINT "Spielregeln wie folgt:"
1620 PRINT "Es gilt, 4 Zahlen in richtiger Reihen-"
1630 PRINT "folge zu raten."
1640 PRINT "Der Rechner sagt Ihnen, wieviele Zahlen"
1650 PRINT "am richigen Fleck (*) sind und wieviele"
1660 PRINT "Zahlen vorhanden , jedoch nicht am"
1670 PRINT "richtigem Fleck sind (+)."
1680 PRINT "Hinweis:Jede Zahl ist nur einmal vor-"
1690 PRINT "        handen."
1700 PRINT :PRINT "Schwierigkeit 1: Zahlen von 1..6"
1710 PRINT "Schwierigkeit 2: Zahlen von 1..9"
1720 PRINT :PRINT "Schwierigkeitsgrad:";:GOSUB 210
1730 PRINT IN$
1740 SC=VAL(IN$)
1750 IF (SC<1)OR (SC>2)THEN 1720
1760 SC=(SC+1)*3
1770 RETURN
1780 REM ***** ENDE *****
32000 REM TILO WUENSCHE 
32010 REM LIEBENWERDAERSTR.11
32020 REM O-7901 MAASDORF
32030 REM AM 25.9.1990 AUF KC85/4
32040 REM -----------------------------------------
32050 REM Erstausstrahlung: Deutschlandsender Kultur
32060 REM -spezial 901114