build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.5.+'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.3'
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1'
    }
}

plugins {
    id 'com.github.sherter.google-java-format' version '0.6'
}

repositories {
    jcenter()
}

apply plugin: 'idea'
apply plugin: 'eclipse'
apply from: 'gradle/gradle/nexus.upload.plugin.gradle'

if(hasProperty('target') && target == 'android') {

    apply plugin: 'com.android.library'
    apply plugin: 'com.github.dcendents.android-maven'

    android {
        compileSdkVersion 23
        buildToolsVersion '23.0.2'
        defaultConfig {
            minSdkVersion 14
            targetSdkVersion 23
        }
        compileOptions {
            sourceCompatibility JavaVersion.VERSION_1_7
            targetCompatibility JavaVersion.VERSION_1_7
        }

        // Rename the aar correctly
        libraryVariants.all { variant ->
            variant.outputs.each { output ->
                def outputFile = output.outputFile
                if (outputFile != null && outputFile.name.endsWith('.aar')) {
                    def fileName = "${project.name}-${variant.baseName}-${version}.aar"
                    output.outputFile = new File(outputFile.parent, fileName)
                }
            }
        }

        dependencies {
            provided 'javax.annotation:jsr250-api:1.0'
        }
    }

    afterEvaluate {
        android.libraryVariants.all { variant ->
            def task = project.tasks.create "jar${variant.name.capitalize()}", Jar
            task.description = "Create jar artifact for ${variant.name}"
            task.dependsOn variant.javaCompile
            task.from variant.javaCompile.destinationDir
            task.destinationDir = project.file("${project.buildDir}/outputs/jar")
            task.archiveName = "${project.name}-${variant.baseName}-${version}.jar"
            artifacts.add('archives', task);
        }
    }

    task sourcesJar(type: Jar) {
        from android.sourceSets.main.java.srcDirs
        classifier = 'sources'
    }

    artifacts {
        archives sourcesJar
    }

} else {

    apply plugin: 'java'
    apply plugin: 'maven'

    sourceCompatibility = JavaVersion.VERSION_1_7
    targetCompatibility = JavaVersion.VERSION_1_7

    install {
        repositories.mavenInstaller {
            pom.artifactId = 'epm'
        }
    }

    task execute(type:JavaExec) {
       main = System.getProperty('mainClass')
       classpath = sourceSets.main.runtimeClasspath
    }
}

dependencies {
    compile 'io.swagger:swagger-annotations:1.5.8'
    compile 'com.squareup.okhttp:okhttp:2.7.5'
    compile 'com.squareup.okhttp:logging-interceptor:2.7.5'
    compile 'com.google.code.gson:gson:2.6.2'
    compile 'joda-time:joda-time:2.9.3'

    // https://mvnrepository.com/artifact/org.slf4j/slf4j-log4j12
    compile group: 'org.slf4j', name: 'slf4j-log4j12', version: '1.7.25'

    testCompile 'junit:junit:4.12'
}

compileJava.dependsOn tasks.googleJavaFormat

javadoc {
    source = sourceSets.main.allJava
    classpath = configurations.compile
}

task writeNewPom {
    doLast {
        pom {
            project {
                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }
                name 'epm-java-client'
                description 'Java client for the ElasTest Platform Manager (EPM).'
                url 'https://github.com/tub-elastest/epm-client-java'
                developers {
                    developer {
                        id 'elastest.io'
		                name 'elastest.io Community'
		                organizationUrl 'http://elastest.io'
                    }
                }
                scm {
                    connection 'scm:git:git://github.com/tub-elastest/epm-client-java.git'
                    developerConnection 'scm:git:ssh://github.com:/-elastest/epm-client-java.git'
		            url 'http://github.com/tub-elastest/epm-client-java/tree/master'
                }
                /*distributionManagement {
                    snapshotRepository {
                        id 'ossrh'
                        url 'https://oss.sonatype.org/content/repositories/snapshots'
                    }
                    repository {
                        id 'ossrh'
                        url 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
                    }
                }*/
            }
        }.writeTo("build/newPom.xml")
    }
}