build.gradle

plugins {
    id 'org.springframework.boot' version '2.6.13'
    id 'io.spring.dependency-management' version '1.1.0'
    id 'java'
}

group = 'handong'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {

    implementation 'org.springframework.boot:spring-boot-starter-web'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // swagger
    implementation 'org.springdoc:springdoc-openapi-ui:1.6.12'

    // database
    runtimeOnly 'mysql:mysql-connector-java'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'

    // redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    // queryDSL
    implementation 'com.querydsl:querydsl-jpa'

    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jpa"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"

    // security
    implementation 'org.springframework.boot:spring-boot-starter-security'

    // validator
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    // mail
    implementation 'org.springframework.boot:spring-boot-starter-mail'

    // cloud
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

    // logging
    implementation 'org.springframework.boot:spring-boot-starter-logging'

    // nimbusds
    implementation 'com.nimbusds:nimbus-jose-jwt:9.22'

    // oauth2
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-resource-server'

    // remote
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign:3.1.5'

    // mobile
    implementation 'com.google.firebase:firebase-admin:9.1.1'

    // sms
    implementation group: 'com.twilio.sdk', name: 'twilio', version: '8.0.0'

    // chat
    implementation 'org.springframework.boot:spring-boot-starter-websocket'

    // test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'

    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.mockito:mockito-inline'
}

clean {
    delete file('src/main/generated')
}

def querydslDir = "$buildDir/generated/querydsl"

sourceSets {
    main.java.srcDirs += [ querydslDir ]
}

tasks.withType(JavaCompile) {
    options.annotationProcessorGeneratedSourcesDirectory = file(querydslDir)
}

test {
    useJUnitPlatform()
}