-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathparser.scm
428 lines (390 loc) · 13.5 KB
/
parser.scm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
(define (parse source)
(define current-def-proc-id #f)
(define (form? keyword source)
(and (pair? source)
(eq? (car source) keyword)))
(define (expect-form keyword source)
(if (not (form? keyword source))
(error "expected" keyword source)))
(define (get-id source)
(expect-form 'six.identifier source)
(cadr source))
(define (define-variable source cte cont)
(let* ((id (get-id (cadr source)))
(type (caddr source))
(dims (cadddr source))
(val (car (cddddr source))))
;; variables which, when found in programs, have special meanings
;; when any of these are encountered, its associated thunk is
;; called
(define special-variables
(list ;; TODO fit with the predefined variables in cte.scm ?
(cons 'SIXPIC_MEMORY_DIVIDE
(lambda ()
(set! memory-divide (cadr val)) ; must be a literal
(expression val cte (lambda (ast cte)
(def (list ast) cte)))))))
(define (def asts cte)
(let* ((value
(alloc-value type current-def-proc-id id))
(ast
(new-def-variable
asts id '() type value '() current-def-proc-id))
(cte
(cte-extend cte (list ast))))
(cont ast
cte)))
;; if it's a special variable, call its associated thunk instead
(let ((target (assq id special-variables)))
(if target
((cdr target))
(if val
(expression val cte (lambda (ast cte) (def (list ast) cte)))
(def '() cte))))))
(define (define-procedure source cte cont)
(let* ((id (get-id (cadr source)))
(proc (caddr source)))
(expect-form 'six.procedure proc)
(set! current-def-proc-id id)
(let* ((type
(cadr proc))
(params
(map (lambda (x)
(let* ((var-id (get-id (car x)))
(type (cadr x))
(value (alloc-value type id var-id)))
(new-def-variable '() var-id '() type value '() id))) ;; TODO allocate the value inside new-def-variable ?
(caddr proc)))
(body
(cadddr proc)))
(expect-form 'six.procedure-body body)
(let* ((value
(alloc-value type id id))
(ast
(new-def-procedure '() id '() type value params))
(cte
(cte-extend cte (list ast))))
(multi-link-parent! params ast)
(let ((res (block body
(cte-extend cte params)
(lambda (body-ast body-cte)
(ast-subasts-set! ast (list body-ast))
(link-parent! body-ast ast)
(cont ast
cte)))))
(set! current-def-proc-id #f)
res)))))
(define (block source cte cont)
(define (b source cte cont)
(if (null? source)
(cont '() cte)
(let ((head (car source))
(tail (cdr source)))
(if (or (form? 'six.label head) ; we complete the block with a list of named blocks
(form? 'six.case head))
(named-block-list source
cte
cont) ; will return a list of named blocks
(statement head
cte
(lambda (ast cte)
(b tail
cte
(lambda (asts cte)
(cont (cons ast asts)
cte)))))))))
(b (cdr source)
cte
(lambda (asts cte)
(cont (new-block asts)
cte))))
;; handles named blocks (implicit blocks delimited by labels)
;; useful for switch and goto
(define (named-block-list source cte cont)
(define (b source cte cont name body-so-far)
(if (null? source)
(cont (list (new-named-block name body-so-far)) ; last block
cte)
(let ((curr (car source)))
(if (or (form? 'six.label curr) ; we reached another named block
(form? 'six.case curr))
(named-block-list source
cte
(lambda (named-blocks cte)
(cont (cons (new-named-block name body-so-far)
named-blocks)
cte)))
(statement curr
cte
(lambda (ast cte)
(b (cdr source)
cte
cont
name
(append body-so-far (list ast)))))))))
(let ((new-cont
(lambda (name cte)
(statement (caddar source)
cte
(lambda (ast cte)
(b (cdr source)
cte
cont
name
;; the first statement is in the case/label form
(list ast)))))))
(if (form? 'six.case (car source)) ; the label is a case
(literal (cadar source)
cte
(lambda (name cte)
(new-cont (list 'case (literal-val name)) cte)))
(new-cont (cadar source) cte)))) ; ordinary label
(define (statement source cte cont)
(cond ((form? 'six.define-variable source)
(define-variable source cte cont))
((form? 'six.if source)
(if (null? (cdddr source))
(if1 source cte cont)
(if2 source cte cont)))
((form? 'six.switch source)
(switch source cte cont))
((form? 'six.while source)
(while source cte cont))
((form? 'six.do-while source)
(do-while source cte cont))
((form? 'six.for source)
(for source cte cont))
((form? 'six.return source)
(return source cte cont))
((form? 'six.break source)
(break source cte cont))
((form? 'six.continue source)
(continue source cte cont))
((form? 'six.goto source)
(goto source cte cont))
((form? 'six.compound source)
(block source cte cont))
(else
(expression source cte cont))))
(define (return source cte cont)
(define (ret asts cte)
(cont (new-return asts)
cte))
(if (null? (cdr source))
(ret '() cte)
(expression (cadr source)
cte
(lambda (ast cte)
(ret (list ast) cte)))))
(define (break source cte cont)
(cont (new-break)
cte))
(define (continue source cte cont)
(cont (new-continue)
cte))
(define (goto source cte cont)
(cont (new-goto (cadadr source)) ; label
cte))
(define (if1 source cte cont)
(expression (cadr source)
cte
(lambda (ast1 cte)
(statement (caddr source)
cte
(lambda (ast2 cte)
(cont (new-if (list ast1 ast2))
cte))))))
(define (if2 source cte cont)
(expression (cadr source)
cte
(lambda (ast1 cte)
(statement (caddr source)
cte
(lambda (ast2 cte)
(statement (cadddr source)
cte
(lambda (ast3 cte)
(cont (new-if (list ast1 ast2 ast3))
cte))))))))
(define (switch source cte cont)
(expression (cadr source)
cte
(lambda (ast1 cte) ; we matched the paren expr
(expect-form 'six.compound (caddr source))
(block (caddr source)
cte
(lambda (ast2 cte)
(cont (new-switch (cons ast1 (ast-subasts ast2)))
cte))))))
(define (while source cte cont)
(expression (cadr source)
cte
(lambda (ast1 cte)
(statement (caddr source)
cte
(lambda (ast2 cte)
(cont (new-while (list ast1 ast2))
cte))))))
(define (do-while source cte cont)
(statement (cadr source)
cte
(lambda (ast1 cte)
(expression (caddr source)
cte
(lambda (ast2 cte)
(cont (new-do-while (list ast1 ast2))
cte))))))
(define (for source cte cont)
(define (opt-expr source cte cont)
(if source
(expression source cte cont)
(cont #f cte)))
(statement (cadr source)
cte
(lambda (ast1 cte)
(opt-expr (caddr source)
cte
(lambda (ast2 cte)
(opt-expr (cadddr source)
cte
(lambda (ast3 cte)
(statement (car (cddddr source))
cte
(lambda (ast4 cte)
(cont (new-for
(list ast1
(or ast2
(new-literal 'byte 1))
(or ast3
(new-block '()))
ast4))
cte))))))))))
(define (expression source cte cont)
(cond ((form? 'six.literal source)
(literal source cte cont))
((form? 'six.prefix source)
;; this is a hack to support hexadecimal values
;; SIX does not parse C-style hex values (0x...), but falls back on
;; the regular parser when it encounters Scheme-style hex values
;; (#x...) and wraps them in a six.prefix.
;; TODO support C-style hex values
(literal `(six.literal ,(cadr source)) cte cont))
((form? 'six.identifier source)
(ref source cte cont))
((form? 'six.call source)
(call source cte cont))
((operation? source)
=>
(lambda (op)
(operation op source cte cont)))
(else
(error "expected expression" source))))
(define (operation op source cte cont)
(define (continue ast cte)
(expr-type-set! ast ((op-type-rule op) ast))
(cont (if fold-constants? ((op-constant-fold op) ast) ast)
cte))
(cond ((op1? op)
(expression
(cadr source)
cte
(lambda (ast1 cte)
(continue (new-oper (list ast1) #f op) cte))))
((op2? op)
(expression
(cadr source)
cte
(lambda (ast1 cte)
(expression
(caddr source)
cte
(lambda (ast2 cte)
(continue (new-oper (list ast1 ast2) #f op) cte))))))
(else ; ternary operator
(expression
(cadr source)
cte
(lambda (ast1 cte)
(expression
(caddr source)
cte
(lambda (ast2 cte)
(expression
(cadddr source)
cte
(lambda (ast3 cte)
(continue (new-oper (list ast1 ast2 ast3) #f op)
cte))))))))))
(define (call source cte cont)
(let* ((id (get-id (cadr source)))
(binding (cte-lookup cte id)))
(if (def-procedure? binding)
(expressions (cddr source)
cte
(lambda (args cte)
(cont (new-call args (def-procedure-type binding) binding)
cte)))
(error "expected procedure" source))))
(define (expressions source cte cont)
(cond ((null? source)
(cont '()
cte))
(else
(let ((head (car source))
(tail (cdr source)))
(expression head
cte
(lambda (ast cte)
(expressions tail
cte
(lambda (asts cte)
(cont (cons ast asts)
cte)))))))))
(define (literal source cte cont)
(let ((n (cadr source)))
;; note: literals have the smallest type they can fit in.
;; this is not standard, so more casts than usual might be needed to
;; avoid unfortunate truncations
;; this helps generate shorter code, and can be considered a domain
;; specific optimization
(cont (new-literal (val->type n) n)
cte)))
(define (ref source cte cont)
(let* ((id (cadr source))
(binding (cte-lookup cte id)))
(if (def-variable? binding)
(cont (new-ref (def-variable-type binding) binding)
cte)
(error "expected variable" source))))
(define (toplevel source cte cont) ;; TODO have an implicit main
(cond ((form? 'six.define-variable source)
(define-variable source cte cont))
((form? 'six.define-procedure source)
(define-procedure source cte cont))
(else
(statement source cte cont))))
(define (program source cte cont)
(define (p source cte cont)
(cond ((null? source)
(cont '()
cte))
(else
(let ((head (car source))
(tail (cdr source)))
(toplevel head
cte
(lambda (ast cte)
(p tail
cte
(lambda (asts cte)
(cont (cons ast asts)
cte)))))))))
(p source
cte
(lambda (asts cte)
(cont (new-program asts)
cte))))
(program source
initial-cte
(lambda (ast cte)
ast)))