Desk Bell

code/modules/paperwork/desk_bell.dm

@@ -0,0 +1,95 @@
+// A receptionist's bell
+
+/obj/item/desk_bell
+	name = "desk bell"
+	desc = "The cornerstone of any customer service job. You feel an unending urge to ring it. It looks like it can be wrenched or screwdrivered."
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "desk_bell"
+	w_class = SIZE_SMALL
+	embeddable = FALSE
+	/// The amount of times this bell has been rang, used to check the chance it breaks.
+	var/times_rang = 0
+	/// Is this bell broken?
+	var/broken_ringer = FALSE
+	/// Holds the time that the bell can next be rang.
+	var/ring_cooldown = 0
+	/// The length of the cooldown. Setting it to 0 will skip all cooldowns alltogether.
+	var/ring_cooldown_length = 1 SECONDS // This is here to protect against tinnitus.
+	/// The sound the bell makes.
+	var/ring_sound = 'sound/misc/desk_bell.ogg'
+
+/obj/item/desk_bell/attack_hand(mob/living/user)
+	if(!ishuman(user))
+		return FALSE
+	if(!anchored)
+		return ..()
+	if(ring_cooldown > world.time)
+		return FALSE
+	if(!ring_bell(user))
+		to_chat(user, SPAN_NOTICE("[src] is silent. Some idiot broke it."))
+		return FALSE
+	ring_cooldown = world.time + ring_cooldown_length
+	return TRUE
+
+/obj/item/desk_bell/MouseDrop(atom/over_object)
+	var/mob/mob = usr
+	if(!Adjacent(mob) || anchored)
+		return
+	if(!ishuman(mob))
+		return
+
+	if(over_object == mob)
+		mob.put_in_hands(src)
+
+/obj/item/desk_bell/attackby(obj/item/item, mob/user)
+	//Repair the desk bell if its broken and we're using a screwdriver.
+	if(HAS_TRAIT(item, TRAIT_TOOL_SCREWDRIVER))
+		if(broken_ringer)
+			visible_message(SPAN_NOTICE("[user] begins repairing [src]..."), SPAN_NOTICE("You begin repairing [src]..."))
+			if(do_after(user, 5 SECONDS, INTERRUPT_ALL, BUSY_ICON_GENERIC))
+				user.visible_message(SPAN_NOTICE("[user] repairs [src]"), SPAN_NOTICE("You repair [src]."))
+				playsound(user, 'sound/items/Screwdriver.ogg', 50)
+				broken_ringer = FALSE
+				times_rang = 0
+				return TRUE
+			return FALSE
+
+	//Return at this point if we're not on a turf so we don't anchor or unanchor inside our bag/hands or inventory.
+	if(!isturf(loc))
+		return
+
+	//Wrenching down and unwrenching.
+	if(HAS_TRAIT(item, TRAIT_TOOL_WRENCH))
+		if(user.a_intent == INTENT_HARM)
+			visible_message(SPAN_NOTICE("[user] begins taking apart [src]..."), SPAN_NOTICE("You begin taking apart [src]..."))
+			if(do_after(user, 5 SECONDS, INTERRUPT_ALL, BUSY_ICON_GENERIC))
+				visible_message(SPAN_NOTICE("[user] takes apart [src]."), SPAN_NOTICE("You take apart [src]."))
+				playsound(user, 'sound/items/deconstruct.ogg', 50)
+				new /obj/item/stack/sheet/metal(get_turf(src))
+				qdel(src)
+				return TRUE
+		else
+			user.visible_message("[user] begins [anchored ? "un" : ""]securing [src]...", "You begin [anchored ? "un" : ""]securing [src]...")
+			if(!do_after(user, 2 SECONDS, INTERRUPT_ALL, BUSY_ICON_GENERIC))
+				return FALSE
+			user.visible_message("[user] [anchored ? "un" : ""]secures [src].", "You [anchored ? "un" : ""]secure [src]")
+			anchored = !anchored
+			return TRUE
+
+
+/// Check if the clapper breaks, and if it does, break it chance to break is 1% for every 100 rings of the bell.
+/obj/item/desk_bell/proc/check_clapper(mob/living/user)
+	if(prob(times_rang / 100))
+		to_chat(user, SPAN_NOTICE("You hear [src]'s clapper fall off of its hinge. Nice job, you broke it."))
+		broken_ringer = TRUE
+
+/// Ring the bell.
+/obj/item/desk_bell/proc/ring_bell(mob/living/user)
+	if(broken_ringer)
+		return FALSE
+	check_clapper(user)
+	// The lack of varying is intentional. The only variance occurs on the strike the bell breaks.
+	playsound(src, ring_sound, 70, vary = broken_ringer)
+	flick("desk_bell_activate", src)
+	times_rang++
+	return TRUE

colonialmarines.dme

@@ -2161,6 +2161,7 @@
 #include "code\modules\organs\wound.dm"
 #include "code\modules\paperwork\carbonpaper.dm"
 #include "code\modules\paperwork\clipboard.dm"
+#include "code\modules\paperwork\desk_bell.dm"
 #include "code\modules\paperwork\filingcabinet.dm"
 #include "code\modules\paperwork\folders.dm"
 #include "code\modules\paperwork\notepad.dm"

maps/map_files/USS_Almayer/USS_Almayer.dmm

@@ -20030,6 +20030,11 @@
 	},
 /obj/structure/machinery/door/firedoor/border_only/almayer,
 /obj/structure/surface/table/reinforced/almayer_blend/north,
+/obj/item/desk_bell{
+	pixel_x = -6;
+	pixel_y = -8;
+	anchored = 1
+	},
 /turf/open/floor/almayer{
 	icon_state = "test_floor4"
 	},
@@ -20415,6 +20420,11 @@
 	},
 /obj/structure/machinery/door/firedoor/border_only/almayer,
 /obj/structure/surface/table/reinforced/almayer_blend,
+/obj/item/desk_bell{
+	pixel_x = -6;
+	pixel_y = 10;
+	anchored = 1
+	},
 /turf/open/floor/almayer{
 	icon_state = "test_floor4"
 	},
@@ -42054,8 +42064,11 @@
 /obj/structure/machinery/door/window/eastleft{
 	req_access_txt = "8"
 	},
-/obj/item/book/manual/medical_diagnostics_manual,
-/obj/item/device/megaphone,
+/obj/item/desk_bell{
+	pixel_x = -6;
+	pixel_y = 10;
+	anchored = 1
+	},
 /turf/open/floor/almayer{
 	icon_state = "sterile_green"
 	},
@@ -69247,6 +69260,8 @@
 	dir = 8;
 	pixel_x = 17
 	},
+/obj/item/device/megaphone,
+/obj/item/book/manual/medical_diagnostics_manual,
 /turf/open/floor/almayer{
 	icon_state = "sterile_green_side"
 	},