Codeunit_0000000111.txt

OBJECT Codeunit 111 Vend. Entry-SetAppl.ID
{
  OBJECT-PROPERTIES
  {
    Date=09/07/12;
    Time=12:00:00 PM;
    Version List=NAVW17.00;
  }
  PROPERTIES
  {
    Permissions=TableData 25=imd;
    OnRun=BEGIN
          END;

  }
  CODE
  {
    VAR
      VendEntryApplID@1000 : Code[50];

    PROCEDURE SetApplId@1(VAR VendLedgEntry@1000 : Record 25;ApplyingVendLedgEntry@1001 : Record 25;AppliesToID@1005 : Code[50]);
    BEGIN
      VendLedgEntry.LOCKTABLE;
      IF VendLedgEntry.FIND('-') THEN BEGIN
        // Make Applies-to ID
        IF VendLedgEntry."Applies-to ID" <> '' THEN
          VendEntryApplID := ''
        ELSE BEGIN
          VendEntryApplID := AppliesToID;
          IF VendEntryApplID = '' THEN BEGIN
            VendEntryApplID := USERID;
            IF VendEntryApplID = '' THEN
              VendEntryApplID := '***';
          END;
        END;

        // Set Applies-to ID
        REPEAT
          VendLedgEntry.TESTFIELD(Open,TRUE);
          VendLedgEntry."Applies-to ID" := VendEntryApplID;
          IF VendLedgEntry."Applies-to ID" = '' THEN BEGIN
            VendLedgEntry."Accepted Pmt. Disc. Tolerance" := FALSE;
            VendLedgEntry."Accepted Payment Tolerance" := 0;
          END;
          // Set Amount to Apply

          IF ((VendLedgEntry."Amount to Apply" <> 0) AND (VendEntryApplID = '')) OR
             (VendEntryApplID = '')
          THEN
            VendLedgEntry."Amount to Apply" := 0
          ELSE
            IF VendLedgEntry."Amount to Apply" = 0 THEN BEGIN
              VendLedgEntry.CALCFIELDS("Remaining Amount");
              VendLedgEntry."Amount to Apply" := VendLedgEntry."Remaining Amount"
            END;

          IF VendLedgEntry."Entry No." = ApplyingVendLedgEntry."Entry No." THEN
            VendLedgEntry."Applying Entry" := ApplyingVendLedgEntry."Applying Entry";
          VendLedgEntry.MODIFY;
        UNTIL VendLedgEntry.NEXT = 0;
      END;
    END;

    BEGIN
    END.
  }
}