package overrides using a mini module system

pkgs/applications/terminal-emulators/mlterm/default.nix

@@ -20,71 +20,13 @@
 , gtk ? gtk3
 # List of gui libraries to use. According to `./configure --help` ran on
 # release 3.9.3, options are: (xlib|win32|fb|quartz|console|wayland|sdl2|beos)
-, enableGuis ? {
-  xlib = enableX11;
-  # From some reason, upstream's ./configure script disables compilation of the
-  # external tool `mlconfig` if `enableGuis.fb == true`. This behavior is not
-  # documentd in `./configure --help`, and it is reported here:
-  # https://github.com/arakiken/mlterm/issues/73
-  fb = false;
-  quartz = stdenv.isDarwin;
-  wayland = stdenv.isLinux;
-  sdl2 = true;
-}
 , libxkbcommon
 , wayland # for the "wayland" --with-gui option
 , SDL2 # for the "sdl" --with-gui option
-# List of typing engines, the default list enables compiling all of the
-# available ones, as recorded on release 3.9.3
-, enableTypeEngines ? {
-  xcore = false; # Considered legacy
-  xft = enableX11;
-  cairo = true;
-}
 , libX11
 , libXft
 , cairo
-# List of external tools to create, this default list includes all default
-# tools, as recorded on release 3.9.3.
-, enableTools ? {
-  mlclient = true;
-  mlconfig = true;
-  mlcc = true;
-  mlterm-menu = true;
-  # Note that according to upstream's ./configure script, to disable
-  # mlimgloader you have to disable _all_ tools. See:
-  # https://github.com/arakiken/mlterm/issues/69
-  mlimgloader = true;
-  registobmp = true;
-  mlfc = true;
-}
-# Whether to enable the X window system
-, enableX11 ? stdenv.isLinux
-# Most of the input methods and other build features are enabled by default,
-# the following attribute set can be used to disable some of them. It's parsed
-# when we set `configureFlags`. If you find other configure Flags that require
-# dependencies, it'd be nice to make that contribution here.
-, enableFeatures ? {
-  uim = !stdenv.isDarwin;
-  ibus = !stdenv.isDarwin;
-  fcitx = !stdenv.isDarwin;
-  m17n = !stdenv.isDarwin;
-  ssh2 = true;
-  bidi = true;
-  # Open Type layout support, (substituting glyphs with opentype fonts)
-  otl = true;
-}
-# Configure the Exec directive in the generated .desktop file
-, desktopBinary ? (
-  if enableGuis.xlib then
-    "mlterm"
-  else if enableGuis.wayland then
-    "mlterm-wl"
-  else if enableGuis.sdl2 then
-    "mlterm-sdl2"
-  else
-    throw "mlterm: couldn't figure out what desktopBinary to use."
-  )
+, configuration ? { }
 }:
 
 let
@@ -96,6 +38,23 @@ let
   in
     lib.withFeatureAs (commaSepList != "") featureName commaSepList
   ;
+  eval = lib.evalModules {
+    modules = [
+      ./options.nix
+      configuration
+      {
+        _module.args = {
+          inherit stdenv;
+        };
+      }
+    ];
+  };
+  inherit (eval) config;
+  # For compat in order to not need to touch the entire drv
+  enableGuis = config.gui;
+  enableTypeEngines = config.typeEngines;
+  enableTools = config.tools;
+  enableFeatures = config.features;
 in stdenv.mkDerivation (finalAttrs: {
   pname = "mlterm";
   version = "3.9.3";
@@ -173,7 +132,7 @@ in stdenv.mkDerivation (finalAttrs: {
     (withFeaturesList "type-engines" enableTypeEngines)
     (withFeaturesList "tools" enableTools)
     (withFeaturesList "gui" enableGuis)
-    (lib.withFeature enableX11 "x")
+    (lib.withFeature config.x11 "x")
   ] ++ lib.optionals (gtk != null) [
     "--with-gtk=${lib.versions.major gtk.version}.0"
   ] ++ (lib.mapAttrsToList (n: v: lib.enableFeature v n) enableFeatures) ++ [
@@ -193,7 +152,7 @@ in stdenv.mkDerivation (finalAttrs: {
 
   desktopItem = makeDesktopItem {
     name = "mlterm";
-    exec = "${desktopBinary} %U";
+    exec = "${config.desktopBinary} %U";
     icon = "mlterm";
     type = "Application";
     comment = "Multi Lingual TERMinal emulator";

pkgs/applications/terminal-emulators/mlterm/options.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  config,
+  stdenv,
+  ...
+}:
+
+let
+  # For prototyping. In reality you may want to declare options manually
+  quickConvert = lib.mapAttrs (n: v: lib.mkOption { default = v; });
+in
+
+{
+  options = {
+    gui = {
+      xlib = lib.mkOption { default = config.x11; };
+      # From some reason, upstream's ./configure script disables compilation of the
+      # external tool `mlconfig` if `config.gui.fb == true`. This behavior is not
+      # documentd in `./configure --help`, and it is reported here:
+      # https://github.com/arakiken/mlterm/issues/73
+      fb = lib.mkOption { default = false; };
+      quartz = lib.mkOption { default = stdenv.isDarwin; };
+      wayland = lib.mkOption { default = stdenv.isLinux; };
+      sdl2 = lib.mkOption { default = true; };
+    };
+
+    # Whether to enable the X window system
+    x11 = lib.mkOption { default = stdenv.isLinux; };
+
+    typeEngines = {
+      # List of typing engines, the default list enables compiling all of the
+      # available ones, as recorded on release 3.9.3
+      xcore = lib.mkOption { default = false; }; # Considered legacy
+      xft = lib.mkOption { default = config.x11; };
+      cairo = lib.mkOption { default = true; };
+    };
+
+    # Most of the input methods and other build features are enabled by default,
+    # the following attribute set can be used to disable some of them. It's parsed
+    # when we set `configureFlags`. If you find other configure Flags that require
+    # dependencies, it'd be nice to make that contribution here.
+    features = quickConvert {
+      uim = !stdenv.isDarwin;
+      ibus = !stdenv.isDarwin;
+      fcitx = !stdenv.isDarwin;
+      m17n = !stdenv.isDarwin;
+      ssh2 = true;
+      bidi = true;
+      # Open Type layout support, (substituting glyphs with opentype fonts)
+      otl = true;
+    };
+
+    # List of external tools to create, this default list includes all default
+    # tools, as recorded on release 3.9.3.
+    tools = quickConvert {
+      mlclient = true;
+      mlconfig = true;
+      mlcc = true;
+      mlterm-menu = true;
+      # Note that according to upstream's ./configure script, to disable
+      # mlimgloader you have to disable _all_ tools. See:
+      # https://github.com/arakiken/mlterm/issues/69
+      mlimgloader = true;
+      registobmp = true;
+      mlfc = true;
+    };
+
+    desktopBinary = lib.mkOption {
+      default =
+        # Configure the Exec directive in the generated .desktop file
+        if config.gui.xlib then
+          "mlterm"
+        else if config.gui.wayland then
+          "mlterm-wl"
+        else if config.gui.sdl2 then
+          "mlterm-sdl2"
+        else
+          throw "mlterm: couldn't figure out what desktopBinary to use.";
+    };
+  };
+}