wasm miscompilation without LLVM: can modify const value

[knexator]

Zig Version

0.14.0-dev.2647+5322459a0

Steps to Reproduce and Observed Behavior

Create an array of Foo (a struct with a single usize field), take the first element as a const value, and then modify the array. The const element has changed!

main.zig:

const std = @import("std");

// Without a custom log fn, it doesn't compile
pub const std_options = std.Options{
    .logFn = myLogFn,
};
fn myLogFn(
    comptime message_level: std.log.Level,
    comptime scope: @Type(.enum_literal),
    comptime format: []const u8,
    args: anytype,
) void {
    _ = message_level;
    _ = scope;
    _ = format;
    _ = args;
}

extern fn logInt(arg: usize) void;

export fn _start() void {
    bug() catch unreachable;
}

fn bug() !void {
    const Foo = struct {
        k: usize,
    };
    var gpa = std.heap.GeneralPurposeAllocator(.{}).init;
    const alloc = gpa.allocator();
    var foos = std.ArrayList(Foo).init(alloc);
    try foos.append(.{ .k = 0 });
    try foos.append(.{ .k = 1 });
    const first_foo = foos.items[0];
    logInt(first_foo.k);
    _ = foos.orderedRemove(0);
    // The bug persists if we change the above line to:
    // foos.items[0] = foos.items[1];
    logInt(first_foo.k);
}

build.zig:

const std = @import("std");

// JS helper to run the wasm module
const main_js_contents =
    \\const fs = require("fs");
    \\(async () => {
    \\  const wasmBuffer = fs.readFileSync(process.argv[2]);
    \\  const wasmModule = await WebAssembly.instantiate(wasmBuffer, {
    \\    env: { logInt: (arg) => console.log(arg) },
    \\  });
    \\  wasmModule.instance.exports._start();
    \\})();
;

pub fn build(b: *std.Build) void {
    const use_llvm = b.option(bool, "llvm", "use llvm and lld");
    const optimize = b.standardOptimizeOption(.{});
    const exe = b.addExecutable(.{
        .name = "wasm_bug",
        .root_source_file = b.path("main.zig"),
        .optimize = optimize,
        .target = b.resolveTargetQuery(.{
            .cpu_arch = .wasm32,
            .os_tag = .freestanding,
        }),
        .use_llvm = use_llvm,
    });
    exe.import_symbols = true;
    b.installArtifact(exe);

    const write_file_step = b.addWriteFiles();
    const main_js = write_file_step.add("main.js", main_js_contents);
    const launch_node = b.addSystemCommand(&.{"node"});
    launch_node.addFileArg(main_js);
    launch_node.addFileArg(exe.getEmittedBin());
    launch_node.step.dependOn(b.getInstallStep());

    const run_launch_node_step = b.step("run", "run the wasm module");
    run_launch_node_step.dependOn(&launch_node.step);
}

zig build run -Dllmv=false outputs, on my machine, "0 1"

(note that the run is provided only for convenience and requires node installed; feel free to run the .wasm in any other way.)

Expected Behavior

The output should be "0 0", and in fact that's what we see when running zig build run -Dllmv=true.

I've also tried on 0.14.0-dev.2851+b074fb7dd but I can't get it working there; it fails on WebAssembly.instantiate()