Merge pull request #305391 from LeSuisse/rustls-ffi-0.13.0

rustls-ffi: 0.10.0 -> 0.13.0
NixOS · Aug 1, 2024 · 83d2194 · 83d2194
2 parents f4b4f1b + 248ffce
commit 83d2194
Show file tree

Hide file tree

Showing 5 changed files with 69 additions and 415 deletions.
diff --git a/pkgs/by-name/ru/rustls-ffi/package.nix b/pkgs/by-name/ru/rustls-ffi/package.nix
@@ -0,0 +1,68 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cargo
+, rustPlatform
+, cargo-c
+, validatePkgConfig
+, rust
+, libiconv
+, darwin
+, curl
+, apacheHttpd
+, testers
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "rustls-ffi";
+  version = "0.13.0";
+
+  src = fetchFromGitHub {
+    owner = "rustls";
+    repo = "rustls-ffi";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Bc9bVZ2pDsG118l/SlElZpgh9F1JEgPF8LzBX7d4mhE=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoTarball {
+    src = finalAttrs.src;
+    name = "${finalAttrs.pname}-${finalAttrs.version}";
+    hash = "sha256-gDQ9AFrJuV7SrzKCAHQBkKj6clXuPLO0DHhnvcBqRLs=";
+  };
+
+  propagatedBuildInputs = lib.optionals stdenv.isDarwin [ libiconv darwin.apple_sdk.frameworks.Security ];
+
+  nativeBuildInputs = [ cargo rustPlatform.cargoSetupHook cargo-c validatePkgConfig ];
+
+  buildPhase = ''
+    runHook preBuild
+    ${rust.envVars.setEnv} cargo cbuild -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    ${rust.envVars.setEnv} cargo cinstall -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postInstall
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    ${rust.envVars.setEnv} cargo ctest -j $NIX_BUILD_CORES --release --frozen --prefix=${placeholder "out"} --target ${stdenv.hostPlatform.rust.rustcTarget}
+    runHook postCheck
+  '';
+
+  passthru.tests = {
+    curl = curl.override { opensslSupport = false; rustlsSupport = true; rustls-ffi = finalAttrs.finalPackage; };
+    apacheHttpd = apacheHttpd.override { modTlsSupport = true; rustls-ffi = finalAttrs.finalPackage; };
+    pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = with lib; {
+    description = "C-to-rustls bindings";
+    homepage = "https://github.com/rustls/rustls-ffi/";
+    pkgConfigModules = [ "rustls" ];
+    license = with lib.licenses; [ mit asl20 isc ];
+    maintainers = [ maintainers.lesuisse ];
+  };
+})