Fix string localization bug in some IO read procedures (chapel-lang#2…

…4444)

Fix a bug where `readTo`, `readThrough` and `readLine` were not handling
non-local string/bytes arguments properly. These methods all rely on
`readStringBytesData`, which accessed a string/bytes argument's buffer
regardless of whether it was declared locally. It now checks whether the
argument is local, and if not, creates a local temporary string/bytes to
complete the operation.

New tests are added to ensure the methods behave properly when called
with non-local arguments (note: the multilocale behavior of `readLine`
is locked in by some tests added in
chapel-lang#24323 — this PR removes the
`notest`s from those).

resolves: chapel-lang#24443

- [x] local paratest
- [x] gasnet paratest

[ reviewed by @ShreyasKhandekar ] - thanks!

modules/standard/IO.chpl

@@ -7235,37 +7235,41 @@ proc fileReader.readline(ref arg: ?t): bool throws where t==string || t==bytes {
 // Passing -1 to 'nCodepoints' tells this function to compute the number
 // of codepoints itself, and store the result in 'cachedNumCodepoints'.
 @chpldoc.nodoc
-proc readStringBytesData(ref s /*: string or bytes*/,
+proc readStringBytesData(ref s: ?t /*: string or bytes*/,
                                  _channel_internal:qio_channel_ptr_t,
                                  nBytes: int,
                                  nCodepoints: int): errorCode {
   import BytesStringCommon;
+  var sLoc: t;
+  ref sLocal = if s.locale == here then s else sLoc;
 
-  BytesStringCommon.resizeBuffer(s, nBytes);
+  BytesStringCommon.resizeBuffer(sLocal, nBytes);
 
   // TODO: if the fileReader is working with non-UTF-8 data
   // (which is a feature not yet implemented at all)
-  // this would need to call a read than can do character set conversion
+  // this would need to call a read that can do character set conversion
   // in the event that s.type == string.
 
   var len:c_ssize_t = nBytes.safeCast(c_ssize_t);
-  var err = qio_channel_read_amt(false, _channel_internal, s.buff, len);
+  var err = qio_channel_read_amt(false, _channel_internal, sLocal.buff, len);
   if !err {
-    s.buffLen = nBytes;
-    if nBytes != 0 then s.buff[nBytes] = 0; // include null-byte
-    if s.type == string {
+    sLocal.buffLen = nBytes;
+    if nBytes != 0 then sLocal.buff[nBytes] = 0; // include null-byte
+    if t == string {
       if nCodepoints == -1
-        then s.cachedNumCodepoints = BytesStringCommon.countNumCodepoints(s);
-        else s.cachedNumCodepoints = nCodepoints;
-      s.hasEscapes = false;
+        then sLocal.cachedNumCodepoints = BytesStringCommon.countNumCodepoints(sLocal);
+        else sLocal.cachedNumCodepoints = nCodepoints;
+      sLocal.hasEscapes = false;
     }
   } else {
-    s.buffLen = 0;
-    if s.type == string {
-      s.cachedNumCodepoints = 0;
-      s.hasEscapes = false;
+    sLocal.buffLen = 0;
+    if t == string {
+      sLocal.cachedNumCodepoints = 0;
+      sLocal.hasEscapes = false;
     }
   }
+
+  if s.locale != here then s <=> sLoc;
   return err;
 }
 

test/library/standard/IO/readThrough/readThroughML.chpl

@@ -0,0 +1,20 @@
+use IO;
+
+var fr = openReader("listInput.txt", locking=false);
+
+test(fr, Locales[0], Locales[1]);
+test(fr, Locales[1], Locales[0]);
+test(fr, Locales[1], Locales[1]);
+test(fr, Locales[1], Locales[2]);
+
+proc test(fr, L1: locale, L2: locale) {
+    on L1 {
+        var s = "", b = b"";
+        on L2 {
+            fr.readThrough(",", s);
+            fr.readThrough(b",", b);
+        }
+        writeln(s);
+        writeln(b);
+    }
+}

test/library/standard/IO/readThrough/readThroughML.good

@@ -0,0 +1,8 @@
+1,
+2,
+3,
+4,
+5,
+6,
+7,
+8,

test/library/standard/IO/readThrough/readThroughML.numlocales

@@ -0,0 +1 @@
+3

test/library/standard/IO/readThrough/readThroughML.skipif

@@ -0,0 +1 @@
+CHPL_COMM==none

test/library/standard/IO/readTo/listInput.txt

@@ -0,0 +1 @@
+1,2,3,4,5,6,7,8,

test/library/standard/IO/readTo/readToML.chpl

@@ -0,0 +1,22 @@
+use IO;
+
+var fr = openReader("listInput.txt", locking=false);
+
+test(fr, Locales[0], Locales[1]);
+test(fr, Locales[1], Locales[0]);
+test(fr, Locales[1], Locales[1]);
+test(fr, Locales[1], Locales[2]);
+
+proc test(fr, L1: locale, L2: locale) {
+    on L1 {
+        var s = "", b = b"";
+        on L2 {
+            fr.readTo(",", s);
+            fr.matchLiteral(",");
+            fr.readTo(b",", b);
+            fr.matchLiteral(",");
+        }
+        writeln(s);
+        writeln(b);
+    }
+}

test/library/standard/IO/readTo/readToML.good

@@ -0,0 +1,8 @@
+1
+2
+3
+4
+5
+6
+7
+8

test/library/standard/IO/readTo/readToML.numlocales

@@ -0,0 +1 @@
+3

test/library/standard/IO/readTo/readToML.skipif

@@ -0,0 +1 @@
+CHPL_COMM==none