rustls-ffi: 0.10.0 -> 0.13.0

Switched to the recently introduced cargo-c build in order to get pkg-config/.so config. rustls-ffi 0.10.0 has been kept as is in order to keep the ability of building Apache with the support for it. Hopefully support for recent version of rustls-ffi will land soon, see https://bz.apache.org/bugzilla/show_bug.cgi?id=67860 Changelog: https://github.com/rustls/rustls-ffi/blob/v0.13.0/CHANGELOG.md
NixOS · May 14, 2024 · 7671437 · 7671437
1 parent 53eefbc
commit 7671437
Show file tree

Hide file tree

Showing 7 changed files with 187 additions and 417 deletions.
diff --git a/pkgs/by-name/ru/rustls-ffi/package.nix b/pkgs/by-name/ru/rustls-ffi/package.nix
@@ -0,0 +1,67 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cargo
+, rustPlatform
+, cargo-c
+, validatePkgConfig
+, rust
+, darwin
+, curl
+, apacheHttpd
+, testers
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rustls-ffi";
+  version = "0.13.0";
+
+  src = fetchFromGitHub {
+    owner = "rustls";
+    repo = "rustls-ffi";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Bc9bVZ2pDsG118l/SlElZpgh9F1JEgPF8LzBX7d4mhE=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    src = finalAttrs.src;
+    name = "${finalAttrs.pname}-${finalAttrs.version}";
+    hash = "sha256-gDQ9AFrJuV7SrzKCAHQBkKj6clXuPLO0DHhnvcBqRLs=";
+  };
+
+  propagatedBuildInputs = lib.optionals stdenv.isDarwin [ darwin.apple_sdk.frameworks.Security ];
+
+  nativeBuildInputs = [ cargo rustPlatform.cargoSetupHook cargo-c validatePkgConfig ];
+
+  buildPhase = ''
+    runHook preBuild
+    ${rust.envVars.setEnv} cargo cbuild -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    ${rust.envVars.setEnv} cargo cinstall -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postInstall
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    ${rust.envVars.setEnv} cargo ctest -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postCheck
+  '';
+
+  passthru.tests = {
+    curl = curl.override { opensslSupport = false; rustlsSupport = true; rustls-ffi = finalAttrs.finalPackage; };
+    apacheHttpd = apacheHttpd.override { modTlsSupport = true; rustls-ffi = finalAttrs.finalPackage; };
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = with lib; {
+    description = "C-to-rustls bindings";
+    homepage = "https://github.com/rustls/rustls-ffi/";
+    pkgConfigModules = [ "rustls" ];
+    license = with lib.licenses; [ mit asl20 isc ];
+    maintainers = [ maintainers.lesuisse ];
+  };
+})