[Nix] Remove dependency on nixpkgs

Nix/2015/01.nix

@@ -1,7 +1,10 @@
 let
-  inherit (import ../lib) lib input solution scan;
-  inherit (lib) pipe trim stringToCharacters flip getAttr last;
-  inherit (lib.lists) findFirstIndex;
+  lib = import ../lib;
+  inherit (builtins) getAttr add;
+  inherit (lib.aoc) input solution;
+  inherit (lib.functions) pipe flip;
+  inherit (lib.lists) scan last findFirstIndex;
+  inherit (lib.strings) stringToCharacters trim;
 
   chars = {
     "(" = 1;
@@ -11,7 +14,7 @@ let
     trim
     stringToCharacters
     (map (flip getAttr chars))
-    (scan (acc: x: acc + x) 0)
+    (scan add 0)
   ];
 in
   solution {

Nix/2023/01.nix

@@ -1,22 +1,28 @@
 let
-  inherit (import ../lib) lib input solution;
-  inherit (builtins) fromJSON head filter isList split listToAttrs genList elemAt length stringLength substring attrNames foldl' add;
-  inherit (lib) splitString trim flatten hasPrefix last;
+  lib = import ../lib;
+  inherit (builtins) fromJSON head filter isList split listToAttrs length genList elemAt stringLength substring attrNames foldl' add;
+  inherit (lib.aoc) input solution;
+  inherit (lib.lists) flatten last;
+  inherit (lib.strings) splitLines trim hasPrefix;
+
+  lines = splitLines (trim input);
 
-  lines = splitString "\n" (trim input);
   digits = line: map (s: fromJSON (head s)) (filter isList (split "([0-9])" line));
   nums = let
     words = ["one" "two" "three" "four" "five" "six" "seven" "eight" "nine"];
+    wordList = genList (i: {
+      name = elemAt words i;
+      value = i + 1;
+    }) (length words);
+    digitList =
+      genList (i: {
+        name = toString i;
+        value = i;
+      })
+      10;
   in
-    listToAttrs (genList (i: {
-        name = elemAt words i;
-        value = i + 1;
-      }) (length words)
-      ++ (genList (i: {
-          name = toString i;
-          value = i;
-        })
-        10));
+    listToAttrs (wordList ++ digitList);
+
   prefixes = s: let len = stringLength s; in genList (i: substring i len s) len;
   findWords = s: flatten (map (p: filter (num: hasPrefix num p) (attrNames nums)) (prefixes s));
   findNums = s: map (num: nums.${num}) (findWords s);

Nix/lib/aoc.nix

@@ -0,0 +1,8 @@
+lib: let
+  inherit (builtins) readFile getEnv;
+  inherit (lib.strings) optionalString;
+in {
+  input = readFile (getEnv "INPUT");
+
+  solution = args: args // {__toString = s: "${toString s.p1}\n" + (optionalString (s ? p2) "${toString s.p2}\n");};
+}

Nix/lib/default.nix

@@ -1,21 +1,22 @@
-rec {
-  inherit (import <nixpkgs> {}) lib;
+let
+  pipe = builtins.foldl' (acc: f: f acc);
 
-  scan = f: init: lst: let
-    mkAcc = out: acc: {inherit out acc;};
-    op = x: y: let
-      acc' = f x.acc y;
-    in
-      mkAcc (x.out ++ [acc']) acc';
-    result = builtins.foldl' op (mkAcc [] init) lst;
+  removeDotNix = s: let
+    removed = builtins.match "(.*)\\.nix" s;
   in
-    result.out;
+    if removed != null
+    then builtins.head removed
+    else s;
 
-  input = builtins.readFile (builtins.getEnv "INPUT");
-
-  solution = {
-    p1,
-    p2 ? null,
-  }:
-    "${toString p1}\n" + (lib.optionalString (p2 != null) "${toString p2}\n");
-}
+  lib = pipe ./. [
+    builtins.readDir
+    builtins.attrNames
+    (builtins.filter (name: name != "default.nix"))
+    (map (name: {
+      name = removeDotNix name;
+      value = import ./${name} lib;
+    }))
+    builtins.listToAttrs
+  ];
+in
+  lib

Nix/lib/functions.nix

@@ -0,0 +1,6 @@
+lib: let
+  inherit (builtins) foldl';
+in {
+  flip = f: a: b: f b a;
+  pipe = foldl' (acc: f: f acc);
+}

Nix/lib/lists.nix

@@ -0,0 +1,38 @@
+lib: let
+  inherit (builtins) elemAt length head tail isList concatMap;
+in rec {
+  last = lst: elemAt lst (length lst - 1);
+
+  findFirstIndex = pred: default: lst: let
+    find = lst:
+      if lst == []
+      then null
+      else if pred (head lst)
+      then 0
+      else let
+        x = find (tail lst);
+      in
+        if x == null
+        then null
+        else x + 1;
+    result = find lst;
+  in
+    if result == null
+    then default
+    else result;
+
+  scan = f: init: lst: let
+    mkAcc = out: acc: {inherit out acc;};
+    op = x: y: let
+      acc' = f x.acc y;
+    in
+      mkAcc (x.out ++ [acc']) acc';
+    result = builtins.foldl' op (mkAcc [] init) lst;
+  in
+    result.out;
+
+  flatten = lst:
+    if isList lst
+    then concatMap flatten lst
+    else [lst];
+}

Nix/lib/strings.nix

@@ -0,0 +1,26 @@
+lib: let
+  inherit (builtins) match head substring genList stringLength replaceStrings split filter isString;
+in rec {
+  optionalString = x: s:
+    if x
+    then s
+    else "";
+
+  trim = s: let
+    chars = " \t\r\n";
+    regex = "[${chars}]*(.*[^${chars}])[${chars}]*";
+    res = match regex s;
+  in
+    optionalString (res != null) (head res);
+
+  charAt = s: i: substring i 1 s;
+  stringToCharacters = s: genList (charAt s) (stringLength s);
+
+  escape = lst: replaceStrings lst (map (c: "\\${c}") lst);
+  escapeRegex = escape (stringToCharacters "\\[{()^$?*+|.");
+
+  splitString = sep: s: filter isString (split (escapeRegex sep) s);
+  splitLines = splitString "\n";
+
+  hasPrefix = p: s: substring 0 (stringLength p) s == p;
+}