изменение лейблера и лейблов

code/datums/components/label.dm

@@ -0,0 +1,75 @@
+/**
+	The label component.
+
+	This component is used to manage labels applied by the hand labeler.
+
+	Atoms can only have one instance of this component, and therefore only one label at a time.
+	This is to avoid having names like "Backpack (label1) (label2) (label3)". This is annoying and abnoxious to read.
+
+	When a player clicks the atom with a hand labeler to apply a label, this component gets applied to it.
+	If the labeler is off, the component will be removed from it, and the label will be removed from its name.
+ */
+/datum/component/label
+	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
+	/// The name of the label the player is applying to the parent.
+	var/label_name
+
+/datum/component/label/Initialize(_label_name)
+	if(!isatom(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	label_name = _label_name
+	apply_label()
+
+/datum/component/label/RegisterWithParent()
+	RegisterSignal(parent, COMSIG_PARENT_ATTACKBY, PROC_REF(OnAttackby))
+
+/datum/component/label/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_PARENT_ATTACKBY, COMSIG_PARENT_EXAMINE))
+
+/**
+	This proc will fire after the parent is hit by a hand labeler which is trying to apply another label.
+	Since the parent already has a label, it will remove the old one from the parent's name, and apply the new one.
+*/
+/datum/component/label/InheritComponent(datum/component/label/new_comp , i_am_original, _label_name)
+	remove_label()
+	if(new_comp)
+		label_name = new_comp.label_name
+	else
+		label_name = _label_name
+	apply_label()
+
+/**
+	This proc will trigger when any object is used to attack the parent.
+
+	If the attacking object is not a hand labeler, it will return.
+	If the attacking object is a hand labeler it will restore the name of the parent to what it was before this component was added to it, and the component will be deleted.
+
+	Arguments:
+	* source: The parent.
+	* attacker: The object that is hitting the parent.
+	* user: The mob who is wielding the attacking object.
+*/
+/datum/component/label/proc/OnAttackby(datum/source, obj/item/attacker, mob/user)
+	SIGNAL_HANDLER
+
+	// If the attacking object is not a hand labeler or its mode is 1 (has a label ready to apply), return.
+	// The hand labeler should be off (mode is 0), in order to remove a label.
+	var/obj/item/device/tagger/labeler = attacker
+	if(!istype(labeler))
+		return
+
+	remove_label()
+	to_chat(user, "<span class='warning'>You remove the label from [parent].</span>")
+	qdel(src) // Remove the component from the object.
+
+/// Applies a label to the name of the parent in the format of: "parent_name (label)"
+/datum/component/label/proc/apply_label()
+	var/atom/owner = parent
+	owner.name += " ([label_name])"
+
+/// Removes the label from the parent's name
+/datum/component/label/proc/remove_label()
+	var/atom/owner = parent
+	owner.name = replacetext(owner.name, "([label_name])", "") // Remove the label text from the parent's name, wherever it's located.
+	owner.name = trim(owner.name) // Shave off any white space from the beginning or end of the parent's name.

code/modules/recycling/sortingmachinery.dm

@@ -335,9 +335,8 @@
 	else if(href_list["autocateg"])
 		autocategory = !autocategory
 	else if(href_list["label_text"])
-		var/T = sanitize(input("Введите текст бирки:", "Маркировщик", label, null)  as text)
-		if(T)
-			label = T
+		var/T = sanitize(input("Введите текст бирки:", "Маркировщик", label, null) as text)
+		label = T
 	else if(href_list["change_mode"])
 		mode++
 		if(mode > modes.len)
@@ -456,9 +455,6 @@
 		openwindow(user)
 
 /obj/item/device/tagger/proc/label(obj/target, mob/user)
-	if(!label || !length(label))
-		to_chat(user, "<span class='notice'>Нет текста на бирке.</span>")
-		return
 	if(length(target.name) + length(label) > 64)
 		to_chat(user, "<span class='notice'>Текст бирки слишком большой.</span>")
 		return
@@ -472,9 +468,22 @@
 		to_chat(user, "<span class='notice'>The label can't stick to the [target.name].  (Try using a pen)</span>")
 		return
 
-	user.visible_message("<span class='notice'>[user] labels [target] as [label].</span>", \
-						 "<span class='notice'>You label [target] as [label].</span>")
-	target.name = "[target.name] ([label])"
+	if(!label || !length(label))
+		remove_label(target, user)
+		return
+
+	var/datum/component/label/labelcomponent = target.GetComponent(/datum/component/label)
+	if(labelcomponent)
+		if(labelcomponent.label_name == label)
+			to_chat(user, "<span class='warning'>It already has the same label.</span>")
+			return
+
+	user.visible_message("<span class='notice'>[user] labels [target] as \"[label]\".</span>", "<span class='notice'>You label [target] as \"[label]\".</span>")
+
+	log_admin("[user] has labeled [target.name] with label \"[label]\". (CKEY: ([user.ckey]))")
+
+	target.AddComponent(/datum/component/label, label)
+
 
 /obj/item/device/tagger/proc/get_category(obj/target)
 	if(istype(target, /obj/item/weapon/reagent_containers/food))
@@ -495,6 +504,17 @@
 		return "Разное"
 
 
+/obj/item/device/tagger/proc/remove_label(atom/A, mob/user)
+	var/datum/component/label/label = A.GetComponent(/datum/component/label)
+	if(label)
+		user.visible_message("<span class='notice'>[user] removes label from [A].</span>", "<span class='notice'>You remove the label from [A].</span>")
+		label.remove_label()
+		log_admin("[user] has removed label from [A.name]. (CKEY: ([user.ckey]))")
+		return
+	else
+		to_chat(user, "<span class='notice'>There is no label to remove.</span>")
+		return
+
 /obj/machinery/disposal/deliveryChute
 	name = "Delivery chute"
 	desc = "A chute for big and small packages alike!"

taucetistation.dme

@@ -343,6 +343,7 @@
 #include "code\datums\components\footstep.dm"
 #include "code\datums\components\forcefield.dm"
 #include "code\datums\components\gnawing.dm"
+#include "code\datums\components\label.dm"
 #include "code\datums\components\logout_spawner.dm"
 #include "code\datums\components\magic_item.dm"
 #include "code\datums\components\mechanic_description.dm"