Windowmaker: rework

nixos/modules/services/x11/window-managers/windowmaker.nix

@@ -1,25 +1,54 @@
-{ config, lib, pkgs, ... }:
-
-with lib;
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
 
 let
+  inherit (lib)
+    mkEnableOption
+    mkPackageOption
+    mkOption
+    literalExpression
+    mkIf
+    singleton
+    ;
+  inherit (lib.types) functionTo listOf package;
   cfg = config.services.xserver.windowManager.windowmaker;
 in
 {
-  ###### interface
   options = {
-    services.xserver.windowManager.windowmaker.enable = mkEnableOption "windowmaker";
+    services.xserver.windowManager.windowmaker = {
+      enable = mkEnableOption "windowmaker";
+      package = mkPackageOption pkgs "windowmaker" { };
+      dockapps = mkOption {
+        type = functionTo (listOf package);
+        default = _: [ ];
+        defaultText = literalExpression ''
+          windowmaker: with windowmaker.dockapps; [ ];
+        '';
+        description = ''
+          Extra dockapps available to WindowMaker.
+        '';
+        example = literalExpression ''
+          windowmaker: with windowmaker.dockapps; [
+            cputnik
+            wmcube
+          ];
+        '';
+      };
+    };
   };
 
-  ###### implementation
   config = mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ] ++ cfg.dockapps cfg.package;
     services.xserver.windowManager.session = singleton {
       name = "windowmaker";
       start = ''
-        ${pkgs.windowmaker}/bin/wmaker &
+        ${lib.getExe cfg.package} &
         waitPID=$!
       '';
     };
-    environment.systemPackages = [ pkgs.windowmaker ];
   };
 }

pkgs/by-name/wi/windowmaker/dockapps/AlsaMixer-app.nix → pkgs/by-name/wi/windowmaker/dockapps/AlsaMixer-app/package.nix

@@ -1,23 +1,23 @@
-{ lib
-, stdenv
-, alsa-lib
-, dockapps-sources
-, libX11
-, libXext
-, libXpm
-, pkg-config
+{
+  lib,
+  alsa-lib,
+  libX11,
+  libXext,
+  libXpm,
+  pkg-config,
+  stdenv,
+  windowmaker,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "AlsaMixer.app";
+  inherit (windowmaker.dockapps.dockapps-sources) version;
 
-  inherit (dockapps-sources) version src;
+  src = windowmaker.dockapps.dockapps-sources;
 
   sourceRoot = "${finalAttrs.src.name}/AlsaMixer.app";
 
-  nativeBuildInputs = [
-    pkg-config
-  ];
+  nativeBuildInputs = [ pkg-config ];
 
   buildInputs = [
     alsa-lib
@@ -28,20 +28,24 @@ stdenv.mkDerivation (finalAttrs: {
 
   hardeningDisable = [ "fortify" ];
 
-  dontConfigure = true;
+  strictDeps = true;
 
   installPhase = ''
     runHook preInstall
+
     install -D -t ${placeholder "out"}/bin/ AlsaMixer.app
     pushd ${placeholder "out"}/bin
-    ln -vs AlsaMixer.app AlsaMixer
+    ln -s AlsaMixer.app AlsaMixer
+    popd
+
     runHook postInstall
   '';
 
   meta = {
-    description = "Alsa mixer application for Windowmaker";
     homepage = "https://www.dockapps.net/alsamixerapp";
+    description = "Alsa mixer application for Windowmaker";
     license = lib.licenses.gpl2Plus;
-    maintainers = [ ];
+    mainProgram = "AlsaMixer";
+    inherit (windowmaker.meta) maintainers platforms;
   };
 })

pkgs/by-name/wi/windowmaker/dockapps/cputnik.nix → pkgs/by-name/wi/windowmaker/dockapps/cputnik/package.nix

@@ -1,33 +1,38 @@
-{ lib
-, stdenv
-, dockapps-sources
-, libX11
-, libXext
-, libXpm
+{
+  lib,
+  libX11,
+  libXext,
+  libXpm,
+  stdenv,
+  windowmaker,
 }:
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "cputnik";
+  inherit (finalAttrs.src) version;
 
-  inherit (dockapps-sources) version src;
+  src = windowmaker.dockapps.dockapps-sources;
 
   sourceRoot = "${finalAttrs.src.name}/cputnik/src";
 
   buildInputs = [
     libX11
-    libXpm
     libXext
+    libXpm
   ];
 
+  hardeningDisable = [ "format" ];
+
+  strictDeps = true;
+
+  # TODO: convert to __structuredAttrs
   preBuild = ''
     makeFlagsArray+=(
       INCS="-I${libX11.dev}/include -I${libXext.dev}/include -I${libXpm.dev}/include"
       LIBS="-L${libX11}/lib -L${libXext}/lib -L${libXpm}/lib -lX11 -lXpm -lXext"
     )
   '';
 
-  hardeningDisable = [ "format" ];
-
   installPhase = ''
     runHook preInstall
 
@@ -37,10 +42,10 @@ stdenv.mkDerivation (finalAttrs: {
   '';
 
   meta = {
-    description = "Calendar clock with antialiased text";
-    homepage = "https://www.dockapps.net/wmcalclock";
+    homepage = "https://www.dockapps.net/cputnik";
+    description = "CPU and memory monitor";
     license = lib.licenses.gpl2Plus;
-    maintainers = [ ];
-    platforms = lib.platforms.linux;
+    mainProgram = "cputnik";
+    inherit (windowmaker.meta) maintainers platforms;
   };
 })

pkgs/by-name/wi/windowmaker/dockapps/dockapps-sources.nix

@@ -0,0 +1,12 @@
+{ fetchFromRepoOrCz }:
+
+# We are interested in the pristine sources; installation phases are not needed
+# here
+fetchFromRepoOrCz {
+  pname = "dockapps-sources";
+  version = "0-unstable-2023-10-11"; # Shall correspond to rev below
+  repo = "dockapps";
+  rev = "1bbb32008ecb58acaec9ea70e00b4ea1735408fc";
+  hash = "sha256-BLUDe/cIIuh9mCtafbcBSDatUXSRD83FeyYhcbem5FU=";
+}
+# TODO: update script

pkgs/by-name/wi/windowmaker/dockapps/libdockapp/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  autoreconfHook,
+  fontutil,
+  libX11,
+  libXext,
+  libXpm,
+  mkfontdir,
+  pkg-config,
+  stdenv,
+  windowmaker,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "libdockapp";
+  inherit (finalAttrs.src) version;
+
+  src = windowmaker.dockapps.dockapps-sources;
+
+  sourceRoot = "${finalAttrs.src.name}/libdockapp";
+
+  nativeBuildInputs = [
+    autoreconfHook
+    fontutil
+    mkfontdir
+    pkg-config
+  ];
+
+  buildInputs = [
+    libX11
+    libXext
+    libXpm
+  ];
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  strictDeps = true;
+
+  configureFlags = [
+    (lib.withFeature false "examples")
+    # There is a bug on --with-font
+    (lib.withFeature false "font")
+  ];
+
+  meta = {
+    description = "Library providing a framework for dockapps";
+    homepage = "https://www.dockapps.net/libdockapp";
+    license = lib.licenses.gpl2Plus;
+    inherit (windowmaker.meta) maintainers platforms;
+  };
+})