Add qmake project for standalone builds.

Author: jaredhanson

mkspecs/features/qtx_config.prf

@@ -0,0 +1 @@
+include(qtx_functions.prf)

mkspecs/features/qtx_functions.prf

@@ -0,0 +1,22 @@
+defineReplace(qtxPlatformTargetSuffix) {
+    CONFIG(debug, debug|release) {
+        !debug_and_release|build_pass {
+           mac:return(_debug)
+           win32:return(d)
+        }
+    }
+    return()
+}
+
+defineReplace(qtxLibraryTarget) {
+   unset(LIBRARY_NAME)
+   LIBRARY_NAME = $$1
+   mac:!static:contains(CONFIG, framework) {
+      QMAKE_FRAMEWORK_BUNDLE_NAME = $$LIBRARY_NAME
+      export(QMAKE_FRAMEWORK_BUNDLE_NAME)
+   }
+   unset(LIBRARY_SUFFIX)
+   contains(TEMPLATE, .*lib):LIBRARY_SUFFIX = $$qtxPlatformTargetSuffix()
+   isEmpty(LIBRARY_SUFFIX):return($$LIBRARY_NAME)
+   else:return($$member(LIBRARY_NAME, 0)$$LIBRARY_SUFFIX)
+}

mkspecs/features/qtx_module.prf

@@ -0,0 +1,35 @@
+isEmpty(MODULE):MODULE = $$section($$list($$basename(_PRO_FILE_)), ., 0, 0)
+isEmpty(VERSION):VERSION = $$eval(QTX.$${MODULE}.VERSION)
+
+TEMPLATE = lib
+TARGET   = $$eval(QTX.$${MODULE}.name)
+DESTDIR  = $$eval(QTX.$${MODULE}.libs)
+TARGET   = $$qtxLibraryTarget($$TARGET)
+
+# Build Configurations
+#
+# By default, the module will be built in release mode.  To build in debug mode,
+# or both debug and release mode:
+#
+#     $ qmake [options] "CONFIG+=debug"
+#     $ qmake [options] "CONFIG+=debug_and_release"
+#
+# To build a static library:
+#
+#     $ qmake [options] "CONFIG+=static"
+#
+# On Mac OS X, a framework will be created by default.  To build a dynamic
+# library:
+#
+#     $ qmake [options] "CONFIG+=dylib"
+
+debug_and_release {
+    CONFIG += build_all
+}
+
+mac:!static {
+    CONFIG += lib_bundle
+    dylib {
+        CONFIG -= lib_bundle
+    }
+}

mkspecs/features/qtx_parts.prf

@@ -0,0 +1,12 @@
+TEMPLATE = subdirs
+
+sub_src.subdir = src
+sub_src.target = sub-src
+SUBDIRS = sub_src
+
+exists($$_PRO_FILE_PWD_/tests/tests.pro) {
+    sub_tests.subdir = tests
+    sub_tests.target = sub-tests
+    sub_tests.depends = sub_src   # The tests may have a run-time only dependency on other parts
+    SUBDIRS += sub_tests
+}

mkspecs/features/qtx_testcase.prf

@@ -0,0 +1,10 @@
+check.commands += $(TESTRUNNER)
+
+macx {
+    check.commands += DYLD_LIBRARY_PATH=../../../lib
+
+    app_bundle: check.commands += ./$(QMAKE_TARGET).app/Contents/MacOS/$(QMAKE_TARGET)
+    else:       check.commands += ./$(QMAKE_TARGET)
+}
+
+QMAKE_EXTRA_TARGETS *= check

mkspecs/test.pri

@@ -0,0 +1,8 @@
+include(features/qtx_testcase.prf)
+
+
+INCLUDEPATH += ../../../src/update
+
+LIBS += -L../../../lib
+
+LIBS += -lQtxUpdate

modules/qtx_update.pri

@@ -0,0 +1,12 @@
+QTX.update.MAJOR_VERSION = 0
+QTX.update.MINOR_VERSION = 0
+QTX.update.PATCH_VERSION = 0
+QTX.update.VERSION = $${QTX.update.MAJOR_VERSION}.$${QTX.update.MINOR_VERSION}.$${QTX.update.PATCH_VERSION}
+
+QTX.update.name = QtxVersion
+QTX.update.bins = $$PWD/../bin
+QTX.update.includes = $$PWD/../include
+QTX.update.sources = $$PWD/../src/version
+QTX.update.libs = $$PWD/../lib
+QTX.update.plugins = $$PWD/../plugins
+QTX.update.imports = $$PWD/../imports

qtxupdate.pro

@@ -0,0 +1 @@
+include(mkspecs/features/qtx_parts.prf)

src/src.pro

@@ -0,0 +1,5 @@
+TEMPLATE = subdirs
+
+SUBDIRS += update
+update.subdir = update
+update.target = sub-update

src/update/update.pro

@@ -0,0 +1,6 @@
+include(../../modules/qtx_update.pri)
+include(../../mkspecs/features/qtx_config.prf)
+include(../../mkspecs/features/qtx_module.prf)
+
+
+include(update.pri)