First Drop Protections: Gas and Static Turrets

code/__DEFINES/defenses.dm

@@ -22,6 +22,12 @@
 #define DEFENSE_BELL_TOWER 4
 #define DEFENSE_TESLA_COIL 5
 
+// Defines for /obj/structure/machinery/defenses/sentry/premade/deployable/colony/landing_zone
+#define TURRET_BATTERY_STATE_OK 0
+#define TURRET_BATTERY_STATE_LOW 1
+#define TURRET_BATTERY_STATE_CRITICAL 2
+#define TURRET_BATTERY_STATE_DEAD 3
+
 // What range the generator has to be in or defenses has to be in.
 #define GEN_SEARCH_RANGE 5
 #define GEN_PLASTEEL_COST 10

code/__DEFINES/misc.dm

@@ -25,6 +25,7 @@
 #define SMOKE_RANK_MED 3
 #define SMOKE_RANK_HIGH 4
 #define SMOKE_RANK_BOILER 5
+#define SMOKE_RANK_MAX 6
 
 // What kind of function to use for Explosions falling off.
 

code/game/area/shiva.dm

@@ -262,6 +262,7 @@
 /area/shiva/interior/lz2_habs
 	name = "Shiva's Snowball - Argentinian Research Headquarters"
 	icon_state = "bar1"
+	is_landing_zone = TRUE
 
 /area/shiva/interior/aux_power
 	name = "Shiva's Snowball - Auxiliary Generator Station"

code/game/gamemodes/colonialmarines/colonialmarines.dm

@@ -16,6 +16,7 @@
 	var/next_research_allocation = 0
 	var/next_stat_check = 0
 	var/list/running_round_stats = list()
+	var/list/lz_smoke = list()
 
 ////////////////////////////////////////////////////////////////////////////////////////
 ////////////////////////////////////////////////////////////////////////////////////////
@@ -120,9 +121,116 @@
 
 	addtimer(CALLBACK(src, PROC_REF(ares_online)), 5 SECONDS)
 	addtimer(CALLBACK(src, PROC_REF(map_announcement)), 20 SECONDS)
+	addtimer(CALLBACK(src, PROC_REF(start_lz_hazards)), 2 MINUTES)
 
 	return ..()
 
+/datum/game_mode/colonialmarines/ds_first_landed(obj/docking_port/stationary/marine_dropship)
+	. = ..()
+	clear_lz_hazards() // This shouldn't normally do anything, but is here just in case
+
+	// Assumption: Shuttle origin is its center
+	// Assumption: dwidth is atleast 2 and dheight is atleast 4 otherwise there will be overlap
+	var/list/options = list()
+	var/list/structures_to_break = list(/obj/structure/barricade, /obj/structure/surface/table, /obj/structure/bed)
+	var/bottom = marine_dropship.y - marine_dropship.dheight - 2
+	var/top = marine_dropship.y + marine_dropship.dheight + 2
+	var/left = marine_dropship.x - marine_dropship.dwidth - 2
+	var/right = marine_dropship.x + marine_dropship.dwidth + 2
+	var/z = marine_dropship.z
+
+	// Bottom left
+	options += get_valid_sentry_turfs(left, bottom, z, width=5, height=2, structures_to_ignore=structures_to_break)
+	options += get_valid_sentry_turfs(left, bottom + 2, z, width=2, height=6, structures_to_ignore=structures_to_break)
+	spawn_lz_sentry(pick(options), structures_to_break)
+
+	// Bottom right
+	options.Cut()
+	options += get_valid_sentry_turfs(right-4, bottom, z, width=5, height=2, structures_to_ignore=structures_to_break)
+	options += get_valid_sentry_turfs(right-1, bottom + 2, z, width=2, height=6, structures_to_ignore=structures_to_break)
+	spawn_lz_sentry(pick(options), structures_to_break)
+
+	// Top left
+	options.Cut()
+	options += get_valid_sentry_turfs(left, top-1, z, width=5, height=2, structures_to_ignore=structures_to_break)
+	options += get_valid_sentry_turfs(left, top-7, z, width=2, height=6, structures_to_ignore=structures_to_break)
+	spawn_lz_sentry(pick(options), structures_to_break)
+
+	// Top right
+	options.Cut()
+	options += get_valid_sentry_turfs(right-4, top-1, z, width=5, height=2, structures_to_ignore=structures_to_break)
+	options += get_valid_sentry_turfs(right-1, top-7, z, width=2, height=6, structures_to_ignore=structures_to_break)
+	spawn_lz_sentry(pick(options), structures_to_break)
+
+///Returns a list of non-dense turfs using the given block arguments ignoring the provided structure types
+/datum/game_mode/colonialmarines/proc/get_valid_sentry_turfs(left, bottom, z, width, height, list/structures_to_ignore)
+	var/valid_turfs = list()
+	for(var/turf/turf in block(left, bottom, z, left+width-1, bottom+height-1))
+		if(turf.density)
+			continue
+		var/structure_blocking = FALSE
+		for(var/obj/structure/existing_structure in turf)
+			if(!existing_structure.density)
+				continue
+			if(!is_type_in_list(existing_structure, structures_to_ignore))
+				structure_blocking = TRUE
+				break
+		if(structure_blocking)
+			continue
+		valid_turfs += turf
+	return valid_turfs
+
+///Spawns a droppod with a temporary defense sentry at the given turf
+/datum/game_mode/colonialmarines/proc/spawn_lz_sentry(turf/target, list/structures_to_break)
+	var/obj/structure/droppod/equipment/sentry_holder/droppod = new(target, /obj/structure/machinery/sentry_holder/landing_zone)
+	droppod.special_structures_to_damage = structures_to_break
+	droppod.special_structure_damage = 500
+	droppod.drop_time = 5 SECONDS
+	droppod.launch(target)
+
+///Creates an OB warning at each LZ to warn of the miasma and then spawns the miasma
+/datum/game_mode/colonialmarines/proc/start_lz_hazards()
+	INVOKE_ASYNC(src, PROC_REF(warn_lz_hazard), locate(/obj/structure/machinery/computer/shuttle/dropship/flight/lz1))
+	INVOKE_ASYNC(src, PROC_REF(warn_lz_hazard), locate(/obj/structure/machinery/computer/shuttle/dropship/flight/lz2))
+	addtimer(CALLBACK(src, PROC_REF(spawn_lz_hazards)), OB_TRAVEL_TIMING + 1 SECONDS)
+
+///Creates an OB warning at each LZ to warn of the incoming miasma
+/datum/game_mode/colonialmarines/proc/warn_lz_hazard(lz)
+	if(!lz)
+		return
+	var/turf/target = get_turf(lz)
+	if(!target)
+		return
+	var/obj/structure/ob_ammo/warhead/explosive/warhead = new
+	warhead.name = "\improper CN20-X miasma warhead"
+	warhead.clear_power = 0
+	warhead.clear_falloff = 400
+	warhead.standard_power = 0
+	warhead.standard_falloff = 30
+	warhead.clear_delay = 3
+	warhead.double_explosion_delay = 6
+	warhead.warhead_impact(target) // This is a blocking call
+	playsound(target, 'sound/effects/smoke.ogg', vol=50, vary=1, sound_range=75)
+
+///Spawns miasma smoke in landing zones
+/datum/game_mode/colonialmarines/proc/spawn_lz_hazards()
+	var/datum/cause_data/new_cause_data = create_cause_data("CN20-X miasma")
+	for(var/area/area in GLOB.all_areas)
+		if(!area.is_landing_zone)
+			continue
+		if(!is_ground_level(area.z))
+			continue
+		for(var/turf/turf in area)
+			if(turf.density)
+				continue
+			lz_smoke += new /obj/effect/particle_effect/smoke/miasma(turf, null, new_cause_data)
+
+///Clears miasma smoke in landing zones
+/datum/game_mode/colonialmarines/proc/clear_lz_hazards()
+	for(var/obj/effect/particle_effect/smoke/miasma/smoke as anything in lz_smoke)
+		smoke.time_to_live = rand(1, 5)
+	lz_smoke.Cut()
+
 #define MONKEYS_TO_TOTAL_RATIO 1/32
 
 /datum/game_mode/colonialmarines/proc/spawn_smallhosts()
@@ -289,6 +397,7 @@
 /datum/game_mode/colonialmarines/ds_first_drop(obj/docking_port/mobile/marine_dropship)
 	addtimer(CALLBACK(GLOBAL_PROC, GLOBAL_PROC_REF(show_blurb_uscm)), DROPSHIP_DROP_MSG_DELAY)
 	add_current_round_status_to_end_results("First Drop")
+	clear_lz_hazards()
 
 ///////////////////////////
 //Checks to see who won///

code/game/machinery/sentry_holder.dm

@@ -143,3 +143,41 @@
 /obj/structure/machinery/sentry_holder/almayer/mini/aicore/attack_hand(mob/user)
 	to_chat(user, SPAN_WARNING("[src] can only be deployed remotely."))
 	return
+
+/obj/structure/machinery/sentry_holder/landing_zone
+	icon_state = "floor_sentry_installed" // TODO: More appropriate sprites
+	turret_path = /obj/structure/machinery/defenses/sentry/premade/deployable/colony/landing_zone
+	base_icon_state = "floor_sentry" // TODO: More appropriate sprites
+	layer = HATCH_LAYER // Needs to not hide barricades
+
+/obj/structure/machinery/sentry_holder/landing_zone/attack_hand(mob/user)
+	var/obj/structure/machinery/defenses/sentry/premade/deployable/colony/landing_zone/turret = deployed_turret
+	if(!istype(turret))
+		to_chat(user, SPAN_WARNING("[src] is unresponsive."))
+		return
+
+	if(deployment_cooldown > world.time)
+		to_chat(user, SPAN_WARNING("[src] is busy."))
+		return
+
+	if(deployed_turret.loc == src) //not deployed
+		if(turret.battery_state == TURRET_BATTERY_STATE_DEAD)
+			to_chat(user, SPAN_WARNING("[src] is non-functional."))
+			return
+
+		if(require_red_alert && (seclevel2num(get_security_level()) < SEC_LEVEL_RED))
+			to_chat(user, SPAN_WARNING("[src] can only be activated in emergencies."))
+			return
+
+		to_chat(user, SPAN_NOTICE("You deploy [src]."))
+		deploy_sentry()
+		msg_admin_niche("[key_name(user)] deployed [turret] at [get_location_in_text(src)] [ADMIN_JMP(loc)]")
+		return
+
+	to_chat(user, SPAN_NOTICE("You retract [src]."))
+	msg_admin_niche("[key_name(user)] retracted [turret] at [get_location_in_text(src)] [ADMIN_JMP(loc)]")
+	undeploy_sentry()
+	return
+
+/obj/structure/machinery/sentry_holder/landing_zone/update_use_power(new_use_power)
+	return