Auto/timed feed refresh

[comporder1]

I have a need for my channel to reload my feed and refresh the gridscreen every five minutes or so. As it is currently, the only way to force a feed refresh is to close the channel and restart it. I have looked around in the code, but I can not find where to put a possible loop and I'm not sure what function to call to initiate a refresh. Maybe LoadChannelContent() ? To further complicate, this refresh should only happen when gridscreen is shown. It doesn't need to happen while a video is playing.

Thanks for your work on this project!
CW

[rrirower]

I think you should look into creating a task node that runs in the background with a timer that refreshes your feed content. Keep in mind, that what you're asking for is somewhat complicated in the existing code framework. Loading the channel content already happens in a task at startup. You're asking for a way to repeat that process. It could get messy.

[comporder1]

Thanks for the suggestion. It got me going in the right direction. I managed to get it done pretty cleanly I think. I'm open to suggestions or corrections. Below is code that I added.

in MainScene.brs in Init() add:

        ' Start task to refresh feed content.
	ReLoadChannelTask() 

in ContentTaskLogic.brs add:

'''''''''
' ReLoadChannelTask: Spawns a continuous task to call call ReLoadChannelContent every x minutes.
' 
'''''''''
sub ReLoadChannelTask()
    m.RefreshTask = CreateObject("roSGNode", "RefreshFeedTask")  ' create task for refreshing channel feed.
    m.RefreshTask.ObserveField("refreshcount", "ReLoadChannelContent") ' observe content so we can know when the feed content will be parsed.
    m.RefreshTask.control = "run"  
end sub

'''''''''
' ReLoadChannelContent: Reloads the channel content by spawning a task to iterate the feed file.
' 
'''''''''
sub ReLoadChannelContent()
    m.ContentTask = CreateObject("roSGNode", "MainLoaderTask")  ' create task for retrieving channel feed.
    ' observe content so we can know when the feed content will be parsed.
    m.contentTask.ObserveField("content", "OnMainContentReLoaded")
    m.contentTask.control = "run"   ' GetContent(see MainLoaderTask.brs) method is executed.
end sub

'''''''''
' OnMainContentReLoaded: Event: called after the content feed has been reloaded.
' 
'''''''''
sub OnMainContentReLoaded()    ' invoked when content has been parsed and is ready to use.
	if m.GridScreen.content.getChildCount() <> m.contentTask.content.getChildCount() ' only reload if content count has changed
		m.loadingIndicator.visible = true   ' show loading indicator while content is loading.
		m.GridScreen.content = m.contentTask.content    ' populate GridScreen with content.
		m.loadingIndicator.visible = false  ' hide loading indicator because content was retrieved.
	end if
end sub

in pkg:/components/tasks/ add file RefreshFeedTask.xml:

<?xml_ version="1.0" encoding="UTF-8" ?>
<component name="RefreshFeedTask" extends="Task">

<interface>
    <field id="refreshcount" type="int" value="0"/>
</interface>
    <script type="text/brightscript" uri="RefreshFeedTask.brs" />
</component>

in pkg:/components/tasks/ add file RefreshFeedTask.brs:

sub Init()
    m.top.functionName = "executeTask"
end sub

function executeTask() as void
	while true
			min_to_wait=1  ' how many minutes between content refresh
			ms_to_wait=min_to_wait*60000
			sleep(ms_to_wait)
			m.top.refreshcount = m.top.refreshcount + 1  ' something for the main program to observe for change
	end while
end function

CW

[rrirower]

You should consider testing deep linking and other features to make sure they still work.

[comporder1]

Deep Linking still works as expected. The only thing that is a little quirky is when content is reloaded, the grid screen focus resets to the top. So if a user is browsing rows of content and and a reload occurs, it takes the user all the way to back to the top row. I think I can live with that. I've considered adding a "reloadingIndicator" message to let the user know that content just reloaded.

Thanks again!
CW