-
Notifications
You must be signed in to change notification settings - Fork 9
/
ServerSide.tcl
2790 lines (2600 loc) · 107 KB
/
ServerSide.tcl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
###############################################################################
## ##
## Copyright (c) 2016-2021, Harald Oehlmann ##
## Copyright (c) 2006-2013, Gerald W. Lester ##
## Copyright (c) 2008, Georgios Petasis ##
## Copyright (c) 2006, Visiprise Software, Inc ##
## Copyright (c) 2006, Colin McCormack ##
## Copyright (c) 2006, Rolf Ade ##
## Copyright (c) 2001-2006, Pat Thoyts ##
## All rights reserved. ##
## ##
## Redistribution and use in source and binary forms, with or without ##
## modification, are permitted provided that the following conditions ##
## are met: ##
## ##
## * Redistributions of source code must retain the above copyright ##
## notice, this list of conditions and the following disclaimer. ##
## * Redistributions in binary form must reproduce the above ##
## copyright notice, this list of conditions and the following ##
## disclaimer in the documentation and/or other materials provided ##
## with the distribution. ##
## * Neither the name of the Visiprise Software, Inc nor the names ##
## of its contributors may be used to endorse or promote products ##
## derived from this software without specific prior written ##
## permission. ##
## ##
## THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS ##
## "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT ##
## LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS ##
## FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE ##
## COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, ##
## INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, ##
## BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; ##
## LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER ##
## CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT ##
## LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ##
## ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE ##
## POSSIBILITY OF SUCH DAMAGE. ##
## ##
###############################################################################
package require Tcl 8.6-
package require WS::Utils
package require html
package require log
package require tdom 0.8-
package provide WS::Server 3.5.0
namespace eval ::WS::Server {
array set ::WS::Server::serviceArr {}
set ::WS::Server::procInfo {}
set ::WS::Server::mode {}
}
###########################################################################
#
# Public Procedure Header - as this procedure is modified, please be sure
# that you update this header block. Thanks.
#
#>>BEGIN PUBLIC<<
#
# Procedure Name : ::WS::Server::Service
#
# Description : Declare a Web Service, the following URLs will exist
# /service/<ServiceName>
# Displays an HTML page describing the service
# /service/<ServiceName>/wsdl
# Returns a WSDL describing the service
# /service/<ServiceName>/op
# Invoke an operation
#
# Arguments : this procedure uses position independent arguments, they are:
# -hostcompatibility32 bool - Activate version 3.2.0 compatibility
# mode for -host parameter.
# Defaults to true.
# -host - The host specification within XML namespaces
# of the transmitted XML files.
# This should be unique.
# Defaults to localhost.
# If 3.2 compatibility is activated, the default
# value is changed to ip:port in embedded mode.
# -hostlocation - The host name, which is promoted within the
# generated WSDL file. Defaults to localhost.
# If 3.2 compatibility is activated, the
# default value is equal to the -host parameter.
# -hostlocationserver bool - If true, the host location is set by
# the current server settings.
# In case of httpd server, this value is imported.
# For other servers or if this fails, the value
# is the current ip:port.
# The default value is true.
# In case of 3.2 compatibility, the default
# value is true for tclhttpd, false otherwise.
# -hostprotocol - Define the host protocol (http, https) for the
# WSDL location URL. The special value "server"
# (default) follows the TCP/IP server specification.
# This is implemented for Embedded server and tclhttpd.
# Remark that the protocol for XML namespaces
# is always "http".
# -description - The HTML description for this service
# -service - The service name (this will also be used for
# the Tcl namespace of the procedures that implement
# the operations.
# -premonitor - This is a command prefix to be called before
# an operation is called. The following arguments are
# added to the command prefix:
# PRE serviceName operationName operArgList
# -postmonitor - This is a command prefix to be called after
# an operation is called. The following arguments are
# added to the command prefix:
# POST serviceName operationName OK|ERROR results
# -inheaders - List of input header types.
# -outheaders - List of output header types.
# -intransform - Inbound (request) transform procedure.
# -outtransform - Outbound (reply) transform procedure.
# -checkheader - Command prefix to check headers.
# If the call is not to be allowed, this command
# should raise an error.
# The signature of the command must be:
# cmd \
# service \
# operation \
# caller_ipaddr \
# http_header_list \
# soap_header_list
# -mode - Mode that service is running in. Must be one of:
# tclhttpd -- running inside of tclhttpd or an
# environment that supplies a
# compatible Url_PrefixInstall
# and Httpd_ReturnData commands
# embedded -- using the ::WS::Embedded package
# aolserver -- using the ::WS::AolServer package
# wub -- using the ::WS::Wub package
# wibble -- running inside of wibble
# rivet -- running inside Apache Rivet (mod_rivet)
# channel -- use a channel pair, WSDL is return if no XML
# otherwise an operation is called
# -ports - List of ports. Only valid for embedded and channel mode
# For chanel mode. Defaults to {stdin stdout}
# NOTE -- a call should be to
# ::WS::Channel::Start to process data
# For embedded mode. Default: 80
# NOTE -- a call should be to
# ::WS::Embedded::Listen
# for each port in this
# list prior to this call
# -prefix - Path prefix used for the namespace and endpoint
# Defaults to "/service/" plus the service name
# -traceEnabled - Boolean to enable/disable trace being passed back in exception
# Defaults to "Y"
# -docFormat - Format of the documentation for operations ("text" or "html").
# Defaults to "text"
# -stylesheet - The CSS stylesheet URL used in the HTML documentation
# -errorCallback - Callback to be invoked in the event of an error being produced
# -verifyUserArgs - Boolean to enable/disable validating user supplied arguments
# Defaults to "N"
# -enforceRequired - Throw an error if a required field is not included in the
# response.
# Defaults to "N"
#
#
# Returns : Nothing
#
# Side-Effects : None
#
# Exception Conditions :
# MISSREQARG -- Missing required arguments
#
# Pre-requisite Conditions : None
#
# Original Author : Gerald W. Lester
#
#>>END PUBLIC<<
#
# Maintenance History - as this file is modified, please be sure that you
# update this segment of the file header block by
# adding a complete entry at the bottom of the list.
#
# Version Date Programmer Comments / Changes / Reasons
# ------- ---------- ---------- -------------------------------------------
# 1 07/06/2006 G.Lester Initial version
# 2.7.0 2020-10-26 H.Oehlmann Embedded server: Do not add port 443 to default url
# 3.0.0 2020-10-30 H.Oehlmann New option -hostProtocol
# 3.2.0 2021-03-17 H.Oehlmann Add HTTP method to embedded registration.
# Change default of -checkheader from
# ::WS::Server::ok to the empty string.
# 3.4.0 2021-10-15 H.Oehlmann Rename option -hostProtocol to -hostprotocol.
# Still accept -hostProtocol.
# The logic on .hostprotocol=server is changed
# to default to http and set an update flag.
# The default value of -host in embedded mode
# is <current IP>:port. This is critial, if
# the IP changes and thus the XML namespace.
# If the old WSDL with old IP is used, there
# are no input parameters recognized, as the
# XML namespace has changed.
# In consequence, a new parameter set including
# options -host, -hostlocation, -hostlocationserver
# and -hostcompatibility32 is defined as
# described above.
#
###########################################################################
proc ::WS::Server::Service {args} {
variable serviceArr
variable procInfo
variable mode
::log::logsubst debug {Defining Service as $args}
set defaults [dict create\
-checkheader {}\
-inheaders {}\
-outheaders {}\
-intransform {}\
-outtransform {}\
-htmlhead {TclHttpd Based Web Services}\
-author {}\
-description {}\
-mode {tclhttpd}\
-ports {80}\
-traceEnabled {Y}\
-docFormat {text}\
-stylesheet {}\
-beautifyJson {N}\
-errorCallback {}\
-verifyUserArgs {N}\
-enforceRequired {N}\
-hostcompatibility32 1]
set defaults [dict merge $defaults $args]
# Set default -ports value if mode equal channel
if { [dict get $defaults -mode] eq "channel" &&
! [dict exists $args -ports] } {
dict set defaults -ports {stdin stdout}
}
set requiredList {-service}
set missingList {}
foreach opt $requiredList {
if {![dict exists $defaults $opt]} {
lappend missingList $opt
}
}
if {[llength $missingList]} {
return \
-code error \
-errorcode [list WSSERVER MISSREQARG $missingList] \
"Missing required arguments '[join $missingList {,}]'"
}
set service [dict get $defaults -service]
if {![dict exists $defaults -prefix]} {
dict set defaults -prefix /service/$service
}
# find default host/host location
if {[dict get $defaults -hostcompatibility32]} {
##
## Version 3.2.x compatibility mode:
## -host: default value is changed to ip:port in embedded mode.
## -hostlocation : default value is equal to the -host parameter.
## -hostlocationserver: default true for tclhttpd, false otherwise.
##
if { ! [dict exists $defaults -hostlocationserver]} {
dict set defaults -hostlocationserver [expr {
[dict get $defaults -mode] eq "tclhttpd" }]
}
if {![dict exists $defaults -host]} {
if { [dict get $defaults -mode] eq "embedded" } {
set myHostLocation [MyHostLocationGet [dict get $defaults -ports]]
dict set defaults -host $myHostLocation
# Note: myHostLocation may be reused below
} else {
dict set defaults -host localhost
}
}
if { ! [dict exists $defaults -hostlocation]} {
dict set defaults -hostlocation [dict get $defaults -host]
}
} else {
##
## No Version 3.2.x compatibility mode:
## -host: defaults to localhost.
## -hostlocation : defaults to localhost.
## -hostlocationserver bool: defaults to true.
##
set defaults [dict merge \
[dict create \
-hostlocation "localhost" \
-hostlocationserver 1 \
-host "localhost"] \
$defaults]
}
# Compatibility has done its work, remove it:
dict unset defaults -hostcompatibility32
##
## Update host location server to current value if specified
##
if { [dict get $defaults -hostlocationserver] } {
if {![info exists myHostLocation]} {
set myHostLocation [MyHostLocationGet [dict get $defaults -ports]]
}
dict set defaults -hostlocation $myHostLocation
}
##
## Resolve -hostprotocol setting.
## Also accept -hostProtocol
##
if {![dict exists $defaults -hostprotocol]} {
if {[dict exists $defaults -hostProtocol]} {
dict set defaults -hostprotocol [dict get $defaults -hostProtocol]
} else {
dict set defaults -hostprotocol server
}
}
dict unset defaults -hostProtocol
##
## Resolve server protocol to http and set flag for server protocol.
## If the flag is set, the protocol is corrected when required
##
dict set defaults hostProtocolServer [expr {
[dict get $defaults -hostprotocol] eq "server"}]
if {[dict get $defaults hostProtocolServer]} {
dict set defaults -hostprotocol http
}
dict set defaults -uri $service
namespace eval ::$service {}
set serviceArr($service) $defaults
if {![dict exists $procInfo $service operationList]} {
dict set procInfo $service operationList {}
}
set mode [dict get $defaults -mode]
##
## Install wsdl doc
##
interp alias {} ::WS::Server::generateInfo_${service} \
{} ::WS::Server::generateInfo ${service}
::log::logsubst debug {Installing Generate info for $service at [dict get $defaults -prefix]}
switch -exact -- $mode {
embedded {
package require WS::Embeded
foreach port [dict get $defaults -ports] {
::WS::Embeded::AddHandler $port [dict get $defaults -prefix] GET ::WS::Server::generateInfo_${service}
}
}
tclhttpd {
::Url_PrefixInstall [dict get $defaults -prefix] ::WS::Server::generateInfo_${service} \
-thread 0
}
wub {
package require WS::Wub
}
aolserver {
package require WS::AOLserver
}
rivet {
package require Rivet
}
wibble {
##
## Define zone handler - get code from andy
##
proc ::wibble::webservice {state} {
dict with state options {}
switch -exact -- $suffix {
"" - / {
::WS::Server::generateInfo $name 0 response
sendresponse $response
} /op {
::WS::Server::callOperation $name 0 [dict get $state request] response
sendresponse $response
} /wsdl {
::WS::Server::generateWsdl $name 0 -responsename response
sendresponse $response
}
default {
## Do nothing
}
}
}
if {[package present Wibble] eq "0.1"} {
proc ::WS::Wibble::ReturnData {responseDictVar type text status} {
upvar 1 $responseDictVar responseDict
dict set responseDict header content-type $type
dict set responseDict content $text
dict set responseDict status $status
}
} else {
proc ::WS::Wibble::ReturnData {responseDictVar type text status} {
upvar 1 $responseDictVar responseDict
dict set responseDict header content-type "" $type
dict set responseDict content $text
dict set responseDict status $status
}
}
::wibble::handle [dict get $defaults -prefix] webservice name $service
}
default {
return \
-code error \
-errorcode [list WSSERVER UNSUPMODE $mode] \
"-mode '$mode' not supported"
}
}
##
## Install wsdl
##
interp alias {} ::WS::Server::generateWsdl_${service} \
{} ::WS::Server::generateWsdl ${service}
::log::logsubst debug {Installing GenerateWsdl info for $service at [dict get $defaults -prefix]/wsdl}
switch -exact -- $mode {
embedded {
foreach port [dict get $defaults -ports] {
::WS::Embeded::AddHandler $port [dict get $defaults -prefix]/wsdl GET ::WS::Server::generateWsdl_${service}
}
}
channel {
package require WS::Channel
::WS::Channel::AddHandler [dict get $defaults -ports] {} ::WS::Server::generateWsdl_${service}
}
tclhttpd {
::Url_PrefixInstall [dict get $defaults -prefix]/wsdl ::WS::Server::generateWsdl_${service} \
-thread 0
}
default {
## Do nothing
}
}
##
## Install operations
##
interp alias {} ::WS::Server::callOperation_${service} \
{} ::WS::Server::callOperation ${service}
::log::logsubst debug {Installing callOperation info for $service at [dict get $defaults -prefix]/op}
switch -exact -- $mode {
embedded {
foreach port [dict get $defaults -ports] {
::WS::Embeded::AddHandler $port [dict get $defaults -prefix]/op POST ::WS::Server::callOperation_${service}
}
}
channel {
package require WS::Channel
::WS::Channel::AddHandler [dict get $defaults -ports] {op} ::WS::Server::callOperation_${service}
}
tclhttpd {
::Url_PrefixInstall [dict get $defaults -prefix]/op ::WS::Server::callOperation_${service} \
-thread 1
}
default {
## Do nothing
}
}
return
}
# Get my computers IP address
proc ::WS::Server::MyHostLocationGet {ports} {
if {[catch {
set me [socket -server garbage_word -myaddr [info hostname] 0]
set myHostLocation [lindex [fconfigure $me -sockname] 0]
close $me
} errorMessage]} {
::log::logsubst error {Error '$errorMessage' when querying my own IP\
address. Use 'localhost' instead.}
set myHostLocation "localhost"
}
if { 0 !=[llength $ports] && [lindex $ports 0] ni {80 433} } {
append myHostLocation ":[lindex $ports 0]"
}
return $myHostLocation
}
###########################################################################
#
# Public Procedure Header - as this procedure is modified, please be sure
# that you update this header block. Thanks.
#
#>>BEGIN PUBLIC<<
#
# Procedure Name : ::WS::Server::ServiceProc
#
# Description : Register an operation for a service and declare the procedure to handle
# the operations.
#
# Arguments :
# ServiceName -- Name of the service this operation is for
# NameInfo -- List of four elements:
# 1) OperationName -- the name of the operation
# 2) ReturnType -- the type of the procedure return,
# this can be a simple or complex type
# 3) Description -- description of the return method
# 4) Version -- optional version for the service
# if ommitted then available in all versions
# Arglist -- List of argument definitions,
# each list element must be of the form:
# 1) ArgumentName -- the name of the argument
# 2) ArgumentTypeInfo -- A list of:
# {type typeName comment commentString version versionCode}
# typeName can be any simple or defined type.
# commentString is a quoted string describing the field.
# versionCode is the version which this argument is available for
# Documentation -- HTML describing what this operation does
# Body -- The tcl code to be called when the operation is invoked. . This
# code should return a dictionary with <OperationName>Result as a
# key and the operation's result as the value.
#
# Returns : Nothing
#
# Side-Effects :
# A procedure named "<ServiceName>::<OperationName>" defined
# A type name with the name <OperationName>Result is defined.
#
# Exception Conditions : None
#
# Pre-requisite Conditions : ::WS::Server::Server must have been called for the ServiceName
#
# Original Author : Gerald W. Lester
#
#>>END PUBLIC<<
#
# Maintenance History - as this file is modified, please be sure that you
# update this segment of the file header block by
# adding a complete entry at the bottom of the list.
#
# Version Date Programmer Comments / Changes / Reasons
# ------- ---------- ---------- -------------------------------------------
# 1 07/06/2006 G.Lester Initial version
#
#
###########################################################################
proc ::WS::Server::ServiceProc {service nameInfo arglist documentation body} {
variable procInfo
set name [lindex $nameInfo 0]
set version [expr {[llength $nameInfo] > 3 ? [lindex $nameInfo 3] : {}}]
::log::logsubst debug {Defining operation $name for $service}
set argOrder {}
::log::logsubst debug {\targs are {$arglist}}
foreach {arg data} $arglist {
lappend argOrder $arg
}
if {![dict exists $procInfo $service op$name argList]} {
set tmpList [dict get $procInfo $service operationList]
lappend tmpList $name
dict set procInfo $service operationList $tmpList
}
dict set procInfo $service op$name argList $arglist
dict set procInfo $service op$name argOrder $argOrder
dict set procInfo $service op$name docs $documentation
dict set procInfo $service op$name returnInfo [lindex $nameInfo 1]
set typeInfo [dict get $procInfo $service op$name returnInfo]
dict set procInfo $service op$name version $version
::WS::Utils::ServiceTypeDef Server $service ${name}Results [list ${name}Result $typeInfo] {} {} $version
::WS::Utils::ServiceTypeDef Server $service ${name}Request $arglist {} {} $version
set tclArgList [list]
foreach {arg typeinfo} $arglist {
lappend tclArgList [list [lindex $arg 0] ""]
}
lappend tclArgList [list tclws_op_version ""]
proc ::${service}::${name} $tclArgList $body
}
###########################################################################
#
# Private Procedure Header - as this procedure is modified, please be sure
# that you update this header block. Thanks.
#
#>>BEGIN PRIVATE<<
#
# Procedure Name : ::WS::Server::GetWsdl
#
# Description : Generates a WSDL for a registered service.
#
# Arguments :
# serviceName - The name of the service
# urlPrefix - (optional) Prefix to use for location; defaults to http://<host>
# version - (optional) specific version of service to generate. If ommitted
# then returns the lastest
#
# Returns :
# XML for the WSDL
#
# Side-Effects : None
#
# Exception Conditions :
# WS SERVER UNKSERV - Unknown service name
#
# Pre-requisite Conditions : None
#
# Original Author : Gerald W. Lester
#
#>>END PRIVATE<<
#
# Maintenance History - as this file is modified, please be sure that you
# update this segment of the file header block by
# adding a complete entry at the bottom of the list.
#
# Version Date Programmer Comments / Changes / Reasons
# ------- ---------- ---------- -------------------------------------------
# 1 07/06/2006 G.Lester Initial version
# 2 12/12/2009 W.Kocjan Support for services over SSL in Tclhttpd
# 3 11/13/2018 J.Cone Version support
# 2.7.0 2020-10-26 H.Oehlmann urlPrefix is a mandatory parameter.
# The caller has to think about it.
# 3.3.0 2021-10-15 H.Oehlmann Build default location from options
# -hostprotocol and -hostlocation replacing
# http and option -host.
#
#
###########################################################################
proc ::WS::Server::GetWsdl {serviceName {urlPrefix ""} {version {}}} {
variable serviceArr
variable procInfo
set serviceData $serviceArr($serviceName)
set operList {}
foreach oper [lsort -dictionary [dict get $procInfo $serviceName operationList]] {
if {$version ne {} && [dict exists $procInfo $serviceName op$oper version]
&& ![::WS::Utils::check_version [dict get $procInfo $serviceName op$oper version] $version]} {
continue
}
lappend operList $oper
}
::log::logsubst debug {Generating WSDL for $serviceName}
if {![info exists serviceArr($serviceName)]} {
set msg "Unknown service '$serviceName'"
::return \
-code error \
-errorCode [list WS SERVER UNKSERV $serviceName] \
$msg
}
set msg {}
set reply [::dom createDocument wsdl:definitions]
$reply documentElement definition
$definition setAttribute \
xmlns:wsdl "http://schemas.xmlsoap.org/wsdl/" \
xmlns:http "http://schemas.xmlsoap.org/wsdl/http/" \
xmlns:mime "http://schemas.xmlsoap.org/wsdl/mime/" \
xmlns:xs "http://www.w3.org/2001/XMLSchema" \
xmlns:soap "http://schemas.xmlsoap.org/wsdl/soap/" \
xmlns:soapenc "http://schemas.xmlsoap.org/soap/encoding/" \
xmlns:${serviceName} "http://[dict get $serviceData -host][dict get $serviceData -prefix]" \
targetNamespace "http://[dict get $serviceData -host][dict get $serviceData -prefix]"
foreach topLevel {types} {
$definition appendChild [$reply createElement wsdl:$topLevel $topLevel]
}
##
## Messages
##
## Operations
foreach oper $operList {
$definition appendChild [$reply createElement wsdl:message input]
$input setAttribute name ${oper}In
$input appendChild [$reply createElement wsdl:part part]
$part setAttribute \
name parameters \
element ${serviceName}:${oper}Request
$definition appendChild [$reply createElement wsdl:message output]
$output setAttribute name ${oper}Out
$output appendChild [$reply createElement wsdl:part part]
$part setAttribute \
name parameters \
element ${serviceName}:${oper}Results
}
## Input headers
foreach headerType [dict get $serviceData -inheaders] {
$definition appendChild [$reply createElement wsdl:message header]
$header setAttribute name $headerType
$header appendChild [$reply createElement wsdl:part part]
$part setAttribute \
name parameters \
element ${serviceName}:${headerType}
}
## Output headers
foreach headerType [dict get $serviceData -outheaders] {
$definition appendChild [$reply createElement wsdl:message header]
$header setAttribute name $headerType
$header appendChild [$reply createElement wsdl:part part]
$part setAttribute \
name parameters \
element ${serviceName}:${headerType}
}
##
## Add the rest of the toplevels in
##
foreach topLevel {portType binding service} {
$definition appendChild [$reply createElement wsdl:$topLevel $topLevel]
}
##
## Service
##
$service setAttribute name $serviceName
$service appendChild [$reply createElement wsdl:documentation documentation]
$documentation appendChild [$reply createTextNode [dict get $serviceData -description]]
$service appendChild [$reply createElement wsdl:port port]
$port setAttribute \
name ${serviceName}Soap \
binding ${serviceName}:${serviceName}Soap
$port appendChild [$reply createElement soap:address address]
if {$urlPrefix == ""} {
set urlPrefix "[dict get $serviceData -hostprotocol]://[dict get $serviceData -hostlocation]"
}
$address setAttribute \
location "$urlPrefix[dict get $serviceData -prefix]/op"
##
## Bindings
##
$binding setAttribute \
name ${serviceName}Soap \
type ${serviceName}:${serviceName}Soap
$binding appendChild [$reply createElement soap:binding b2]
$b2 setAttribute \
style document \
transport "http://schemas.xmlsoap.org/soap/http"
foreach oper $operList {
$binding appendChild [$reply createElement wsdl:operation operNode]
$operNode setAttribute name $oper
$operNode appendChild [$reply createElement soap:operation o2]
$o2 setAttribute \
soapAction $serviceName:$oper \
style document
## Input message
$operNode appendChild [$reply createElement wsdl:input input]
$input appendChild [$reply createElement soap:body tmp]
$tmp setAttribute use literal
foreach headerType [dict get $serviceData -inheaders] {
$operNode appendChild [$reply createElement wsdl:header header]
$header appendChild [$reply createElement soap:header tmp]
$tmp setAttribute \
use literal \
message ${serviceName}:${headerType} \
part $headerType
}
## Output message
$operNode appendChild [$reply createElement wsdl:output output]
$output appendChild [$reply createElement soap:body tmp]
$tmp setAttribute use literal
foreach headerType [dict get $serviceData -outheaders] {
$operNode appendChild [$reply createElement wsdl:header header]
$header appendChild [$reply createElement soap:header tmp]
$tmp setAttribute \
use literal \
message ${serviceName}:${headerType} \
part $headerType
}
}
##
## Ports
##
$portType setAttribute name ${serviceName}Soap
foreach oper $operList {
$portType appendChild [$reply createElement wsdl:operation operNode]
$operNode setAttribute name $oper
$operNode appendChild [$reply createElement wsdl:input input]
$input setAttribute message ${serviceName}:${oper}In
$operNode appendChild [$reply createElement wsdl:output output]
$output setAttribute message ${serviceName}:${oper}Out
}
##
## Types
##
GenerateScheme Server $serviceName $reply $types $version
append msg \
{<?xml version="1.0" encoding="utf-8"?>} \
"\n" \
[$reply asXML \
-indent 4 \
-escapeNonASCII \
-doctypeDeclaration 0 \
]
$reply delete
return $msg
}
###########################################################################
#
# Private Procedure Header - as this procedure is modified, please be sure
# that you update this header block. Thanks.
#
#>>BEGIN PRIVATE<<
#
# Procedure Name : ::WS::Server::generateWsdl
#
# Description : Generates a WSDL for a registered service.
#
# Arguments :
# serviceName - The name of the service
# sock - The socket to return the WSDL on
# args - Multi-function depending on server:
# embedded: -port number: embedded server port number
# unknown server: -version number: version
# wibble: -responsename name: response variable name
#
# Returns :
# Embedded mode: return list of contentType, message, httpcode
# Other modes: 1 - On error, 0 - On success
#
# Side-Effects : None
#
# Exception Conditions : None
#
# Pre-requisite Conditions : None
#
# Original Author : Gerald W. Lester
#
#>>END PRIVATE<<
#
# Maintenance History - as this file is modified, please be sure that you
# update this segment of the file header block by
# adding a complete entry at the bottom of the list.
#
# Version Date Programmer Comments / Changes / Reasons
# ------- ---------- ---------- -------------------------------------------
# 1 07/06/2006 G.Lester Initial version
# 2 12/12/2009 W.Kocjan Support for services over SSL in Tclhttpd
# 3 11/13/2018 J.Cone Version support
# 2.7.0 2020-10-26 H.Oehlmann Support https for embedded server.
# 3.1.0 2020-11-06 H.Oehlmann Pass port parameter from embedded server
# with prefix "-port" to be compatible with
# the -version parameter.
# Pass wibble responsename also with prefix
# "-responsename".
# 3.2.0 2021-03-17 H.Oehlmann In embedded mode, directly return the data
# 3.3.0 2021-10-15 H.Oehlmann Change the setting/update of the host location
# by using the new parameter -hostlocationserver
# and -hostlocation.
#
###########################################################################
proc ::WS::Server::generateWsdl {serviceName sock args} {
variable serviceArr
variable procInfo
variable mode
set operList [lsort -dictionary [dict get $procInfo $serviceName operationList]]
::log::logsubst debug {Generating WSDL for $serviceName on $sock with {$args}}
# ToDo HaO 2020-11-06: if confirmed, args may be interpreted as a dict
# and the code may be simplified. It is not clear, if any server does not
# pass any unused data not being a dict.
set version ""
set argsIdx [lsearch -exact $args "-version"]
if {$argsIdx != -1} {
set version [lindex $args [expr {$argsIdx + 1}]]
}
if {![info exists serviceArr($serviceName)]} {
set msg "Unknown service '$serviceName'"
switch -exact -- $mode {
tclhttpd {
::Httpd_ReturnData \
$sock \
"text/html; charset=UTF-8" \
"<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>" \
404
}
embedded {
return [list\
"text/html; charset=UTF-8" \
"<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>" \
404]
}
channel {
::WS::Channel::ReturnData \
$sock \
"text/xml; charset=UTF-8" \
"<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>" \
404
}
rivet {
headers type "text/html; charset=UTF-8"
headers numeric 404
puts "<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>"
}
aolserver {
::WS::AOLserver::ReturnData \
$sock \
text/html \
"<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>" \
404
}
wibble {
upvar 1 [lindex $args 0] responseDict
::WS::Wibble::ReturnData responseDict text/html "<html><head><title>Webservice Error</title></head><body><h2>$msg</h2></body></html>" 404
}
default {
## Do nothing
}
}
return 1
}
set serviceData $serviceArr($serviceName)
##
## Check if the server protocol (and host) should be used
##
##
## Prepare default URL prefix
##
set urlPrefix "[dict get $serviceData -hostprotocol]://[dict get $serviceData -hostlocation]"
##
## Return the WSDL
##
switch -exact -- $mode {
tclhttpd {
upvar #0 ::Httpd$sock s
# Get protocol and host location from server if configured
if { [dict get $serviceData hostProtocolServer] } {
catch {
dict set serviceData -hostprotocol [lindex $s(self) 0]
}
}
if { [dict get $serviceData -hostlocationserver] } {
catch {
dict set serviceData -hostprotocol $s(mime,host)
}
}
set urlPrefix [dict get $serviceData -hostprotocol]://[dict get $serviceData -hostlocation]
set xml [GetWsdl $serviceName $urlPrefix $version]
::Httpd_ReturnData $sock "text/xml; charset=UTF-8" $xml 200
}
channel {
set xml [GetWsdl $serviceName $urlPrefix $version]
::WS::Channel::ReturnData $sock "text/xml; charset=UTF-8" $xml 200
}
embedded {
if {[dict get $serviceData hostProtocolServer]} {
##
## For https, change the URL prefix
##
set argsIdx [lsearch -exact $args "-port"]
if {$argsIdx == -1} {
::log::logsubst error {Parameter '-port' missing from\
embedded server in arguments '$args'}
} elseif { [::WS::Embeded::GetValue isHTTPS\
[lindex $args [expr {$argsIdx + 1}]]]
} {
dict set serviceData -hostprotocol https
} else {
dict set serviceData -hostprotocol http
}
set urlPrefix "[dict get $serviceData -hostprotocol]://[dict get $serviceData -hostlocation]"
}
set xml [GetWsdl $serviceName $urlPrefix $version]
return [list "text/xml; charset=UTF-8" $xml 200]
}
rivet {
set xml [GetWsdl $serviceName $urlPrefix $version]
headers type "text/xml; charset=UTF-8"
headers numeric 200
puts $xml
}
aolserver {
set xml [GetWsdl $serviceName $urlPrefix $version]
::WS::AOLserver::ReturnData $sock text/xml $xml 200
}