-
Notifications
You must be signed in to change notification settings - Fork 1
/
unitdebugger.pas
281 lines (231 loc) · 5.77 KB
/
unitdebugger.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
unit UnitDebugger;
// Copyright 2022-2024 Zoran Vučenović
// SPDX-License-Identifier: Apache-2.0
{$mode ObjFPC}{$H+}
{$i zxinc.inc}
interface
uses
Classes, SysUtils, fgl, LazMethodList, UnitSpectrum, UnitDisassembler;
type
TBreakpointCondition = class(TObject)
private
FCondExprRpn: RawByteString;
FConditionExpr: RawByteString;
procedure SetConditionExpr(AValue: RawByteString);
public
constructor Create;
procedure Clear;
property ConditionExpr: RawByteString read FConditionExpr write SetConditionExpr;
property CondExprRpn: RawByteString read FCondExprRpn write FCondExprRpn;
end;
TBreakpoints = class(specialize TFPGMapObject<Word, TBreakpointCondition>)
public
constructor Create;
end;
TDebugger = class(TSpectrum.TAbstractDebugger)
strict private
type
TBreakpointsW = class(specialize TFPGMap<Word, Word>)
public
constructor Create;
end;
strict private
FBreakpointsWide: TBreakpointsW;
FBreakpoints: TBreakpoints;
FDisassembler: TDisassembler;
FOnBreakpointChangeList: TMethodList;
procedure DoOnBreakpointChange;
public
constructor CreateDebugger; override;
destructor Destroy; override;
procedure SetSpectrum(ASpectrum: TSpectrum); override;
function IsBreakpoint(Addr: Word): Boolean; inline;
function IsOnBreakpoint: Boolean; override;
function BreakpointsEmpty: Boolean; override;
procedure AddBreakpoint(Addr: Word);
procedure RemoveBreakpoint(Addr: Word);
procedure RemoveAllBreakpoints();
procedure AddOnBreakpointChange(ANotifyEvent: TNotifyEvent);
procedure RemoveOnBreakPointChangeHandlerOfObject(AObject: TObject);
property Breakpoints: TBreakpoints read FBreakpoints write FBreakpoints;
property Disassembler: TDisassembler read FDisassembler;
end;
implementation
{ TDebugger.TBreakpointsW }
constructor TDebugger.TBreakpointsW.Create;
begin
inherited Create;
Duplicates := TDuplicates.dupIgnore;
Sorted := True;
end;
{ TBreakpointCondition }
procedure TBreakpointCondition.SetConditionExpr(AValue: RawByteString);
begin
if FConditionExpr <> AValue then begin
FCondExprRpn := '';
FConditionExpr := AValue;
end;
end;
constructor TBreakpointCondition.Create;
begin
Clear;
end;
procedure TBreakpointCondition.Clear;
begin
FConditionExpr := '';
FCondExprRpn := '';
end;
{ TBreakpoints }
constructor TBreakpoints.Create;
begin
inherited Create(True);
Duplicates := TDuplicates.dupIgnore;
Sorted := True;
end;
{ TDebugger }
procedure TDebugger.DoOnBreakpointChange;
var
I: Integer;
begin
if Assigned(FOnBreakpointChangeList) then begin
for I := 0 to FOnBreakpointChangeList.Count - 1 do begin
TNotifyEvent(FOnBreakpointChangeList[I])(Self);
end;
end;
end;
constructor TDebugger.CreateDebugger;
begin
inherited Create;
FOnBreakpointChangeList := nil;
FDisassembler := nil;
FSpectrum := nil;
FBreakpointsWide := TBreakpointsW.Create;
FBreakpoints := TBreakpoints.Create;
end;
destructor TDebugger.Destroy;
begin
FOnBreakpointChangeList.Free;
FBreakpointsWide.Free;
FBreakpoints.Free;
FDisassembler.Free;
inherited Destroy;
end;
function TDebugger.BreakpointsEmpty: Boolean;
begin
Result := FBreakpoints.Count = 0;
end;
procedure TDebugger.SetSpectrum(ASpectrum: TSpectrum);
begin
FSpectrum := ASpectrum;
if FDisassembler = nil then begin
FDisassembler := TDisassembler.Create(FSpectrum.Memory);
end else
FDisassembler.Memory := FSpectrum.Memory;
end;
function TDebugger.IsBreakpoint(Addr: Word): Boolean;
var
N: Integer;
begin
Result := FBreakpoints.Find(Addr, N);
end;
{$push}
{$Q-}{$R-}
function TDebugger.IsOnBreakpoint: Boolean;
var
N: Integer;
W: Word;
I: Word;
begin
W := FSpectrum.GetProcessor.RegPC;
Result := FBreakpointsWide.Find(W, N);
if Result then begin
I := FBreakpointsWide.Data[N];
if I > 0 then begin
FDisassembler.Dissasemble(W, N);
if N <= I then
Result := False;
end;
end;
end;
procedure TDebugger.AddBreakpoint(Addr: Word);
var
I: Word;
W: Word;
B: TBreakpointCondition;
begin
B := TBreakpointCondition.Create;
FBreakpoints.AddOrSetData(Addr, B);
W := Addr;
I := 0;
while True do begin
FBreakpointsWide.AddOrSetData(W, I);
if I = 3 then
Break;
Dec(W);
if IsBreakpoint(W) then
Break;
Inc(I);
end;
DoOnBreakpointChange;
end;
procedure TDebugger.RemoveBreakpoint(Addr: Word);
var
J, I: Word;
N, L: Integer;
W: Word;
begin
FBreakpoints.Remove(Addr);
W := Addr;
Inc(W);
I := I.MaxValue;
if FBreakpointsWide.Find(W, L) then begin
J := FBreakpointsWide.Data[L];
if (J < 3) then begin
I := J;
end;
end;
N := 0;
W := Addr;
while N <= 3 do begin
if (N > 0) then begin
if FBreakpointsWide.Find(W, L) then begin
J := FBreakpointsWide.Data[L];
if (J = 0) then
Break;
end;
end;
if I < 3 then begin
Inc(I);
FBreakpointsWide.AddOrSetData(W, I);
end else
FBreakpointsWide.Remove(W);
Inc(N);
Dec(W);
end;
DoOnBreakpointChange;
end;
{$pop}
procedure TDebugger.RemoveAllBreakpoints();
begin
FBreakpoints.Clear;
FBreakpointsWide.Clear;
DoOnBreakpointChange;
end;
procedure TDebugger.AddOnBreakpointChange(ANotifyEvent: TNotifyEvent);
begin
if Assigned(ANotifyEvent) then begin
if FOnBreakpointChangeList = nil then begin
FOnBreakpointChangeList := TMethodList.Create;
end;
FOnBreakpointChangeList.Add(TMethod(ANotifyEvent));
end;
end;
procedure TDebugger.RemoveOnBreakPointChangeHandlerOfObject(AObject: TObject);
begin
if Assigned(FOnBreakpointChangeList) then begin
FOnBreakpointChangeList.RemoveAllMethodsOfObject(AObject);
if FOnBreakpointChangeList.Count = 0 then
FreeAndNil(FOnBreakpointChangeList);
end;
end;
end.