-
Notifications
You must be signed in to change notification settings - Fork 0
/
cpm22bdos.s
2582 lines (2576 loc) · 68.2 KB
/
cpm22bdos.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; CP/M 2.2 for SDAS, adapted by Douglas Goodall for N8VEM use 2011
; Minor modifications 2014-06-14 William R Sowerbutts
.module cpm22bdos
.area _CPMBDOS
; export BDOS entry symbol to BIOS
.globl FBASE
; bios table has been replaced with global symbols
.globl BOOT
.globl WBOOT
.globl CONST
.globl CONIN
.globl CONOUT
.globl LIST
.globl PUNCH
.globl READER
.globl HOME
.globl SELDSK
.globl SETTRK
.globl SETSEC
.globl SETDMA
.globl READ
.globl WRITE
.globl LISTST
.globl SECTRN
IOBYTE = 3 ; I/O DEFINITION BYTE.
TDRIVE = 4 ; CURRENT DRIVE NAME AND USER NUMBER.
ENTRY = 5 ; ENTRY POINT FOR THE CP/M BDOS.
TFCB = 0x5C ; DEFAULT FILE CONTROL BLOCK.
TBUFF = 0x80 ; I/O BUFFER AND COMMAND LINE STORAGE.
TBASE = 0x100 ; TRANSIANT PROGRAM STORAGE AREA.
;
; SET CONTROL CHARACTER .EQUATES.
;
ASCIIA = 0x41
AT = 0x40
CNTRLC = 3 ; CONTROL-C
CNTRLE = 05 ; CONTROL-E
BS = 08 ; BACKSPACE
TAB = 09 ; TAB
LF = 0x0A ; LINE FEED
FF = 0x0C ; FORM FEED
CR = 0x0D ; CARRIAGE RETURN
CNTRLP = 0x10 ; CONTROL-P
CNTRLR = 0x12 ; CONTROL-R
CNTRLS = 0x13 ; CONTROL-S
CNTRLU = 0x15 ; CONTROL-U
CNTRLX = 0x18 ; CONTROL-X
CNTRLZ = 0x1A ; CONTROL-Z (END-OF-FILE MARK)
SPACE = 0x20
POUND = 0x23
DOLLAR = 0x24
QUESTION = 0x3f
UP = 0x5E
DEL = 0x7F ; RUBOUT
; CPM ORIGIN CALCULATE
NK = 59 ;SYSTEM SIZE
BASE = (NK*1024)-0x5000
CCPO = BASE+0x3400 ;CCP ORIGIN
BDOSO = BASE+0x3C00 ;BDOS ORIGIN
BIOSO = BASE+0x4A00 ;BIOS ORIGIN
.DB 0,0,0,0,0,0 ;OLD SERIAL NUMBER
;
;**************************************************************
;*
;* B D O S E N T R Y
;*
;**************************************************************
;
FBASE: JP FBASE1
;
; BDOS ERROR TABLE.
;
BADSCTR:.DW ERROR1 ; BAD SECTOR ON READ OR WRITE.
BADSLCT:.DW ERROR2 ; BAD DISK SELECT.
RODISK: .DW ERROR3 ; DISK IS READ ONLY.
ROFILE: .DW ERROR4 ; FILE IS READ ONLY.
;
; ENTRY INTO BDOS. (DE) OR (E) ARE THE PARAMETERS PASSED. THE
; FUNCTION NUMBER DESIRED IS IN REGISTER (C).
; E contains drive number if passing this
FBASE1: EX DE,HL ; SAVE THE (DE) PARAMETERS.
LD (PARAMS),HL
EX DE,HL
LD A,E ; AND SAVE REGISTER (E) IN PARTICULAR.
LD (EPARAM),A
LD HL,#0
LD (STATUS),HL ; CLEAR RETURN STATUS.
ADD HL,SP
LD (USRSTACK),HL ; SAVE USERS STACK POINTER.
LD SP,#STKAREA ; AND SET OUR OWN.
XOR A ; CLEAR AUTO SELECT STORAGE SPACE.
LD (AUTOFLAG),A
LD (AUTO),A
LD HL,#GOBACK ; SET RETURN ADDRESS.
PUSH HL
LD A,C ; GET FUNCTION NUMBER.
CP #NFUNCTS ; VALID FUNCTION NUMBER?
RET NC
LD C,E ; KEEP SINGLE REGISTER FUNCTION HERE.
LD HL,#FUNCTNS ; NOW LOOK THRU THE FUNCTION TABLE.
LD E,A
LD D,#0 ; (DE)=FUNCTION NUMBER.
ADD HL,DE
ADD HL,DE ; (HL)=(START OF TABLE)+2*(FUNCTION NUMBER).
LD E,(HL)
INC HL
LD D,(HL) ; NOW (DE)=ADDRESS FOR THIS FUNCTION.
LD HL,(PARAMS) ; RETRIEVE PARAMETERS.
EX DE,HL ; NOW (DE) HAS THE ORIGINAL PARAMETERS.
JP (HL) ; EXECUTE DESIRED FUNCTION.
;
; BDOS FUNCTION JUMP TABLE.
;
NFUNCTS = 41 ; NUMBER OF FUNCTIONS IN FOLLOWIN TABLE.
;
FUNCTNS:.DW WBOOT,GETCON,OUTCON,GETRDR,PUNCH,LIST,DIRCIO,GETIOB
.DW SETIOB,PRTSTR,R.DBUFF,GETCSTS,GETVER,RSTDSK,SETDSK,OPENFIL
.DW CLOSEFIL,GETFST,GETNXT,DELFILE,READSEQ,WRTSEQ,FCREATE
.DW RENFILE,GETLOG,GETCRNT,PUTDMA,GETALOC,WRTPRTD,GETROV,SETATTR
.DW GETPARM,GETUSER,RDRANDOM,WTRANDOM,FILESIZE,SETRAN,LOGOFF,RTN
.DW RTN,WTSPECL
;
; BDOS ERROR MESSAGE SECTION.
;
ERROR1: LD HL,#BADSEC ; BAD SECTOR MESSAGE.
CALL PRTERR ; PRINT IT AND GET A 1 CHAR RESPONCE.
CP #CNTRLC ; RE-BOOT R.EQUEST (CONTROL-C)?
JP Z,0 ; YES.
RET ; NO, RETURN TO RETRY I/O FUNCTION.
;
ERROR2: LD HL,#BADSEL ; BAD DRIVE SELECTED.
JP ERROR5
;
ERROR3: LD HL,#DISKRO ; DISK IS READ ONLY.
JP ERROR5
;
ERROR4: LD HL,#FILERO ; FILE IS READ ONLY.
;
ERROR5: CALL PRTERR
JP 0 ; ALWAYS REBOOT ON THESE ERRORS.
;
BDOSERR: .ascii "BDOS ERR ON "
BDOSDRV: .ascii " : $"
BADSEC: .ascii "BAD SECTOR$"
BADSEL: .ascii "SELECT$"
FILERO: .ascii "FILE "
DISKRO: .ascii "R/O$"
;
; PRINT BDOS ERROR MESSAGE.
;
PRTERR: PUSH HL ; SAVE SECOND MESSAGE POINTER.
CALL OUTCRLF ; SEND (CR)(LF).
LD A,(ACTIVE) ; GET ACTIVE DRIVE.
ADD A,#ASCIIA ; MAKE ASCII.
LD (BDOSDRV),A ; AND PUT IN MESSAGE.
LD BC,#BDOSERR ; AND PRINT IT.
CALL PRTMESG
POP BC ; PRINT SECOND MESSAGE LINE NOW.
CALL PRTMESG
;
; GET AN INPUT CHARACTER. WE WILL CHECK OUR 1 CHARACTER
; BUFFER FIRST. THIS MAY BE SET BY THE CONSOLE STATUS ROUTINE.
;
GETCHAR:LD HL,#CHARBUF ; CHECK CHARACTER BUFFER.
LD A,(HL) ; ANYTHING PRESENT ALREADY?
LD (HL),#0 ; ...EITHER CASE CLEAR IT.
OR A
RET NZ ; YES, USE IT.
JP CONIN ; NOPE, GO GET A CHARACTER RESPONCE.
;
; INPUT AND ECHO A CHARACTER.
;
GETECHO:CALL GETCHAR ; INPUT A CHARACTER.
CALL CHKCHAR ; CARRIAGE CONTROL?
RET C ; NO, A REGULAR CONTROL CHAR SO DON'T ECHO.
PUSH AF ; OK, SAVE CHARACTER NOW.
LD C,A
CALL OUTCON ; AND ECHO IT.
POP AF ; GET CHARACTER AND RETURN.
RET
;
; CHECK CHARACTER IN (A). SET THE ZERO FLAG ON A CARRIAGE
; CONTROL CHARACTER AND THE CARRY FLAG ON ANY OTHER CONTROL
; CHARACTER.
;
CHKCHAR:CP #CR ; CHECK FOR CARRIAGE RETURN, LINE FEED, BACKSPACE,
RET Z ; OR A TAB.
CP #LF
RET Z
CP #TAB
RET Z
CP #BS
RET Z
CP #SPACE ; OTHER CONTROL CHAR? SET CARRY FLAG.
RET
;
; CHECK THE CONSOLE DURING OUTPUT. HALT ON A CONTROL-S, THEN
; REBOOT ON A CONTROL-C. IF ANYTHING ELSE IS READY, CLEAR THE
; ZERO FLAG AND RETURN (THE CALLING ROUTINE MAY WANT TO DO
; SOMETHING).
;
CKCONSOL:
LD A,(CHARBUF) ; CHECK BUFFER.
OR A ; IF ANYTHING, JUST RETURN WITHOUT CHECKING.
JP NZ,CKCON2
CALL CONST ; NOTHING IN BUFFER. CHECK CONSOLE.
AND #0x01 ; LOOK AT BIT 0.
RET Z ; RETURN IF NOTHING.
CALL CONIN ; OK, GET IT.
CP #CNTRLS ; IF NOT CONTROL-S, RETURN WITH ZERO CLEARED.
JP NZ,CKCON1
CALL CONIN ; HALT PROCESSING UNTIL ANOTHER CHAR
CP #CNTRLC ; IS TYPED. CONTROL-C?
JP Z,0 ; YES, REBOOT NOW.
XOR A ; NO, JUST PRETEND NOTHING WAS EVER READY.
RET
CKCON1: LD (CHARBUF),A ; SAVE CHARACTER IN BUFFER FOR LATER PROCESSING.
CKCON2: LD A,#1 ; SET (A) TO NON ZERO TO MEAN SOMETHING IS READY.
RET
;
; OUTPUT (C) TO THE SCREEN. IF THE PRINTER FLIP-FLOP FLAG
; IS SET, WE WILL SEND CHARACTER TO PRINTER ALSO. THE CONSOLE
; WILL BE CHECKED IN THE PROCESS.
;
OUTCHAR:LD A,(OUTFLAG) ; CHECK OUTPUT FLAG.
OR A ; ANYTHING AND WE WON'T GENERATE OUTPUT.
JP NZ,OUTCHR1
PUSH BC
CALL CKCONSOL ; CHECK CONSOLE (WE DON'T CARE WHATS THERE).
POP BC
PUSH BC
CALL CONOUT ; OUTPUT (C) TO THE SCREEN.
POP BC
PUSH BC
LD A,(PRTFLAG) ; CHECK PRINTER FLIP-FLOP FLAG.
OR A
CALL NZ,LIST ; PRINT IT ALSO IF NON-ZERO.
POP BC
OUTCHR1:LD A,C ; UPDATE CURSORS POSITION.
LD HL,#CURPOS
CP #DEL ; RUBOUTS DON'T DO ANYTHING HERE.
RET Z
INC (HL) ; BUMP LINE POINTER.
CP #SPACE ; AND RETURN IF A NORMAL CHARACTER.
RET NC
DEC (HL) ; RESTORE AND CHECK FOR THE START OF THE LINE.
LD A,(HL)
OR A
RET Z ; INGNORE CONTROL CHARACTERS AT THE START OF THE LINE.
LD A,C
CP #BS ; IS IT A BACKSPACE?
JP NZ,OUTCHR2
DEC (HL) ; YES, BACKUP POINTER.
RET
OUTCHR2:CP #LF ; IS IT A LINE FEED?
RET NZ ; IGNORE ANYTHING ELSE.
LD (HL),#0 ; RESET POINTER TO START OF LINE.
RET
;
; OUTPUT (A) TO THE SCREEN. IF IT IS A CONTROL CHARACTER
; (OTHER THAN CARRIAGE CONTROL), USE ^X FORMAT.
;
SHOWIT: LD A,C
CALL CHKCHAR ; CHECK CHARACTER.
JP NC,OUTCON ; NOT A CONTROL, USE NORMAL OUTPUT.
PUSH AF
LD C,#UP ; FOR A CONTROL CHARACTER, PRECEED IT WITH '^'.
CALL OUTCHAR
POP AF
OR #AT ; AND THEN USE THE LETTER .EQUIVELANT.
LD C,A
;
; FUNCTION TO OUTPUT (C) TO THE CONSOLE DEVICE AND EXPAND TABS
; IF NECESSARY.
;
OUTCON: LD A,C
CP #TAB ; IS IT A TAB?
JP NZ,OUTCHAR ; USE REGULAR OUTPUT.
OUTCON1:LD C,#SPACE ; YES IT IS, USE SPACES INSTEAD.
CALL OUTCHAR
LD A,(CURPOS) ; GO UNTIL THE CURSOR IS AT A MULTIPLE OF 8
AND #7 ; POSITION.
JP NZ,OUTCON1
RET
;
; ECHO A BACKSPACE CHARACTER. ERASE THE PREVOIUS CHARACTER
; ON THE SCREEN.
;
BACKUP: CALL BACKUP1 ; BACKUP THE SCREEN 1 PLACE.
LD C,#SPACE ; THEN BLANK THAT CHARACTER.
CALL CONOUT
BACKUP1:LD C,#BS ; THEN BACK SPACE ONCE MORE.
JP CONOUT
;
; SIGNAL A DELETED LINE. PRINT A '#' AT THE END AND START
; OVER.
;
NEWLINE:LD C,#POUND
CALL OUTCHAR ; PRINT THIS.
CALL OUTCRLF ; START NEW LINE.
NEWLN1: LD A,(CURPOS) ; MOVE THE CURSOR TO THE STARTING POSITION.
LD HL,#STARTING
CP (HL)
RET NC ; THERE YET?
LD C,#SPACE
CALL OUTCHAR ; NOPE, KEEP GOING.
JP NEWLN1
;
; OUTPUT A (CR) (LF) TO THE CONSOLE DEVICE (SCREEN).
;
OUTCRLF:LD C,#CR
CALL OUTCHAR
LD C,#LF
JP OUTCHAR
;
; PRINT MESSAGE POINTED TO BY (BC). IT WILL END WITH A '$'.
;
PRTMESG:LD A,(BC) ; CHECK FOR TERMINATING CHARACTER.
CP #DOLLAR
RET Z
INC BC
PUSH BC ; OTHERWISE, BUMP POINTER AND PRINT IT.
LD C,A
CALL OUTCON
POP BC
JP PRTMESG
;
; FUNCTION TO EXECUTE A BUFFERED READ.
;
R.DBUFF: LD A,(CURPOS) ; USE PRESENT LOCATION AS STARTING ONE.
LD (STARTING),A
LD HL,(PARAMS) ; GET THE MAXIMUM BUFFER SPACE.
LD C,(HL)
INC HL ; POINT TO FIRST AVAILABLE SPACE.
PUSH HL ; AND SAVE.
LD B,#0 ; KEEP A CHARACTER COUNT.
R.DBUF1: PUSH BC
PUSH HL
R.DBUF2: CALL GETCHAR ; GET THE NEXT INPUT CHARACTER.
AND #0x7F ; STRIP BIT 7.
POP HL ; RESET REGISTERS.
POP BC
CP #CR ; EN OF THE LINE?
JP Z,R.DBUF17
CP #LF
JP Z,R.DBUF17
CP #BS ; HOW ABOUT A BACKSPACE?
JP NZ,R.DBUF3
LD A,B ; YES, BUT IGNORE AT THE BEGINNING OF THE LINE.
OR A
JP Z,R.DBUF1
DEC B ; OK, UPDATE COUNTER.
LD A,(CURPOS) ; IF WE BACKSPACE TO THE START OF THE LINE,
LD (OUTFLAG),A ; TREAT AS A CANCEL (CONTROL-X).
JP R.DBUF10
R.DBUF3: CP #DEL ; USER TYPED A RUBOUT?
JP NZ,R.DBUF4
LD A,B ; IGNORE AT THE START OF THE LINE.
OR A
JP Z,R.DBUF1
LD A,(HL) ; OK, ECHO THE PREVOIUS CHARACTER.
DEC B ; AND RESET POINTERS (COUNTERS).
DEC HL
JP R.DBUF15
R.DBUF4: CP #CNTRLE ; PHYSICAL END OF LINE?
JP NZ,R.DBUF5
PUSH BC ; YES, DO IT.
PUSH HL
CALL OUTCRLF
XOR A ; AND UPDATE STARTING POSITION.
LD (STARTING),A
JP R.DBUF2
R.DBUF5: CP #CNTRLP ; CONTROL-P?
JP NZ,R.DBUF6
PUSH HL ; YES, FLIP THE PRINT FLAG FILP-FLOP BYTE.
LD HL,#PRTFLAG
LD A,#1 ; PRTFLAG=1-PRTFLAG
SUB (HL)
LD (HL),A
POP HL
JP R.DBUF1
R.DBUF6: CP #CNTRLX ; CONTROL-X (CANCEL)?
JP NZ,R.DBUF8
POP HL
R.DBUF7: LD A,(STARTING) ; YES, BACKUP THE CURSOR TO HERE.
LD HL,#CURPOS
CP (HL)
JP NC,R.DBUFF ; DONE YET?
DEC (HL) ; NO, DECREMENT POINTER AND OUTPUT BACK UP ONE SPACE.
CALL BACKUP
JP R.DBUF7
R.DBUF8: CP #CNTRLU ; CNTROL-U (CANCEL LINE)?
JP NZ,R.DBUF9
CALL NEWLINE ; START A NEW LINE.
POP HL
JP R.DBUFF
R.DBUF9: CP #CNTRLR ; CONTROL-R?
JP NZ,R.DBUF14
R.DBUF10:PUSH BC ; YES, START A NEW LINE AND RETYPE THE OLD ONE.
CALL NEWLINE
POP BC
POP HL
PUSH HL
PUSH BC
R.DBUF11:LD A,B ; DONE WHOLE LINE YET?
OR A
JP Z,R.DBUF12
INC HL ; NOPE, GET NEXT CHARACTER.
LD C,(HL)
DEC B ; COUNT IT.
PUSH BC
PUSH HL
CALL SHOWIT ; AND DISPLAY IT.
POP HL
POP BC
JP R.DBUF11
R.DBUF12:PUSH HL ; DONE WITH LINE. IF WE WERE DISPLAYING
LD A,(OUTFLAG) ; THEN UPDATE CURSOR POSITION.
OR A
JP Z,R.DBUF2
LD HL,#CURPOS ; BECAUSE THIS LINE IS SHORTER, WE MUST
SUB (HL) ; BACK UP THE CURSOR (NOT THE SCREEN HOWEVER)
LD (OUTFLAG),A ; SOME NUMBER OF POSITIONS.
R.DBUF13:CALL BACKUP ; NOTE THAT AS LONG AS (OUTFLAG) IS NON
LD HL,#OUTFLAG ; ZERO, THE SCREEN WILL NOT BE CHANGED.
DEC (HL)
JP NZ,R.DBUF13
JP R.DBUF2 ; NOW JUST GET THE NEXT CHARACTER.
;
; JUST A NORMAL CHARACTER, PUT THIS IN OUR BUFFER AND ECHO.
;
R.DBUF14:INC HL
LD (HL),A ; STORE CHARACTER.
INC B ; AND COUNT IT.
R.DBUF15:PUSH BC
PUSH HL
LD C,A ; ECHO IT NOW.
CALL SHOWIT
POP HL
POP BC
LD A,(HL) ; WAS IT AN ABORT R.EQUEST?
CP #CNTRLC ; CONTROL-C ABORT?
LD A,B
JP NZ,R.DBUF16
CP #1 ; ONLY IF AT START OF LINE.
JP Z,0
R.DBUF16:CP C ; NOPE, HAVE WE FILLED THE BUFFER?
JP C,R.DBUF1
R.DBUF17:POP HL ; YES END THE LINE AND RETURN.
LD (HL),B
LD C,#CR
JP OUTCHAR ; OUTPUT (CR) AND RETURN.
;
; FUNCTION TO GET A CHARACTER FROM THE CONSOLE DEVICE.
;
GETCON: CALL GETECHO ; GET AND ECHO.
JP SETSTAT ; SAVE STATUS AND RETURN.
;
; FUNCTION TO GET A CHARACTER FROM THE TAPE READER DEVICE.
;
GETRDR: CALL READER ; GET A CHARACTER FROM READER, SET STATUS AND RETURN.
JP SETSTAT
;
; FUNCTION TO PERFORM DIRECT CONSOLE I/O. IF (C) CONTAINS (FF)
; THEN THIS IS AN INPUT R.EQUEST. IF (C) CONTAINS (FE) THEN
; THIS IS A STATUS R.EQUEST. OTHERWISE WE ARE TO OUTPUT (C).
;
DIRCIO: LD A,C ; TEST FOR (FF).
INC A
JP Z,DIRC1
INC A ; TEST FOR (FE).
JP Z,CONST
JP CONOUT ; JUST OUTPUT (C).
DIRC1: CALL CONST ; THIS IS AN INPUT R.EQUEST.
OR A
JP Z,GOBACK1 ; NOT READY? JUST RETURN (DIRECTLY).
CALL CONIN ; YES, GET CHARACTER.
JP SETSTAT ; SET STATUS AND RETURN.
;
; FUNCTION TO RETURN THE I/O BYTE.
;
GETIOB: LD A,(IOBYTE)
JP SETSTAT
;
; FUNCTION TO SET THE I/O BYTE.
;
SETIOB: LD HL,#IOBYTE
LD (HL),C
RET
;
; FUNCTION TO PRINT THE CHARACTER STRING POINTED TO BY (DE)
; ON THE CONSOLE DEVICE. THE STRING ENDS WITH A '$'.
;
PRTSTR: EX DE,HL
LD C,L
LD B,H ; NOW (BC) POINTS TO IT.
JP PRTMESG
;
; FUNCTION TO INTERIGATE THE CONSOLE DEVICE.
;
GETCSTS:CALL CKCONSOL
;
; GET HERE TO SET THE STATUS AND RETURN TO THE CLEANUP
; SECTION. THEN BACK TO THE USER.
;
SETSTAT:LD (STATUS),A
RTN: RET
;
; SET THE STATUS TO 1 (READ OR WRITE ERROR CODE).
;
IOERR1: LD A,#1
JP SETSTAT
;
OUTFLAG:.DB 0 ; OUTPUT FLAG (NON ZERO MEANS NO OUTPUT).
STARTING:
.DB 2 ; STARTING POSITION FOR CURSOR.
CURPOS: .DB 0 ; CURSOR POSITION (0=START OF LINE).
PRTFLAG:.DB 0 ; PRINTER FLAG (CONTROL-P TOGGLE). LIST IF NON ZERO.
CHARBUF:.DB 0 ; SINGLE INPUT CHARACTER BUFFER.
;
; STACK AREA FOR BDOS CALLS.
;
USRSTACK:
.DW 0 ; SAVE USERS STACK POINTER HERE.
;
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.DB 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
STKAREA: ; END OF STACK AREA.
;
USERNO: .DB 0 ; CURRENT USER NUMBER.
ACTIVE: .DB 0 ; CURRENTLY ACTIVE DRIVE.
PARAMS: .DW 0 ; SAVE (DE) PARAMETERS HERE ON ENTRY.
STATUS: .DW 0 ; STATUS RETURNED FROM BDOS FUNCTION.
;
; SELECT ERROR OCCURED, JUMP TO ERROR ROUTINE.
;
SLCTERR:LD HL,#BADSLCT
;
; JUMP TO (HL) INDIRECTLY.
;
JUMPHL: LD E,(HL)
INC HL
LD D,(HL) ; NOW (DE) CONTAIN THE DESIRED ADDRESS.
EX DE,HL
JP (HL)
;
; BLOCK MOVE. (DE) TO (HL), (C) BYTES TOTAL.
;
DE2HL: INC C ; IS COUNT DOWN TO ZERO?
DE2HL1: DEC C
RET Z ; YES, WE ARE DONE.
LD A,(DE) ; NO, MOVE ONE MORE BYTE.
LD (HL),A
INC DE
INC HL
JP DE2HL1 ; AND REPEAT.
;
; SELECT THE DESIRED DRIVE.
;
SELECT: LD A,(ACTIVE) ; GET ACTIVE DISK.
LD C,A
CALL SELDSK ; SELECT IT.
LD A,H ; VALID DRIVE?
OR L ; VALID DRIVE?
RET Z ; RETURN IF NOT.
;
; HERE, THE BIOS RETURNED THE ADDRESS OF THE PARAMETER BLOCK
; IN (HL). WE WILL EXTRACT THE NECESSARY POINTERS AND SAVE THEM.
;
LD E,(HL) ; YES, GET ADDRESS OF TRANSLATION TABLE INTO (DE).
INC HL
LD D,(HL)
INC HL
LD (SCRATCH1),HL ; SAVE POINTERS TO SCRATCH AREAS.
INC HL
INC HL
LD (SCRATCH2),HL ; DITTO.
INC HL
INC HL
LD (SCRATCH3),HL ; DITTO.
INC HL
INC HL
EX DE,HL ; NOW SAVE THE TRANSLATION TABLE ADDRESS.
LD (XLATE),HL
LD HL,#DIRBUF ; PUT THE NEXT 8 BYTES HERE.
LD C,#8 ; THEY CONSIST OF THE DIRECTORY BUFFER
CALL DE2HL ; POINTER, PARAMETER BLOCK POINTER,
LD HL,(DISKPB) ; CHECK AND ALLOCATION VECTORS.
EX DE,HL
LD HL,#SECTORS ; MOVE PARAMETER BLOCK INTO OUR RAM.
LD C,#15 ; IT IS 15 BYTES LONG.
CALL DE2HL
LD HL,(DSKSIZE) ; CHECK DISK SIZE.
LD A,H ; MORE THAN 256 BLOCKS ON THIS?
LD HL,#BIGDISK
LD (HL),#0x0FF ; SET TO SAMLL.
OR A
JP Z,SELECT1
LD (HL),#0 ; WRONG, SET TO LARGE.
SELECT1:LD A,#0x0FF ; CLEAR THE ZERO FLAG.
OR A
RET
;
; ROUTINE TO HOME THE DISK TRACK HEAD AND CLEAR POINTERS.
;
HOMEDRV:CALL HOME ; HOME THE HEAD.
XOR A
LD HL,(SCRATCH2) ; SET OUR TRACK POINTER ALSO.
LD (HL),A
INC HL
LD (HL),A
LD HL,(SCRATCH3) ; AND OUR SECTOR POINTER.
LD (HL),A
INC HL
LD (HL),A
RET
;
; DO THE ACTUAL DISK READ AND CHECK THE ERROR RETURN STATUS.
;
DOREAD: CALL READ
JP IORET
;
; DO THE ACTUAL DISK WRITE AND HANDLE ANY BIOS ERROR.
;
DOWRITE:CALL WRITE
IORET: OR A
RET Z ; RETURN UNLESS AN ERROR OCCURED.
LD HL,#BADSCTR ; BAD READ/WRITE ON THIS SECTOR.
JP JUMPHL
;
; ROUTINE TO SELECT THE TRACK AND SECTOR THAT THE DESIRED
; BLOCK NUMBER FALLS IN.
;
TRKSEC: LD HL,(FILEPOS) ; GET POSITION OF LAST ACCESSED FILE
LD C,#2 ; IN DIRECTORY AND COMPUTE SECTOR #.
CALL SHIFTR ; SECTOR #=FILE-POSITION/4.
LD (BLKNMBR),HL ; SAVE THIS AS THE BLOCK NUMBER OF INTEREST.
LD (CKSUMTBL),HL ; WHAT'S IT DOING HERE TOO?
;
; IF THE SECTOR NUMBER HAS ALREADY BEEN SET (BLKNMBR), ENTER
; AT THIS POINT.
;
TRKSEC1:LD HL,#BLKNMBR
LD C,(HL) ; MOVE SECTOR NUMBER INTO (BC).
INC HL
LD B,(HL)
LD HL,(SCRATCH3) ; GET CURRENT SECTOR NUMBER AND
LD E,(HL) ; MOVE THIS INTO (DE).
INC HL
LD D,(HL)
LD HL,(SCRATCH2) ; GET CURRENT TRACK NUMBER.
LD A,(HL) ; AND THIS INTO (HL).
INC HL
LD H,(HL)
LD L,A
TRKSEC2:LD A,C ; IS DESIRED SECTOR BEFORE CURRENT ONE?
SUB E
LD A,B
SBC A,D
JP NC,TRKSEC3
PUSH HL ; YES, DECREMENT SECTORS BY ONE TRACK.
LD HL,(SECTORS) ; GET SECTORS PER TRACK.
LD A,E
SUB L
LD E,A
LD A,D
SBC A,H
LD D,A ; NOW WE HAVE BACKED UP ONE FULL TRACK.
POP HL
DEC HL ; ADJUST TRACK COUNTER.
JP TRKSEC2
TRKSEC3:PUSH HL ; DESIRED SECTOR IS AFTER CURRENT ONE.
LD HL,(SECTORS) ; GET SECTORS PER TRACK.
ADD HL,DE ; BUMP SECTOR POINTER TO NEXT TRACK.
JP C,TRKSEC4
LD A,C ; IS DESIRED SECTOR NOW BEFORE CURRENT ONE?
SUB L
LD A,B
SBC A,H
JP C,TRKSEC4
EX DE,HL ; NOT YES, INCREMENT TRACK COUNTER
POP HL ; AND CONTINUE UNTIL IT IS.
INC HL
JP TRKSEC3
;
; HERE WE HAVE DETERMINED THE TRACK NUMBER THAT CONTAINS THE
; DESIRED SECTOR.
;
TRKSEC4:POP HL ; GET TRACK NUMBER (HL).
PUSH BC
PUSH DE
PUSH HL
EX DE,HL
LD HL,(OFFSET) ; ADJUST FOR FIRST TRACK OFFSET.
ADD HL,DE
LD B,H
LD C,L
CALL SETTRK ; SELECT THIS TRACK.
POP DE ; RESET CURRENT TRACK POINTER.
LD HL,(SCRATCH2)
LD (HL),E
INC HL
LD (HL),D
POP DE
LD HL,(SCRATCH3) ; RESET THE FIRST SECTOR ON THIS TRACK.
LD (HL),E
INC HL
LD (HL),D
POP BC
LD A,C ; NOW SUBTRACT THE DESIRED ONE.
SUB E ; TO MAKE IT RELATIVE (1-# SECTORS/TRACK).
LD C,A
LD A,B
SBC A,D
LD B,A
LD HL,(XLATE) ; TRANSLATE THIS SECTOR ACCORDING TO THIS TABLE.
EX DE,HL
CALL SECTRN ; LET THE BIOS TRANSLATE IT.
LD C,L
LD B,H
JP SETSEC ; AND SELECT IT.
;
; COMPUTE BLOCK NUMBER FROM RECORD NUMBER (SAVNREC) AND
; EXTENT NUMBER (SAVEXT).
;
GETBLOCK:
LD HL,#BLKSHFT ; GET LOGICAL TO PHYSICAL CONVERSION.
LD C,(HL) ; NOTE THAT THIS IS BASE 2 LOG OF RATIO.
LD A,(SAVNREC) ; GET RECORD NUMBER.
GETBLK1:OR A ; COMPUTE (A)=(A)/2^BLKSHFT.
RRA
DEC C
JP NZ,GETBLK1
LD B,A ; SAVE RESULT IN (B).
LD A,#8
SUB (HL)
LD C,A ; COMPUTE (C)=8-BLKSHFT.
LD A,(SAVEXT)
GETBLK2:DEC C ; COMPUTE (A)=SAVEXT*2^(8-BLKSHFT).
JP Z,GETBLK3
OR A
RLA
JP GETBLK2
GETBLK3:ADD A,B
RET
;
; ROUTINE TO EXTRACT THE (BC) BLOCK BYTE FROM THE FCB POINTED
; TO BY (PARAMS). IF THIS IS A BIG-DISK, THEN THESE ARE 16 BIT
; BLOCK NUMBERS, ELSE THEY ARE 8 BIT NUMBERS.
; NUMBER IS RETURNED IN (HL).
;
EXTBLK: LD HL,(PARAMS) ; GET FCB ADDRESS.
LD DE,#16 ; BLOCK NUMBERS START 16 BYTES INTO FCB.
ADD HL,DE
ADD HL,BC
LD A,(BIGDISK) ; ARE WE USING A BIG-DISK?
OR A
JP Z,EXTBLK1
LD L,(HL) ; NO, EXTRACT AN 8 BIT NUMBER FROM THE FCB.
LD H,#0
RET
EXTBLK1:ADD HL,BC ; YES, EXTRACT A 16 BIT NUMBER.
LD E,(HL)
INC HL
LD D,(HL)
EX DE,HL ; RETURN IN (HL).
RET
;
; COMPUTE BLOCK NUMBER.
;
COMBLK: CALL GETBLOCK
LD C,A
LD B,#0
CALL EXTBLK
LD (BLKNMBR),HL
RET
;
; CHECK FOR A ZERO BLOCK NUMBER (UNUSED).
;
CHKBLK: LD HL,(BLKNMBR)
LD A,L ; IS IT ZERO?
OR H
RET
;
; ADJUST PHYSICAL BLOCK (BLKNMBR) AND CONVERT TO LOGICAL
; SECTOR (LOGSECT). THIS IS THE STARTING SECTOR OF THIS BLOCK.
; THE ACTUAL SECTOR OF INTEREST IS THEN ADDED TO THIS AND THE
; RESULTING SECTOR NUMBER IS STORED BACK IN (BLKNMBR). THIS
; WILL STILL HAVE TO BE ADJUSTED FOR THE TRACK NUMBER.
;
LOGICAL:LD A,(BLKSHFT) ; GET LOG2(PHYSICAL/LOGICAL SECTORS).
LD HL,(BLKNMBR) ; GET PHYSICAL SECTOR DESIRED.
LOGICL1:ADD HL,HL ; COMPUTE LOGICAL SECTOR NUMBER.
DEC A ; NOTE LOGICAL SECTORS ARE 128 BYTES LONG.
JP NZ,LOGICL1
LD (LOGSECT),HL ; SAVE LOGICAL SECTOR.
LD A,(BLKMASK) ; GET BLOCK MASK.
LD C,A
LD A,(SAVNREC) ; GET NEXT SECTOR TO ACCESS.
AND C ; EXTRACT THE RELATIVE POSITION WITHIN PHYSICAL BLOCK.
OR L ; AND ADD IT TOO LOGICAL SECTOR.
LD L,A
LD (BLKNMBR),HL ; AND STORE.
RET
;
; SET (HL) TO POINT TO EXTENT BYTE IN FCB.
;
SETEXT: LD HL,(PARAMS)
LD DE,#12 ; IT IS THE TWELTH BYTE.
ADD HL,DE
RET
;
; SET (HL) TO POINT TO RECORD COUNT BYTE IN FCB AND (DE) TO
; NEXT RECORD NUMBER BYTE.
;
SETHLDE:LD HL,(PARAMS)
LD DE,#15 ; RECORD COUNT BYTE (#15).
ADD HL,DE
EX DE,HL
LD HL,#17 ; NEXT RECORD NUMBER (#32).
ADD HL,DE
RET
;
; SAVE CURRENT FILE DATA FROM FCB.
;
STRDATA:CALL SETHLDE
LD A,(HL) ; GET AND STORE RECORD COUNT BYTE.
LD (SAVNREC),A
EX DE,HL
LD A,(HL) ; GET AND STORE NEXT RECORD NUMBER BYTE.
LD (SAVNXT),A
CALL SETEXT ; POINT TO EXTENT BYTE.
LD A,(EXTMASK) ; GET EXTENT MASK.
AND (HL)
LD (SAVEXT),A ; AND SAVE EXTENT HERE.
RET
;
; SET THE NEXT RECORD TO ACCESS. IF (MODE) IS SET TO 2, THEN
; THE LAST RECORD BYTE (SAVNREC) HAS THE CORRECT NUMBER TO ACCESS.
; FOR S.EQUENTIAL ACCESS, (MODE) WILL BE .EQUAL TO 1.
;
SETNREC:CALL SETHLDE
LD A,(MODE) ; GET S.EQUENTIAL FLAG (=1).
CP #2 ; A 2 INDICATES THAT NO ADDER IS NEEDED.
JP NZ,STNREC1
XOR A ; CLEAR ADDER (RANDOM ACCESS?).
STNREC1:LD C,A
LD A,(SAVNREC) ; GET LAST RECORD NUMBER.
ADD A,C ; INCREMENT RECORD COUNT.
LD (HL),A ; AND SET FCB'S NEXT RECORD BYTE.
EX DE,HL
LD A,(SAVNXT) ; GET NEXT RECORD BYTE FROM STORAGE.
LD (HL),A ; AND PUT THIS INTO FCB AS NUMBER OF RECORDS USED.
RET
;
; SHIFT (HL) RIGHT (C) BITS.
;
SHIFTR: INC C
SHIFTR1:DEC C
RET Z
LD A,H
OR A
RRA
LD H,A
LD A,L
RRA
LD L,A
JP SHIFTR1
;
; COMPUTE THE CHECK-SUM FOR THE DIRECTORY BUFFER. RETURN
; INTEGER SUM IN (A).
;
CHECKSUM:
LD C,#128 ; LENGTH OF BUFFER.
LD HL,(DIRBUF) ; GET ITS LOCATION.
XOR A ; CLEAR SUMMATION BYTE.
CHKSUM1:ADD A,(HL) ; AND COMPUTE SUM IGNORING CARRIES.
INC HL
DEC C
JP NZ,CHKSUM1
RET
;
; SHIFT (HL) LEFT (C) BITS.
;
SHIFTL: INC C
SHIFTL1:DEC C
RET Z
ADD HL,HL ; SHIFT LEFT 1 BIT.
JP SHIFTL1
;
; ROUTINE TO SET A BIT IN A 16 BIT VALUE CONTAINED IN (BC).
; THE BIT SET DEPENDS ON THE CURRENT DRIVE SELECTION.
;
SETBIT: PUSH BC ; SAVE 16 BIT WORD.
LD A,(ACTIVE) ; GET ACTIVE DRIVE.
LD C,A
LD HL,#1
CALL SHIFTL ; SHIFT BIT 0 INTO PLACE.
POP BC ; NOW 'OR' THIS WITH THE ORIGINAL WORD.
LD A,C
OR L
LD L,A ; LOW BYTE DONE, DO HIGH BYTE.
LD A,B
OR H
LD H,A
RET
;
; EXTRACT THE WRITE PROTECT STATUS BIT FOR THE CURRENT DRIVE.
; THE RESULT IS RETURNED IN (A), BIT 0.
;
GETWPRT:LD HL,(WRTPRT) ; GET STATUS BYTES.
LD A,(ACTIVE) ; WHICH DRIVE IS CURRENT?
LD C,A
CALL SHIFTR ; SHIFT STATUS SUCH THAT BIT 0 IS THE
LD A,L ; ONE OF INTEREST FOR THIS DRIVE.
AND #1 ; AND ISOLATE IT.
RET
;
; FUNCTION TO WRITE PROTECT THE CURRENT DISK.
;
WRTPRTD:LD HL,#WRTPRT ; POINT TO STATUS WORD.
LD C,(HL) ; SET (BC) .EQUAL TO THE STATUS.
INC HL
LD B,(HL)
CALL SETBIT ; AND SET THIS BIT ACCORDING TO CURRENT DRIVE.
LD (WRTPRT),HL ; THEN SAVE.
LD HL,(DIRSIZE) ; NOW SAVE DIRECTORY SIZE LIMIT.
INC HL ; REMEMBER THE LAST ONE.
EX DE,HL
LD HL,(SCRATCH1) ; AND STORE IT HERE.
LD (HL),E ; PUT LOW BYTE.
INC HL
LD (HL),D ; THEN HIGH BYTE.
RET
;
; CHECK FOR A READ ONLY FILE.
;
CHKROFL:CALL FCB2HL ; SET (HL) TO FILE ENTRY IN DIRECTORY BUFFER.
CKROF1: LD DE,#9 ; LOOK AT BIT 7 OF THE NINTH BYTE.
ADD HL,DE
LD A,(HL)
RLA
RET NC ; RETURN IF OK.
LD HL,#ROFILE ; ELSE, PRINT ERROR MESSAGE AND TERMINATE.
JP JUMPHL
;
; CHECK THE WRITE PROTECT STATUS OF THE ACTIVE DISK.
;
CHKWPRT:CALL GETWPRT
RET Z ; RETURN IF OK.
LD HL,#RODISK ; ELSE PRINT MESSAGE AND TERMINATE.
JP JUMPHL
;
; ROUTINE TO SET (HL) POINTING TO THE PROPER ENTRY IN THE
; DIRECTORY BUFFER.
;
FCB2HL: LD HL,(DIRBUF) ; GET ADDRESS OF BUFFER.
LD A,(FCBPOS) ; RELATIVE POSITION OF FILE.
;
; ROUTINE TO ADD (A) TO (HL).
;
ADDA2HL:ADD A,L
LD L,A
RET NC
INC H ; TAKE CARE OF ANY CARRY.
RET
;
; ROUTINE TO GET THE 'S2' BYTE FROM THE FCB SUPPLIED IN
; THE INITIAL PARAMETER SPECIFICATION.
;
GETS2: LD HL,(PARAMS) ; GET ADDRESS OF FCB.
LD DE,#14 ; RELATIVE POSITION OF 'S2'.
ADD HL,DE
LD A,(HL) ; EXTRACT THIS BYTE.
RET
;
; CLEAR THE 'S2' BYTE IN THE FCB.
;
CLEARS2:CALL GETS2 ; THIS SETS (HL) POINTING TO IT.
LD (HL),#0 ; NOW CLEAR IT.
RET
;
; SET BIT 7 IN THE 'S2' BYTE OF THE FCB.
;
SETS2B7:CALL GETS2 ; GET THE BYTE.
OR #0x80 ; AND SET BIT 7.
LD (HL),A ; THEN STORE.
RET
;
; COMPARE (FILEPOS) WITH (SCRATCH1) AND SET FLAGS BASED ON
; THE DIFFERENCE. THIS CHECKS TO SEE IF THERE ARE MORE FILE
; NAMES IN THE DIRECTORY. WE ARE AT (FILEPOS) AND THERE ARE
; (SCRATCH1) OF THEM TO CHECK.
;