forked from fantaisie-software/purebasic
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathTemplates.pb
1112 lines (850 loc) · 36 KB
/
Templates.pb
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; --------------------------------------------------------------------------------------------
; Copyright (c) Fantaisie Software. All rights reserved.
; Dual licensed under the GPL and Fantaisie Software licenses.
; See LICENSE and LICENSE-FANTAISIE in the project root for license information.
; --------------------------------------------------------------------------------------------
;TODO: mac: edit menu in treegadget and edit window!
Structure Template
Name$
IsDirectory.l
Sublevel.l
IsExpanded.l ; for directories
Comment$
Code$
EndStructure
Global NewList Template.Template()
Global Template_Selection
Global Template_FirstVisible
Global Template_Splitter
Global Template_AskDelete, Backup_Template_AskDelete
Global Template_DragItem
Global TemplateWindowDialog.DialogWindow, TemplateWindowPosition.DialogPosition
Global *Templates.ToolsPanelEntry ; for global access to the data...
Procedure.s Template_Escape(String$)
ProcedureReturn ReplaceString(ReplaceString(String$, "\", "\\"), #NewLine, "\n")
EndProcedure
Procedure.s Template_Unescape(String$, NewlineSequence$ = #NewLine)
;
; A simple ReplaceString() does not work, as "\n" is escaped to "\\n", so
; no matter how the replaces are done, a newline gets inserted.
;
Index = 1
Length = Len(String$)
While Index < Length ; last character needs no checking, as escape sequences are 2 chars
If Mid(String$, Index, 2) = "\\"
String$ = Left(String$, index-1) + Right(String$, Length-index) ; cut one of the \
Length - 1
ElseIf Mid(String$, Index, 2) = "\n"
String$ = Left(String$, index-1) + NewlineSequence$ + Right(String$, Length-index-1) ; cut all the \n
Length - 2 + Len(NewlineSequence$)
EndIf
Index + 1
Wend
ProcedureReturn String$
EndProcedure
CompilerIf #CompileWindows
Procedure TreeGadgetItemNumber(GadgetID, ItemHandle)
Count = CountGadgetItems(GadgetID)
For k = 0 To Count-1
If GadgetItemID(GadgetID, k) = ItemHandle
ProcedureReturn k
EndIf
Next
ProcedureReturn -1
EndProcedure
CompilerEndIf
Procedure Template_Save()
If CreateFile(#FILE_Template, TemplatesFile$)
WriteStringN(#FILE_Template, "TEMPLATES:1.0")
WriteStringN(#FILE_Template, "")
sublevel = 0
ForEach Template()
While Template()\Sublevel < sublevel
sublevel - 1
WriteStringN(#FILE_Template, Space(sublevel*2)+"CloseDirectory")
Wend
If Template()\IsDirectory
WriteStringN(#FILE_Template, Space(sublevel*2)+"Directory: "+Template()\Name$)
If Template()\IsExpanded
WriteStringN(#FILE_Template, Space(sublevel*2)+"Expanded")
EndIf
sublevel + 1
Else
WriteStringN(#FILE_Template, Space(sublevel*2)+"Template: "+Template()\Name$)
If Template()\Comment$ <> ""
WriteStringN(#FILE_Template, Space(sublevel*2+2)+"Comment: "+Template()\Comment$)
EndIf
WriteStringN(#FILE_Template, Space(sublevel*2+2)+"Code: "+Template()\Code$)
EndIf
Next Template()
While sublevel > 0
sublevel - 1
WriteStringN(#FILE_Template, Space(sublevel*2)+"CloseDirectory")
Wend
CloseFile(#FILE_Template)
EndIf
EndProcedure
Procedure Template_UpdateGadgetStates()
If IsWindow(#WINDOW_Template)
; disable template window
For i = #GADGET_Template_Add To #GADGET_Template_Tree
DisableGadget(i, 1)
Next i
Else
index = GetGadgetState(#GADGET_Template_Tree)
If index = -1
DisableGadget(#GADGET_Template_Edit, 1)
DisableGadget(#GADGET_Template_Remove, 1)
DisableGadget(#GADGET_Template_RemoveDir, 1)
DisableGadget(#GADGET_Template_Up, 1)
DisableGadget(#GADGET_Template_Down, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Use, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Edit, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Remove, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_RemoveDir, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Rename, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Up, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Down, 1)
SetGadgetText(#GADGET_Template_Comment, "")
Else
SelectElement(Template(), index)
If Template()\IsDirectory
DisableGadget(#GADGET_Template_Edit, 1)
DisableGadget(#GADGET_Template_Remove, 1)
DisableGadget(#GADGET_Template_RemoveDir, 0)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Use, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Edit, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Remove, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_RemoveDir, 0)
SetGadgetText(#GADGET_Template_Comment, "")
Else
DisableGadget(#GADGET_Template_Edit, 0)
DisableGadget(#GADGET_Template_Remove, 0)
DisableGadget(#GADGET_Template_RemoveDir, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Use, 0)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Edit, 0)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Remove, 0)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_RemoveDir, 1)
SetGadgetText(#GADGET_Template_Comment, Template_Unescape(Template()\Comment$))
EndIf
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Rename, 0)
Sublevel = Template()\Sublevel
If PreviousElement(Template()) = 0 Or Template()\Sublevel < Sublevel
DisableGadget(#GADGET_Template_Up, 1)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Up, 1)
Else
DisableGadget(#GADGET_Template_Up, 0)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Up, 0)
EndIf
SelectElement(Template(), index)
disable = 1
While NextElement(Template())
If Template()\Sublevel = Sublevel
disable = 0
Break
ElseIf Template()\Sublevel < Sublevel
Break
EndIf
Wend
DisableGadget(#GADGET_Template_Down, disable)
DisableMenuItem(#POPUPMENU_Template, #MENU_Template_Down, disable)
EndIf
EndIf
EndProcedure
Procedure TemplateWindowEvents(EventID)
If EventID = #PB_Event_CloseWindow
If MemorizeWindow
TemplateWindowDialog\Close(@TemplateWindowPosition)
Else
TemplateWindowDialog\Close()
EndIf
If *Templates ; if its a separate window, it may be closed!
For i = #GADGET_Template_Add To #GADGET_Template_Tree
DisableGadget(i, 0) ; re-enable all gadgets
Next i
Template_UpdateGadgetStates() ; update the disabled state
; put focus back on templates window if it is separate
If *Templates\IsSeparateWindow
SetActiveWindow(*Templates\ToolWindowID)
EndIf
SetActiveGadget(#GADGET_Template_Tree)
EndIf
ElseIf EventID = #PB_Event_Gadget
If EventGadget() = #GADGET_Template_Save
Length = ScintillaSendMessage(#GADGET_Template_Editor, #SCI_GETTEXTLENGTH, 0, 0)
Text$ = Space(Length)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_GETTEXT, Length+1, @Text$)
Template()\Code$ = Template_Escape(PeekS(@Text$, -1, #PB_UTF8))
Length = ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_GETTEXTLENGTH, 0, 0)
Text$ = Space(Length)
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_GETTEXT, Length+1, @Text$)
Template()\Comment$ = Template_Escape(PeekS(@Text$, -1, #PB_UTF8))
SetGadgetText(#GADGET_Template_Comment, GetGadgetText(#GADGET_Template_SetComment))
TemplateWindowEvents(#PB_Event_CloseWindow) ; close the window
; Write the templates immediately to disk, so if the IDE crash or force closed, it won't be lost
Template_Save()
ElseIf EventGadget() = #GADGET_Template_Cancel
TemplateWindowEvents(#PB_Event_CloseWindow)
EndIf
ElseIf EventID = #PB_Event_SizeWindow
TemplateWindowDialog\SizeUpdate()
EndIf
EndProcedure
Procedure OpenTemplateWindow()
TemplateWindowDialog = OpenDialog(?Dialog_Templates, WindowID(#WINDOW_Main), @TemplateWindowPosition)
If TemplateWindowDialog
EnsureWindowOnDesktop(#WINDOW_Template)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_USEPOPUP, 1, 0) ; use the scintilla popup
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_SETMARGINWIDTHN, 0, 0)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_SETMARGINWIDTHN, 1, 0)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_STYLESETFONT, #STYLE_DEFAULT, ToAscii(EditorFontName$))
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_STYLESETSIZE, #STYLE_DEFAULT, EditorFontSize)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_STYLECLEARALL, 0, 0)
Text$ = Template_Unescape(Template()\Code$)
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_SETTEXT, 0, ToUTF8(Text$))
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_USEPOPUP, 1, 0) ; use the scintilla popup
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETMARGINWIDTHN, 0, 0)
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETMARGINWIDTHN, 1, 0)
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETWRAPMODE, 1, 0) ; wrap at word boundaries
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_STYLESETFONT, #STYLE_DEFAULT, ToAscii(EditorFontName$))
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_STYLESETSIZE, #STYLE_DEFAULT, EditorFontSize)
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_STYLECLEARALL, 0, 0)
Text$ = Template_Unescape(Template()\Comment$)
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETTEXT, 0, ToUTF8(Text$))
CompilerIf #CompileWindows
; Use system defaults for selected text for screenreader access
;
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_SETSELBACK, 1, GetSysColor_(#COLOR_HIGHLIGHT))
ScintillaSendMessage(#GADGET_Template_Editor, #SCI_SETSELFORE, 1, GetSysColor_(#COLOR_HIGHLIGHTTEXT))
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETSELBACK, 1, GetSysColor_(#COLOR_HIGHLIGHT))
ScintillaSendMessage(#GADGET_Template_SetComment, #SCI_SETSELFORE, 1, GetSysColor_(#COLOR_HIGHLIGHTTEXT))
CompilerEndIf
; disable template window
For i = #GADGET_Template_Add To #GADGET_Template_Tree
DisableGadget(i, 1)
Next i
HideWindow(#WINDOW_Template, 0)
EndIf
EndProcedure
Procedure UpdateTemplateWindow()
; since the toolpanel is recreated on a prefs update, we should make sure
; this window gets closed, not updated.. to prevent any invalid input to happen
;
TemplateWindowEvents(#PB_Event_CloseWindow)
EndProcedure
Procedure Template_SaveState()
currentindex = ListIndex(Template())
Template_Selection = GetGadgetState(#GADGET_Template_Tree)
ForEach Template()
If Template()\IsDirectory
Template()\IsExpanded = GetGadgetItemState(#GADGET_Template_Tree, ListIndex(Template())) & #PB_Tree_Expanded
EndIf
Next Template()
CompilerIf #CompileWindows
Template_FirstVisible = TreeGadgetItemNumber(#GADGET_Template_Tree, SendMessage_(GadgetID(#GADGET_Template_Tree), #TVM_GETNEXTITEM, #TVGN_FIRSTVISIBLE, 0))
CompilerEndIf
If currentindex = -1
ResetList(Template())
Else
SelectElement(Template(), currentindex)
EndIf
EndProcedure
Procedure Template_FillTree()
StartGadgetFlickerFix(#GADGET_Template_Tree)
ClearGadgetItems(#GADGET_Template_Tree)
sublevel = 0
ForEach Template()
; close necessary nodes..
While Template()\sublevel < sublevel
sublevel - 1
Wend
If Template()\IsDirectory
AddGadgetItem(#GADGET_Template_Tree, -1, Template()\Name$, ImageID(#IMAGE_Template_Dir), sublevel)
sublevel + 1
Else
AddGadgetItem(#GADGET_Template_Tree, -1, Template()\Name$, ImageID(#IMAGE_Template_Template), sublevel)
EndIf
Next Template()
;
; Apply the recently saved items state
;
SetGadgetState(#GADGET_Template_Tree, Template_Selection)
ForEach Template()
If Template()\IsDirectory And Template()\IsExpanded
SetGadgetItemState(#GADGET_Template_Tree, ListIndex(Template()), #PB_Tree_Expanded)
EndIf
Next Template()
CompilerIf #CompileWindows
SendMessage_(GadgetID(#GADGET_Template_Tree), #TVM_ENSUREVISIBLE, 0, GadgetItemID(#GADGET_Template_Tree, Template_FirstVisible))
CompilerEndIf
Template_UpdateGadgetStates()
StopGadgetFlickerFix(#GADGET_Template_Tree)
EndProcedure
Procedure Template_Insert()
If *ActiveSource <> *ProjectInfo
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
SelectElement(Template(), index)
If Template()\IsDirectory = 0
; build the string to put before each line (except the first)
;
Prefix$ = ""
GetCursorPosition() ; update cursor position values
Line$ = Left(GetLine(*ActiveSource\CurrentLine-1), *ActiveSource\CurrentColumnChars-1)
While Asc(Line$) = ' ' Or Asc(Line$) = 9 ; process all the space/tab combinations
Prefix$ + Left(Line$, 1)
Line$ = Right(Line$, Len(Line$)-1)
Wend
Prefix$ + Space(Len(Line$)) ; replace remaining characters by spaces
Template$ = Template_Unescape(Template()\Code$)
Code$ = ReplaceString(Template$, #NewLine, #NewLine+Prefix$)
InsertCodeString(Code$)
SetActiveGadget(*ActiveSource\EditorGadget)
EndIf
EndIf
EndIf
EndProcedure
Procedure Template_MoveElement(*Element.Template, *Target.Template, Type)
Template_SaveState()
; save the position of the item after the *Element!
;
ChangeCurrentElement(Template(), *Element)
If NextElement(Template())
*GetPoint.Template = @Template()
Else
*GetPoint = 0
EndIf
; first we just move the element itself
;
ChangeCurrentElement(Template(), *Target)
If Type = 1 ; move up
InsertElement(Template())
ElseIf Type = 2 ; move down
If *Target\IsDirectory = 0 ; we must skip the directory of the target first
AddElement(Template())
Else
Repeat
If NextElement(Template()) = 0
AddElement(Template())
Break
EndIf
If Template()\Sublevel <= *Target\Sublevel
InsertElement(Template())
Break
EndIf
ForEver
EndIf
ElseIf Type = 3 ; drag & drop
If *Target\IsDirectory = 0
InsertElement(Template())
Else
AddElement(Template())
EndIf
EndIf
*New.Template = @Template()
SwapElements(Template(), *Element, *New)
ChangeCurrentElement(Template(), *New) ; remove the dummy element again
DeleteElement(Template())
Sublevel = *Element\Sublevel
If Type = 3 And *Target\IsDirectory
*Element\Sublevel = *Target\Sublevel + 1
Else
*Element\Sublevel = *Target\Sublevel
EndIf
If *Element\IsDirectory = 1 ; we must move the rest of the directory
*AddPoint.Template = *Element ; we add all the children after the element
While *GetPoint And *GetPoint\Sublevel > Sublevel
ChangeCurrentElement(Template(), *GetPoint) ; save the next item position first!
If NextElement(Template())
*NewGetPoint.Template = @Template()
Else
*NewGetPouint = 0
EndIf
ChangeCurrentElement(Template(), *AddPoint)
AddElement(Template())
*New.Template = @Template()
SwapElements(Template(), *New, *GetPoint)
ChangeCurrentElement(Template(), *New)
DeleteElement(Template())
If Type = 3 And *Target\IsDirectory
*GetPoint\Sublevel - (Sublevel - *Target\Sublevel) + 1
Else
*GetPoint\Sublevel - (Sublevel - *Target\Sublevel)
EndIf
*AddPoint = *GetPoint
*GetPoint = *NewGetPoint ; move to the next item
Wend
EndIf
ChangeCurrentElement(Template(), *Element)
Template_Selection = ListIndex(Template()) ; mark the moved element as selected one
Template_FillTree()
EndProcedure
; Called on a #PB_Event_GadgetDrop on the Tree. As this is a separate event
; from #PB_Event_Gadget, the EventHandler() will not get it itself.
Procedure Template_DropEvent()
Target = GetGadgetState(#GADGET_Template_Tree)
If Target = -1
Target = CountGadgetItems(#GADGET_Template_Tree)-1
EndIf
; verify and do the move
;
If Template_DragItem <> Target
SelectElement(Template(), Template_DragItem)
*Element.Template = @Template()
SelectElement(Template(), Target)
*Target.Template = @Template()
If Target < Template_DragItem ; moving up is always valid
Template_MoveElement(*Element, *Target, 3)
ElseIf *Element\IsDirectory ; cannot move a directory into itself.. check that
While PreviousElement(Template()) And @Template() <> *Element ; move from target to source
If Template()\Sublevel <= *Element\Sublevel ; target is not inside the source
Template_MoveElement(*Element, *Target, 3)
Break
EndIf
Wend
Else ; a template can be moved everywhere
Template_MoveElement(*Element, *Target, 3)
EndIf
EndIf
EndProcedure
Procedure Template_CreateFunction(*Entry.ToolsPanelEntry)
Shared Templae_FirstResize
ButtonImageGadget(#GADGET_Template_Add, 0, 0, 0, 0, ImageID(#IMAGE_Template_Add))
ButtonImageGadget(#GADGET_Template_Edit, 0, 0, 0, 0, ImageID(#IMAGE_Template_Edit))
ButtonImageGadget(#GADGET_Template_Remove, 0, 0, 0, 0, ImageID(#IMAGE_Template_Remove))
ButtonImageGadget(#GADGET_Template_AddDir, 0, 0, 0, 0, ImageID(#IMAGE_Template_AddDir))
ButtonImageGadget(#GADGET_Template_RemoveDir, 0, 0, 0, 0, ImageID(#IMAGE_Template_RemoveDir))
ButtonImageGadget(#GADGET_Template_Up, 0, 0, 0, 0, ImageID(#IMAGE_Template_Up))
ButtonImageGadget(#GADGET_Template_Down, 0, 0, 0, 0, ImageID(#IMAGE_Template_Down))
GadgetToolTip(#GADGET_Template_Add, Language("Templates","New"))
GadgetToolTip(#GADGET_Template_Edit, Language("Templates","Edit"))
GadgetToolTip(#GADGET_Template_Remove, Language("Templates","Delete"))
GadgetToolTip(#GADGET_Template_AddDir, Language("Templates","NewDir"))
GadgetToolTip(#GADGET_Template_RemoveDir, Language("Templates","DeleteDir"))
GadgetToolTip(#GADGET_Template_Up, Language("Templates","Up"))
GadgetToolTip(#GADGET_Template_Down, Language("Templates","Down"))
TreeGadget(#GADGET_Template_Tree, 0, 0, 0, 0, #PB_Tree_AlwaysShowSelection)
TextGadget(#GADGET_Template_Comment, 0, 0, 0, 0, "", #PB_Text_Border)
;SplitterGadget(#GADGET_Template_Splitter, 0, 0, 0, 0, #GADGET_Template_Tree, #GADGET_Template_Comment, #PB_Splitter_SecondFixed)
Templae_FirstResize = 1 ; to set the splitter pos after! the resize
If EnableMenuIcons
*Popup = CreatePopupImageMenu(#POPUPMENU_Template)
Else
*Popup = CreatePopupMenu(#POPUPMENU_Template)
EndIf
If *Popup
MenuItem(#MENU_Template_Use, Language("Templates","MenuUse"))
MenuBar()
MenuItem(#MENU_Template_New, Language("Templates","MenuNew"), ImageID(#IMAGE_Template_Add))
MenuItem(#MENU_Template_Edit, Language("Templates","MenuEdit"), ImageID(#IMAGE_Template_Edit))
MenuItem(#MENU_Template_Remove, Language("Templates","MenuDelete"), ImageID(#IMAGE_Template_Remove))
MenuBar()
MenuItem(#MENU_Template_NewDir, Language("Templates","MenuNewDir"), ImageID(#IMAGE_Template_AddDir))
MenuItem(#MENU_Template_RemoveDir, Language("Templates","MenuDeleteDir"), ImageID(#IMAGE_Template_RemoveDir))
MenuBar()
MenuItem(#MENU_Template_Rename, Language("Templates","MenuRename"))
MenuBar()
MenuItem(#MENU_Template_Up, Language("Templates","MenuUp"), ImageID(#IMAGE_Template_Up))
MenuItem(#MENU_Template_Down, Language("Templates","MenuDown"), ImageID(#IMAGE_Template_Down))
EndIf
Template_FillTree()
If *Entry\IsSeparateWindow = 0 Or NoIndependentToolsColors = 0
ToolsPanel_ApplyColors(#GADGET_Template_Tree)
EndIf
EnableGadgetDrop(#GADGET_Template_Tree, #PB_Drop_Private, #PB_Drag_Move, #DRAG_Templates)
CompilerIf #CompileLinuxGtk
; the gtk label is by default not wrapping lines
gtk_label_set_line_wrap_(GadgetID(#GADGET_Template_Comment), #True)
CompilerEndIf
*Templates = *Entry
EndProcedure
Procedure Template_DestroyFunction(*Entry.ToolsPanelEntry)
Template_SaveState()
*Templates = 0
EndProcedure
Procedure Template_ResizeHandler(*Entry.ToolsPanelEntry, PanelWidth, PanelHeight)
Shared Templae_FirstResize
;TODO: templates - splitterproblem (should be fixed and enabled again)
; ResizeGadget(#GADGET_Template_Splitter, 0, 32, PanelWidth, PanelHeight-32)
; If Templae_FirstResize
; SetGadgetState(#GADGET_Template_Splitter, PanelHeight-32-Template_Splitter)
; Templae_FirstResize = 0
; Else
; Template_Splitter = PanelHeight-32-GetGadgetState(#GADGET_Template_Splitter)
; EndIf
; All the buttons should have the same size, so only call it once
;
GetRequiredSize(#GADGET_Template_Add, @Width.l, @Height.l)
CompilerIf #CompileWindows
Space = 5
CompilerElse
Space = 8 ; looks better on Linux/OSX with some more space
CompilerEndIf
x = 5
ResizeGadget(#GADGET_Template_Add, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_Edit, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_Remove, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_AddDir, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_RemoveDir, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_Up, x, 5, Width, Height): x + Width + Space
ResizeGadget(#GADGET_Template_Down, x, 5, Width, Height)
If *Entry\IsSeparateWindow
ResizeGadget(#GADGET_Template_Tree, 5, 10+Height, PanelWidth-10, PanelHeight-Height-80)
ResizeGadget(#GADGET_Template_Comment, 5, PanelHeight-65, PanelWidth-10, 60)
Else
ResizeGadget(#GADGET_Template_Tree, 0, 10+Height, PanelWidth, PanelHeight-Height-80)
ResizeGadget(#GADGET_Template_Comment, 0, PanelHeight-65, PanelWidth, 65)
EndIf
CompilerIf #CompileLinuxGtk
; required for the TextGadget() to correctly wrap the lines
; sets the gtklabel's size request to the size of the gtkeventbox
; (see gtk_label_set_line_wrap_() documentation for an explanation)
gtk_widget_set_size_request_(GadgetID(#GADGET_Template_Comment), GadgetWidth(#GADGET_Template_Comment)-4, -1)
CompilerEndIf
EndProcedure
Procedure Template_EventHandler(*Entry.ToolsPanelEntry, EventGadgetID)
Static DragItem
Select EventGadgetID
Case #GADGET_Template_Add
Name$ = InputRequester(Language("Templates","Title"), Language("Templates","EnterName")+":", "")
If Name$ <> ""
Template_SaveState()
index = GetGadgetState(#GADGET_Template_Tree)
If index = -1
LastElement(Template())
AddElement(Template())
Sublevel = 0
Else
SelectElement(Template(), index)
Sublevel = Template()\Sublevel
If Template()\IsDirectory
IsExpanded = Template()\IsExpanded
IsEmpty = 1
Repeat
If NextElement(Template()) = 0
AddElement(Template())
Break
EndIf
If Template()\Sublevel <= Sublevel
InsertElement(Template())
Break
EndIf
IsEmpty = 0 ; at least one item was found
ForEver
If IsExpanded Or IsEmpty ; only add as child to opened dirs, or if it was new
Sublevel + 1
EndIf
Else
AddElement(Template())
EndIf
EndIf
Template()\Name$ = Name$
Template()\IsDirectory = 0
Template()\Sublevel = Sublevel
index = ListIndex(Template())
Template_FillTree()
SetGadgetState(#GADGET_Template_Tree, index)
SelectElement(Template(), index)
OpenTemplateWindow() ; start editing this template
EndIf
Case #GADGET_Template_Edit
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
SelectElement(Template(), index)
If Template()\IsDirectory = 0
OpenTemplateWindow() ; start editing this item
EndIf
EndIf
Case #GADGET_Template_Remove
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
SelectElement(Template(), index)
If Template()\IsDirectory = 0
If Template_AskDelete
If MessageRequester(#ProductName$, Language("Templates", "DeleteQuestion"), #FLAG_QUESTION|#PB_MessageRequester_YesNo) = #PB_MessageRequester_Yes
Template_SaveState()
DeleteElement(Template())
Template_FillTree()
EndIf
Else
Template_SaveState()
DeleteElement(Template())
Template_FillTree()
EndIf
EndIf
EndIf
Case #GADGET_Template_AddDir
Name$ = InputRequester(Language("Templates","Title"), Language("Templates","EnterDirName")+":", "")
If Name$ <> ""
Template_SaveState()
index = GetGadgetState(#GADGET_Template_Tree)
If index = -1
LastElement(Template())
AddElement(Template())
Sublevel = 0
Else
SelectElement(Template(), index)
Sublevel = Template()\Sublevel
If Template()\IsDirectory
IsExpanded = Template()\IsExpanded
IsEmpty = 1
Repeat
If NextElement(Template()) = 0
AddElement(Template())
Break
EndIf
If Template()\Sublevel <= Sublevel
InsertElement(Template())
Break
EndIf
IsEmpty = 0 ; at least one item was found
ForEver
If IsExpanded Or IsEmpty ; only add as child to opened dirs, or if it was new
Sublevel + 1
EndIf
Else
AddElement(Template())
EndIf
EndIf
index = ListIndex(Template())
Template()\Name$ = Name$
Template()\IsDirectory = 1
Template()\Sublevel = Sublevel
Template_FillTree()
SetGadgetState(#GADGET_Template_Tree, index)
EndIf
Case #GADGET_Template_RemoveDir
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
SelectElement(Template(), index)
If Template()\IsDirectory
Sublevel = Template()\Sublevel
If NextElement(Template())
If Template()\Sublevel > Sublevel ; this is a subitem of the dir
delete = 0
Else
delete = 1 ; directory is empty
EndIf
PreviousElement(Template()) ; go back to the current!
Else
delete = 1 ; it is the last one in the gadget, so it is empty.
EndIf
If delete = 0
If MessageRequester(#ProductName$, Language("Templates","DeleteNonEmpty"), #FLAG_QUESTION|#PB_MessageRequester_YesNo) = #PB_MessageRequester_Yes
delete = 1
EndIf
EndIf
If delete
Template_SaveState()
Repeat
DeleteElement(Template())
Until NextElement(Template()) = 0 Or Template()\Sublevel <= Sublevel
Template_FillTree()
EndIf
EndIf
EndIf
Case #GADGET_Template_Rename ; not real gadgets, but used for wrappers of the menu
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
; CompilerIf #CompileWindows
; SendMessage_(GadgetID(#GADGET_Template_Tree), #TVM_EDITLABEL, 0, GadgetItemID(#GADGET_Template_Tree, index))
;
; CompilerElse
SelectElement(Template(), index)
If Template()\IsDirectory
Title$ = Language("Templates","EnterDirName")
Else
Title$ = Language("Templates","EnterName")
EndIf
Name$ = InputRequester(Language("Templates","Title"), Title$, Template()\Name$)
If Name$ <> ""
Template()\Name$ = Name$
SetGadgetItemText(#GADGET_Template_Tree, index, Name$, 0)
EndIf
;
; CompilerEndIf
;
EndIf
Case #GADGET_Template_Use
Template_Insert()
Case #GADGET_Template_Tree
If EventType() = #PB_EventType_DragStart
Template_DragItem = GetGadgetState(#GADGET_Template_Tree)
If Template_DragItem <> -1
DragPrivate(#DRAG_Templates, #PB_Drag_Move)
EndIf
ElseIf EventType() = #PB_EventType_LeftDoubleClick
Template_Insert()
ElseIf EventType() = #PB_EventType_RightClick
Template_UpdateGadgetStates()
If *Entry\IsSeparateWindow
DisplayPopupMenu(#POPUPMENU_Template, WindowID(*Entry\ToolWindowID))
Else
DisplayPopupMenu(#POPUPMENU_Template, WindowID(#WINDOW_Main))
EndIf
Else
Template_UpdateGadgetStates()
EndIf
Case #GADGET_Template_Up
index = GetGadgetState(#GADGET_Template_Tree)
If index > 0
SelectElement(Template(), index)
*Current.Template = @Template()
While PreviousElement(Template())
If Template()\Sublevel = *Current\Sublevel
Template_MoveElement(*Current, @Template(), 1)
Break
ElseIf Template()\Sublevel < *Current\Sublevel
Break
EndIf
Wend
EndIf
Case #GADGET_Template_Down
index = GetGadgetState(#GADGET_Template_Tree)
If index <> -1
SelectElement(Template(), index)
*Current.Template = @Template()
While NextElement(Template())
If Template()\Sublevel = *Current\Sublevel
Template_MoveElement(*Current, @Template(), 2)
Break
ElseIf Template()\Sublevel < *Current\Sublevel
Break
EndIf
Wend
EndIf
EndSelect
EndProcedure
Procedure Template_PreferenceLoad(*Entry.ToolsPanelEntry)
PreferenceGroup("Templates")
TemplateWindowPosition\x = ReadPreferenceLong("WindowX", 100)
TemplateWindowPosition\y = ReadPreferenceLong("WindowY", 200)
TemplateWindowPosition\Width = ReadPreferenceLong("WindowWidth", 500)
TemplateWindowPosition\Height = ReadPreferenceLong("WindowHeight", 400)
Template_Splitter = ReadPreferenceLong("Splitter", 80)
Template_Selection = ReadPreferenceLong("Selection", -1)
Template_FirstVisible = ReadPreferenceLong("FirstVisible", 0)
Template_AskDelete = ReadPreferenceLong("AskDelete", 1)
; now also read the templates file
;
If ReadFile(#FILE_Template, TemplatesFile$)
If ReadString(#FILE_Template) = "TEMPLATES:1.0"
ClearList(Template())
AddElement(Template()) ; dummy element at start to avoid crash when file content is inconsistent (removed later)
sublevel = 0
While Eof(#FILE_Template) = 0
Line$ = ReadString(#FILE_Template)
separator = FindString(Line$, ":", 1)
If separator = 0
Command$ = UCase(Trim(Line$))
Value$ = ""
Else
Command$ = UCase(Trim(Left(Line$, separator-1)))
Value$ = Trim(Right(Line$, Len(Line$)-separator))
EndIf
Select Command$
Case "DIRECTORY"
AddElement(Template())
Template()\sublevel = sublevel
Template()\Name$ = Value$
Template()\IsDirectory = 1
sublevel + 1
Case "TEMPLATE"
AddElement(Template())
Template()\sublevel = sublevel
Template()\Name$ = Value$
Case "EXPANDED"
Template()\IsExpanded = 1
Case "COMMENT"
Template()\Comment$ = Value$
Case "CODE"
Template()\Code$ = Value$
Case "CLOSEDIRECTORY"
sublevel - 1
If sublevel < 0
sublevel = 0
EndIf
EndSelect
Wend
FirstElement(Template())
DeleteElement(Template()) ; remove the dummy element
EndIf
CloseFile(#FILE_Template)
EndIf
EndProcedure
Procedure Template_PreferenceSave(*Entry.ToolsPanelEntry)