forked from GNOME/gimp
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathmeson.build
1688 lines (1366 loc) · 50.8 KB
/
meson.build
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
project('gimp',
'c', 'cpp',
version: '2.99.1',
meson_version: '>=0.50.0',
default_options: [
'cpp_std=gnu++14',
],
)
project_url = 'https://gitlab.gnome.org/GNOME/gimp'
project_url_issues = project_url + '/issues/new'
conf = configuration_data()
warnings = []
################################################################################
# Project info
prettyname = 'GIMP'
full_name = 'GNU Image Manipulation Program'
# General version
gimp_version = meson.project_version()
package_string= prettyname + ' ' + gimp_version
gimp_app_version_arr = gimp_version.split('.')
gimp_app_version_major = gimp_app_version_arr[0].to_int()
gimp_app_version_minor = gimp_app_version_arr[1].to_int()
gimp_app_version_micro = gimp_app_version_arr[2].to_int()
# Override for Release-candidates
gimp_app_version = '@0@.@1@'.format(
gimp_app_version_major,
gimp_app_version_minor
)
# API & pkg-config version
api_version_major = gimp_app_version_major
api_version_minor = gimp_app_version_minor
if api_version_minor == 99
api_version_major += 1
api_version_minor = 0
endif
gimp_api_version = '@0@.@1@'.format(api_version_major, api_version_minor)
gimp_api_name = 'gimp-' + gimp_api_version
gimp_command = 'gimp-' + gimp_app_version
gettext_package= 'gimp@0@@1@'.format(api_version_major, api_version_minor)
conf.set_quoted('GETTEXT_PACKAGE', gettext_package)
conf.set_quoted('GIMP_VERSION', gimp_version)
stable = (gimp_app_version_minor % 2 == 0)
conf.set10('GIMP_UNSTABLE', not stable)
versionconfig = configuration_data()
versionconfig.set('GIMP_FULL_NAME', full_name)
versionconfig.set('GIMP_MAJOR_VERSION', gimp_app_version_major)
versionconfig.set('GIMP_MINOR_VERSION', gimp_app_version_minor)
versionconfig.set('GIMP_MICRO_VERSION', gimp_app_version_micro)
versionconfig.set('GIMP_VERSION', gimp_version)
versionconfig.set('GIMP_API_VERSION', gimp_api_version)
# Libtool versioning
gimp_interface_age = 0
lt_current = 0
lt_revision = gimp_app_version_micro
lt_age = 100*api_version_minor + 0
so_version = '@0@.@1@.@2@'.format(lt_current, lt_age, lt_revision)
################################################################################
# Get configuration and Meson modules
pkgconfig = import('pkgconfig')
i18n = import('i18n')
gnome = import('gnome')
pythonmod = import('python')
cc = meson.get_compiler('c')
cxx = meson.get_compiler('cpp')
prefix = get_option('prefix')
buildtype = get_option('buildtype')
compiler_args = []
linker_args = []
################################################################################
# Host system detection
cpu = host_machine.cpu().to_lower()
arch_x86_64 = (cpu == 'x86_64')
arch_x86 = (cpu.startswith('i') and cpu.endswith('86')) or arch_x86_64
arch_ppc64 = (cpu == 'ppc64' or cpu == 'powerpc64')
arch_ppc = (cpu == 'ppc' or cpu == 'powerpc') or arch_ppc64
if not (arch_x86 or arch_ppc)
error('Unknown host architecture')
endif
conf.set10('ARCH_X86', arch_x86)
conf.set10('ARCH_X86_64', arch_x86_64)
conf.set10('ARCH_PPC', arch_ppc)
conf.set10('ARCH_PPC64', arch_ppc64)
host_os = host_machine.system().to_lower()
message('Host os: ' + host_os)
platform_linux = (
host_os.contains('linux')
)
platform_windows = (
host_os.contains('mingw') or
host_os.contains('cygwin') or
host_os.contains('windows')
)
platform_osx = (
host_os.contains('machten') or
host_os.contains('rhapsody') or
host_os.contains('darwin')
)
conf.set('PLATFORM_OSX', platform_osx)
if platform_windows
windows = import('windows')
# AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
# AM_CONDITIONAL(MS_LIB_AVAILABLE, test "x$ms_librarian" = xyes)
# compiler_args += '-Wl,--large-address-aware'
endif
if cc.get_id() == 'gcc' and cc.version() == '7.2.0'
gcc_warning = '''
GCC 7.2.0 has a serious bug affecting GEGL/GIMP. We advise
against using this version of the compiler (previous and
further versions are fine).
See https://bugzilla.gnome.org/show_bug.cgi?id=787222
'''
warning(gcc_warning)
warnings += gcc_warning
endif
################################################################################
# Compiler CPU extensions for optimizations
if (get_option('buildtype') == 'release' or
get_option('buildtype') == 'debugoptimized')
# Check for compiler CPU extensions
existing_cpu_exts = [
'-mfpmath=sse',
'-mmmx',
'-msse',
'-msse2',
'-msse4.1',
]
supported_cpu_exts = cc.get_supported_arguments(existing_cpu_exts)
compiler_args += supported_cpu_exts
conf.set ('USE_MMX', '-mmmx' in supported_cpu_exts)
conf.set ('USE_SSE', '-msse' in supported_cpu_exts)
conf.set10('COMPILE_SSE2_INTRINISICS', '-msse2' in supported_cpu_exts)
conf.set10('COMPILE_SSE4_1_INTRINISICS','-msse4.1' in supported_cpu_exts)
have_altivec = false
have_altivec_sysctl = false
if arch_ppc
altivec_args = cc.get_supported_arguments([
'-faltivec',
'-maltivec',
'-mabi=altivec',
])
if altivec_args != []
compiler_args += altivec_args
linker_args += altivec_args
if host_os.contains('darwin')
have_altivec = true
have_altivec_sysctl = true
elif cc.compiles('''
int main() { asm ("vand %v0, %v0, %v0"); return 0; }
''')
have_altivec = true
endif
endif
endif
conf.set('HAVE_ALTIVEC_SYSCTL', have_altivec_sysctl)
conf.set('USE_ALTIVEC', have_altivec)
endif
################################################################################
# CFlags
if get_option('profiling') and cc.get_id() == 'gcc'
compiler_args += '-pg'
linker_args += '-pg'
endif
if get_option('ansi')
compiler_args += [ '-ansi', '-pedantic']
endif
warning_cflags_common = [
'-fdiagnostics-show-option',
'-fno-common',
'-Wformat-security',
'-Winit-self',
'-Wlogical-op',
'-Wmissing-declarations',
'-Wmissing-format-attribute',
'-Wpointer-arith',
'-Wreturn-type',
'-Wtype-limits',
# You can uncomment this to debug with less warning outputs
'-Wno-deprecated-declarations',
]
warning_cflags_c = [
'-Wdeclaration-after-statement',
'-Wold-style-definition',
'-Wno-strict-prototypes',
'-Werror=implicit-function-declaration',
]
warning_cflags_cpp = [
]
compiler_args += cc.get_supported_arguments(warning_cflags_common)
add_project_arguments(cc .get_supported_arguments(warning_cflags_c), language: 'c')
add_project_arguments(cxx.get_supported_arguments(warning_cflags_cpp), language: 'cpp')
# Ensure MSVC-compatible struct packing convention is used when
# compiling for Win32 with gcc.
if platform_windows and cc.get_id() == 'gcc'
msvc_compat_args = cc.first_supported_argument([
'-fnative-struct',
'-mms-bitfields',
])
if msvc_compat_args == []
error('''
GCC does not support '-fnative-struct' nor '-mms-bitfields'.
Build will be incompatible with GTK+ DLLs.
''')
endif
compiler_args += msvc_compat_args
endif
conf.set('HAVE__NL_MEASUREMENT_MEASUREMENT',
cc.compiles('''
#include<langinfo.h>
int main() {
char c = *((unsigned char *) nl_langinfo(_NL_MEASUREMENT_MEASUREMENT));
}
''')
)
################################################################################
# Dependencies
no_dep = dependency('', required: false)
################################################################################
# Mandatory Dependencies
if get_option('relocatable-bundle').enabled()
relocatable_bundle = true
elif get_option('relocatable-bundle').disabled()
relocatable_bundle = false
else # .auto()
# By default, assume building for Windows or macOS everything to be on
# the same prefix and can be relocated.
# On other platforms, build-time paths are meaningful.
if platform_windows or platform_osx
relocatable_bundle = true
else
relocatable_bundle = false
endif
endif
conf.set('ENABLE_RELOCATABLE_RESOURCES', relocatable_bundle)
math = cc.find_library('m')
dl = platform_windows ? no_dep : cc.find_library('dl')
rpc = platform_windows ? cc.find_library('rpcrt4') : no_dep
dbghelp = platform_windows ? cc.find_library('dbghelp') : no_dep
winsock = platform_windows ? cc.find_library('ws2_32') : no_dep
atk = dependency('atk', version: '>=2.4.0')
babl = dependency('babl', version: '>=0.1.72')
cairo = dependency('cairo', version: '>=1.12.2')
dbus_glib = dependency('dbus-glib-1')
# fontconfig_name = platform_windows ? 'fontconfig_win32' : 'fontconfig'
fontconfig_name = 'fontconfig'
fontconfig = dependency(fontconfig_name, version: '>=2.12.4')
freetype2 = dependency('freetype2', version: '>=2.1.7')
gdk_pixbuf = dependency('gdk-pixbuf-2.0', version: '>=2.30.8')
gegl = dependency('gegl-0.4', version: '>=0.4.17')
gexiv2 = dependency('gexiv2', version: '>=0.10.6')
gio = dependency('gio-2.0')
gio_specific_name = platform_windows ? 'gio-windows-2.0' : 'gio-unix-2.0'
gio_specific = dependency(gio_specific_name)
glib_version = platform_windows ? '>=2.56.2' : '>=2.54.2'
glib = dependency('glib-2.0', version: glib_version)
conf.set('G_DISABLE_DEPRECATED', glib.version().version_compare('>=2.57'))
gobject = dependency('gobject-2.0', version: '>=2.54.2')
gmodule = dependency('gmodule-no-export-2.0')
gtk3 = dependency('gtk+-3.0', version: '>=3.16.10')
harfbuzz = dependency('harfbuzz', version: '>=0.9.19')
lcms = dependency('lcms2', version: '>=2.8')
libmypaint = dependency('libmypaint', version: '>=1.3.0')
mypaint_brushes = dependency('mypaint-brushes-1.0', version: '>=1.3.0')
if relocatable_bundle
mypaint_brushes_dir = '${gimp_installation_dir}'/'share'/'mypaint-data'/'1.0'/'brushes'
else
mypaint_brushes_dir = mypaint_brushes.get_pkgconfig_variable('brushesdir')
endif
conf.set_quoted('MYPAINT_BRUSHES_DIR', mypaint_brushes_dir)
pangocairo = dependency('pangocairo', version: '>=1.29.4')
pangoft2 = dependency('pangoft2', version: '>=1.29.4')
rsvg = dependency('librsvg-2.0', version: '>=2.40.6')
conf.set('PANGO_DISABLE_DEPRECATED',pangocairo.version().version_compare('<1.43'))
################################################################################
# Check for GLib Networking
glib_networking_works_run=false
if meson.is_cross_build() and not meson.has_exe_wrapper()
# Cross-compilation without run capability: we won't be able to
# check networking support.
glib_networking_works = true
glib_warning = '''
Test for glib-networking cannot be performed while cross-compiling,
unless you set an `exe_wrapper` binary in your toolchain file.
Make sure glib-networking is installed, otherwise GIMP will not be able
to display the remote help pages through the help browser, nor will it
be able to open remote HTTPS (or other protocol using SSL/TLS) files.
HTTPS is becoming the expected standard and should not be considered
optional anymore.
'''
warning(glib_warning)
warnings += glib_warning
else # not meson.is_cross_build() or meson.has_exe_wrapper()
glib_networking_works_run = cc.run(
'''#include <gio/gio.h>
int main() {
return !g_tls_backend_supports_tls (g_tls_backend_get_default ());
}''',
dependencies: gio,
)
glib_networking_works = (glib_networking_works_run.compiled() and
glib_networking_works_run.returncode() == 0)
if not glib_networking_works and meson.is_cross_build()
# Since cross-platform test runs may be unreliable, let's be
# flexible and pass the test with a warning.
glib_networking_works = true
glib_warning = '''
The cross-platform test for glib-networking failed, using the
`exe_wrapper` set in your toolchain file.
Make sure glib-networking is installed, otherwise GIMP will not be able
to display the remote help pages through the help browser, nor will it
be able to open remote HTTPS (or other protocol using SSL/TLS) files.
HTTPS is becoming the expected standard and should not be considered
optional anymore.
'''
warning(glib_warning)
warnings += glib_warning
endif
endif
if not glib_networking_works
error('Test for glib-networking failed. This is required.')
endif
################################################################################
# Check if Pango is built with a recent fontconfig
pango_check = cc.links(
'''#include <fontconfig/fontconfig.h>
int main() {
FcObjectSet *os; os = FcObjectSetBuild (FC_FAMILY, FC_WIDTH);
}''',
dependencies: fontconfig,
)
if not pango_check
pango_warning = '\n *** '.join([
'You have a fontconfig >= fontconfig_required_version installed on your',
'system, but your Pango library is using an older version. This old version',
'is probably in /usr/X11R6. Look at the above output, and note that the',
'result for FONTCONFIG_CFLAGS is not in the result for PANGOCAIRO_CFLAGS,',
'and that there is likely an extra -I line, other than the ones for GLIB,',
'Freetype, and Pango itself. That\'s where your old fontconfig files are.',
'Rebuild pango, and make sure that it uses the newer fontconfig.',
'The easiest way be sure of this is to simply get rid of the old',
'fontconfig. When you rebuild pango, make sure the result for',
'FONTCONFIG_CFLAGS is the same as the result here.',
])
warning(pango_warning)
warnings += pango_warning
endif
################################################################################
# Optional Dependencies
libsocket = cc.find_library('socket', required: false)
conf.set('HAVE_LIBSOCKET', libsocket.found())
################################################################################
# Check for extension support
appstream_glib = dependency('appstream-glib', version: '>=0.7.7')
libarchive = dependency('libarchive')
################################################################################
# Check for debug console (Win32)
if platform_windows
conf.set('ENABLE_WIN32_DEBUG_CONSOLE', get_option('win32-debug-console'))
endif
################################################################################
# Check for 32-bit DLLs (Win32 64-bit)
if platform_windows and arch_x86_64
conf.set_quoted('WIN32_32BIT_DLL_FOLDER', get_option('win32-32bits-dll-folder'))
endif
################################################################################
# Check for detailed backtraces support
## Check for libbacktrace
if get_option('libbacktrace')
libbacktrace = cc.find_library('backtrace', required: false)
if libbacktrace.found()
libbacktrace_links = cc.links('''
#include <stddef.h>
#include <backtrace.h>
#include <backtrace-supported.h>
#if ! BACKTRACE_SUPPORTED
# error ! BACKTRACE_SUPPORTED
#endif
int main() {
(void) backtrace_create_state (NULL, 0, NULL, NULL);
return 0;
}
''',
dependencies: libbacktrace,
)
if not libbacktrace_links
warning(
'libbacktrace was found, but the test compilation failed.\n' +
'You can find more info in meson-logs/meson-logs.txt.'
)
libbacktrace = no_dep
endif
endif
else
libbacktrace = no_dep
endif
conf.set('HAVE_LIBBACKTRACE', libbacktrace.found())
## Check for libunwind
libunwind = ( get_option('libunwind')
? dependency('libunwind', version: '>=1.1.0', required: false)
: no_dep
)
conf.set('HAVE_LIBUNWIND', libunwind.found())
## Check for Dr. Mingw
drmingw = no_dep
if platform_windows
exchndl = cc.find_library('exchndl', required: false)
exchndl_fn = cc.has_function('ExcHndlSetLogFileNameA', dependencies: exchndl)
if exchndl.found() and exchndl_fn
drmingw = declare_dependency(dependencies: exchndl)
endif
endif
conf.set('HAVE_EXCHNDL', drmingw.found())
detailed_backtraces = (
libbacktrace.found() or
libunwind.found() or
drmingw.found()
)
################################################################################
# Check for x11 support
x11_target = gtk3.get_pkgconfig_variable('targets').contains('x11')
x11 = x11_target ? dependency('x11') : no_dep
xmu = x11_target ? dependency('xmu') : no_dep
xext = x11_target ? dependency('xext') : no_dep
xfixes= x11_target ? dependency('xfixes') : no_dep
x11_deps = [ x11, xmu, xext, xfixes ]
conf.set('HAVE_XFIXES', xfixes.found())
if x11_target
foreach header : [ 'X11/Xmu/WinUtil.h', 'X11/extensions/shape.h', ]
if not cc.has_header(header, dependencies: [ xext, xmu ])
error('x11 install does not provide required header ' + header)
endif
endforeach
foreach function : [ 'XmuClientWindow', 'XShapeGetRectangles', ]
if not cc.has_function(function, dependencies: [ xext, xmu ])
error('x11 install does not provide required function ' + function)
endif
endforeach
endif
conf.set('HAVE_X11_EXTENSIONS_SHAPE_H', x11_target and cc.has_header('X11/extensions/shape.h'))
conf.set('HAVE_X11_XMU_WINUTIL_H', x11_target and cc.has_header('X11/Xmu/WinUtil.h'))
# Features requiring x11
have_doc_shooter= x11_target
if get_option('print').disabled()
have_print = false
elif get_option('print').enabled() and not x11_target
error('Printing requires x libs')
else
have_print = x11_target
endif
if get_option('screenshot').disabled()
have_screenshot = false
elif get_option('screenshot').enabled() and not x11_target
error('Printing requires x libs')
else
have_screenshot = x11_target
endif
################################################################################
# Plugins (optional dependencies)
# The list of MIME types that are supported by plug-ins
MIMEtypes = [
'image/bmp',
'image/g3fax',
'image/gif',
'image/svg+xml',
'image/x-compressed-xcf',
'image/x-fits',
'image/x-gimp-gbr',
'image/x-gimp-gih',
'image/x-gimp-pat',
'image/x-pcx',
'image/x-portable-anymap',
'image/x-portable-bitmap',
'image/x-portable-graymap',
'image/x-portable-pixmap',
'image/x-psd',
'image/x-sgi',
'image/x-tga',
'image/x-xbitmap',
'image/x-xcf',
'image/x-xwindowdump',
]
libtiff = dependency('libtiff-4', required: get_option('tiff'))
if libtiff.found()
MIMEtypes += 'image/tiff'
endif
libjpeg = dependency('libjpeg', required: get_option('jpeg'))
conf.set('HAVE_LIBJPEG', libjpeg.found())
if libjpeg.found()
MIMEtypes += 'image/jpeg'
endif
zlib = dependency('zlib')
MIMEtypes += 'image/x-psp'
bz2 = cc.find_library('bz2')
liblzma = dependency('liblzma', version: '>=5.0.0')
ghostscript = cc.find_library('gs', required: get_option('ghostscript'))
if ghostscript.found()
MIMEtypes += 'application/postscript'
else
ghostscript = disabler()
endif
libpng = dependency('libpng', version: '>=1.6.25', required: get_option('png'))
if libpng.found()
MIMEtypes += [ 'image/png', 'image/x-icon']
endif
libmng = cc.find_library('mng', required: get_option('mng'))
libaa = cc.find_library('aa', required: get_option('aa'))
libxpm = dependency('xpm', required: get_option('xpm'))
if libxpm.found()
MIMEtypes += 'image/x-xpixmap'
endif
openexr = dependency('OpenEXR', version: '>=1.6.1', required: get_option('openexr'))
if openexr.found()
MIMEtypes += 'image/x-exr'
endif
webp_libs = [
dependency('libwebp', version: '>=0.6.0', required: get_option('webp')),
dependency('libwebpmux', version: '>=0.6.0', required: get_option('webp')),
dependency('libwebpdemux',version: '>=0.6.0', required: get_option('webp')),
]
webp_found = true
foreach lib : webp_libs
webp_found = webp_found and lib.found()
endforeach
if webp_found
MIMEtypes += 'image/x-webp'
endif
libheif = dependency('libheif', version: '>=1.3.2', required: get_option('heif'))
conf.set('HAVE_LIBHEIF_4_1_0', libheif.version().version_compare('>=1.4.0'))
if libheif.found()
MIMEtypes += [
'image/heif',
'image/heic',
]
endif
webkit = dependency('webkit2gtk-4.0', version: '>=2.20.3', required: get_option('webkit'))
conf.set('HAVE_WEBKIT', webkit.found())
if get_option('poppler')
poppler = [
dependency('poppler-glib', version: '>=0.69.0'),
dependency('poppler-data', version: '>=0.4.9'),
]
else
poppler = no_dep
endif
cairopdf = dependency('cairo-pdf', version: '>=1.12.2', required: get_option('cairo-pdf'))
# PDF import support is a granted feature.
MIMEtypes += 'application/pdf'
wmf = dependency('libwmf', version: '>=0.2.8', required: get_option('wmf'))
if wmf.found()
MIMEtypes += 'image/x-wmf'
endif
openjpeg = dependency('libopenjp2', version: '>=2.1.0', required: get_option('jpeg2000'))
if openjpeg.found()
MIMEtypes += [ 'image/jp2', 'image/jpeg2000', 'image/jpx', ]
endif
xmc = dependency('xcursor', required: get_option('xcursor'))
if xmc.found()
MIMEtypes += 'image/x-xcursor'
endif
alsa = dependency('alsa', version: '>=1.0.0', required: get_option('alsa'))
conf.set('HAVE_ALSA', alsa.found())
if get_option('linux-input').disabled()
have_linuxinput = false
elif get_option('linux-input').enabled() and not cc.has_header('linux/input.h')
error('linux/input.h header not found.')
else
have_linuxinput = x11_target
endif
# DirectX DirectInput
directx = no_dep
directx_sdk_path = get_option('directx-sdk-dir')
if directx_sdk_path != '' and platform_windows
if directx_sdk_path.contains(' ') or directx_sdk_path.contains('\\')
error('\n'.join([
'The DirectX SDK path should be given :',
'* without spaces (use MSys mounts)',
'* with plain (forward) slashes only,'
]))
endif
directx = declare_dependency(
link_with: cc.find_library('dxguid',
dirs: directx_sdk_path / 'Lib' / 'x86'),
include_directories: directx_sdk_path / 'Include',
)
endif
conf.set('HAVE_DX_DINPUT', directx.found())
gudev = dependency('gudev-1.0', version: '>=167', required: get_option('gudev'))
conf.set('HAVE_LIBGUDEV', gudev.found())
################################################################################
# Email sending
email_message = false
sendmail_choice = get_option('with-sendmail')
if not [ '', 'false', 'no', ].contains(sendmail_choice)
if [ 'true', 'yes' ].contains(sendmail_choice)
sendmail_path = 'sendmail'
else
sendmail_path = sendmail_choice
endif
sendmail = find_program(sendmail_path, required: false)
if sendmail.found()
sendmail_path = sendmail.path()
else
mail_warning = 'Sendmail specified but not found. It should be installed at runtime!'
warning(mail_warning)
warnings += mail_warning
endif
email_message = '@0@ (@1@)'.format(true, sendmail_path)
conf.set_quoted('SENDMAIL', sendmail_path)
else
xdg_email_path = 'xdg-email'
xdg_email = find_program(xdg_email_path, required: false)
if xdg_email.found()
xdg_email_path = xdg_email.path()
else
mail_warning = 'Xdg-email not found, but required at runtime for email sending.'
warning(mail_warning)
warnings += mail_warning
endif
email_message = '@0@ (@1@)'.format(true, xdg_email_path)
endif
################################################################################
# ISO codes
isocodes = dependency('iso-codes', required: false)
if isocodes.found()
isocodes_prefix = isocodes.get_pkgconfig_variable('prefix')
isocodes_location = isocodes_prefix / get_option('datadir') / 'xml' / 'iso-codes'
isocodes_localedir= isocodes_prefix / get_option('datadir') / 'locale'
endif
conf.set('HAVE_ISO_CODES', isocodes.found())
################################################################################
# Program tools
perl = find_program('perl5', 'perl', 'perl5.005', 'perl5.004', 'perl')
## Python
# By default, we want packagers to install Python plug-ins to get the
# optimum experience. -Dpython=true will check for a Python 3
# interpreter and PyGObject, and warns without.
# It is up to the packager to ensure they are available at run time.
# This can be useful in particular when cross-compiling since anyway
# the interpreter is not useful at build time.
python3_required_version = '>=3.6.0'
if get_option('python') == 'never'
python_warning = '''
You disabled the installation of core Python plug-ins. This is discouraged
as it won't provide the full GIMP experience.
Note that you may install the Python plug-ins even if you have no Python
interpreter at build-time by passing the configure option -Dpython=always.
Just make sure that a Python @0@ interpreter is available at run-time.
'''.format(python3_required_version)
warning(python_warning)
warnings += python_warning
have_python = false
else
always_install = get_option('python') == 'always'
python = pythonmod.find_installation('python3', required: false)
python_found = (
python.found() and
python.language_version().version_compare(python3_required_version)
)
if python_found
pygobject_found = run_command(
python, '-c',
'\n'.join([
'''import sys, gi''',
'''version = '@0@' '''.format('3.0'),
'''sys.exit(gi.check_version(version))''',
]),
).returncode() == 0
python_found = python_found and pygobject_found
endif
if (not python_found) and (not always_install)
error('''
Python @0@ or PyGObject was not found.
Note that you may install the Python plug-ins even if you have no Python
interpreter at build-time by passing the configure option -Dpython=always.
Just make sure that a Python @0@ interpreter is available at run-time.
'''.format(python3_required_version))
endif
if (not python_found) and (always_install)
python_warning = '''
Python @0@ or PyGObject was not found.
Python plug-ins will be installed anyway but you should make sure that
a compatible Python interpreter is available at installation, otherwise
installed plug-ins won't be usable.
'''.format(python3_required_version)
warning(python_warning)
warnings += python_warning
endif
have_python = python_found or always_install
endif
## Javascript
if get_option('javascript') == 'never'
js_warning = '''
You disabled the installation of core Javascript plug-ins. This is
discouraged as it won't provide the full GIMP experience.
Note that you may install the Javascript plug-ins even if you have no GJS
interpreter at build-time by passing the configure option -Djavascript=always.
Just make sure that the GJS interpreter is available at run-time.
'''
warning(js_warning)
warnings += js_warning
have_javascript = false
else
always_install = get_option('javascript') == 'always'
gjs = find_program('gjs', required: false)
if (not gjs.found()) and (not always_install)
error('''
GJS was not found.
Note that you may install the Javascript plug-ins even if you have no GJS
interpreter at build-time by passing the configure option -Djavascript=always.
Just make sure that the GJS interpreter is available at run-time.
''')
endif
if (not gjs.found()) and (always_install)
js_warning = '''
GJS was not found.
JavaScript plug-ins will be installed anyway but you should make sure that
the JavaScript interpreter GJS is available at installation, otherwise
installed plug-ins won't be usable.
'''
warning(js_warning)
warnings += js_warning
endif
have_javascript = gjs.found() or always_install
endif
## Lua
if get_option('lua') == 'never'
lua_warning = '''
You disabled the installation of core Lua plug-ins. This is discouraged
as it won't provide the full GIMP experience.
Note that you may install the Lua plug-ins even if you have no Lua LGI
interpreter at build-time by passing the configure option -Dlua=always.
Just make sure that the Lua LGI interpreter is available at run-time.
'''
warning(lua_warning)
warnings += lua_warning
have_lua = false
else
always_install = get_option('lua') == 'always'
lua = find_program('luajit', required: false)
if (not lua.found()) and (not always_install)
error('''
Luajit was not found.
Note that you may install the Lua plug-ins even if you have no Lua LGI
interpreter at build-time by passing the configure option -Dlua=always.
Just make sure that the Lua LGI interpreter is available at run-time.
''')
endif
if (not lua.found()) and always_install
lua_warning = '''
Luajit was not found.
Lua plug-ins will be installed anyway but you should make sure that
luajit and LGI are available at installation, otherwise
installed plug-ins won't be usable.
'''
warning(lua_warning)
warnings += lua_warning
endif
have_lua = lua.found() or always_install
endif
# Check for GTK Mac Integration
if platform_osx and (gtk3.get_pkgconfig_variable('targets').contains('xquartz'))
gtk3_macos = dependency('gtk-mac-integration', version: '>=2.0.0')
else
gtk3_macos = no_dep
endif
# Check for XML tools
xmllint = find_program('xmllint', required: false)
xsltproc = find_program('xsltproc')
intltool_merge = find_program('intltool-merge')
desktop_validate = find_program('desktop-file-validate', required: false)
appstream_util = find_program('appstream-util', required: get_option('appdata-test'))
# Check for doc generation tools
have_gtk_doc = get_option('gtk-doc')
# Check for vector icons
have_vector_icons = get_option('vec-icons')
if have_vector_icons
# shared-mime-info is needed to correctly detect SVG files
# (except on Windows, apparently).
if platform_windows
vec_warning = '''