stylix: init droid

docs/src/installation.md

@@ -78,6 +78,39 @@ While this won't have an effect on the looks of MacOS, since we don't have the
 controls to theme it like we do NixOS, it will automatically set up the [Home
 Manager][nix-hm] modules for you.
 
+## Nix-on-Droid
+
+You can install Stylix into your
+[Nix-on-Droid](https://github.com/nix-community/nix-on-droid) configuration in
+a similar fashion to NixOS via [Flakes][nix-flakes].
+
+```nix
+{
+  inputs = {
+    nix-on-droid = {
+      url = "github:nix-community/nix-on-droid/release-24.05";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
+    stylix.url = "github:danth/stylix";
+  };
+
+  outputs = { nix-on-droid, nixpkgs, stylix, ... }: {
+    nixOnDroidConfigurations.default = nix-on-droid.lib.nixOnDroidConfiguration {
+      pkgs = nixpkgs.legacyPackages."aarch64-linux";
+      modules = [ stylix.nixOnDroidModules.stylix ./nix-on-droid.nix ];
+    };
+  };
+}
+```
+<small>Minimal `flake.nix` for a Nix-on-Droid configuration.</small>
+
+This will apply your configured color scheme and monospace font to the
+nix-on-droid terminal. If [Home Manager integration for
+Nix-on-Droid](https://github.com/nix-community/nix-on-droid#home-manager-integration)
+is used, Stylix will automatically set up the [Home Manager][nix-hm] modules for
+you.
+
 ## Home Manager
 
 If you would prefer to use the standalone version of Home Manager, you can

docs/src/modules.md

@@ -25,6 +25,7 @@ The following platforms are supported:
 - NixOS (`nixos`)
 - Home Manager (`hm`)
 - Nix-Darwin (`darwin`)
+- Nix-on-Droid (`droid`)
 
 Correctly named modules will be imported automatically.
 

flake.nix

@@ -255,5 +255,17 @@
             }
           ];
         };
+
+      nixOnDroidModules.stylix =
+        { pkgs, ... }@args:
+        {
+          imports = [
+            (import ./stylix/droid inputs {
+              inherit (self.packages.${pkgs.system}) palette-generator;
+              base16 = base16.lib args;
+              homeManagerModule = self.homeManagerModules.stylix;
+            })
+          ];
+        };
     };
 }

stylix/droid/default.nix

@@ -0,0 +1,28 @@
+inputs:
+{
+  palette-generator,
+  base16,
+  homeManagerModule,
+}:
+{ lib, ... }:
+
+let
+  autoload = import ../autoload.nix { inherit lib inputs; } "droid";
+in
+{
+  imports = [
+    ../pixel.nix
+    ../target.nix
+    ../opacity.nix
+    ./fonts.nix
+    ./terminal.nix
+    (import ./palette.nix { inherit palette-generator base16 lib; })
+    (import ../templates.nix inputs)
+    (import ../home-manager-integration.nix homeManagerModule)
+  ] ++ autoload;
+
+  # See https://github.com/nix-community/nix-on-droid/issues/436
+  options.lib = lib.mkOption {
+    type = with lib.types; attrsOf attrs;
+  };
+}

stylix/droid/fonts.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  mkFont =
+    font:
+    pkgs.runCommand "stylix-font-${font.package.name}"
+      {
+        FONTCONFIG_FILE = pkgs.makeFontsConf { fontDirectories = [ font.package ]; };
+      }
+      ''
+        font="$(
+          ${lib.getExe' pkgs.fontconfig "fc-match"} \
+          ${lib.escapeShellArg font.name} \
+          --format %{file}
+        )"
+
+        cp "$font" "$out"
+      '';
+  terminalFont = mkFont config.stylix.fonts.monospace;
+in
+{
+  imports = [ ../fonts.nix ];
+
+  config.terminal.font = lib.mkIf config.stylix.enable terminalFont;
+}

stylix/droid/palette.nix

@@ -0,0 +1,10 @@
+args:
+{ config, lib, ... }:
+
+{
+  imports = [ (import ../palette.nix args) ];
+
+  config = lib.mkIf config.stylix.enable {
+    environment.etc = config.stylix.generated.fileTree;
+  };
+}

stylix/droid/terminal.nix

@@ -0,0 +1,31 @@
+{ config, lib, ... }:
+
+{
+  config = lib.mkIf config.stylix.enable {
+    terminal.colors = with config.lib.stylix.colors.withHashtag; rec {
+      background = base00;
+      foreground = base05;
+      cursor = base05;
+
+      # normal
+      color0 = base00;
+      color1 = base08;
+      color2 = base0B;
+      color3 = base0A;
+      color4 = base0D;
+      color5 = base0E;
+      color6 = base0C;
+      color7 = base05;
+
+      # bright
+      color8 = base02;
+      color9 = color1;
+      color10 = color2;
+      color11 = color3;
+      color12 = color4;
+      color13 = color5;
+      color14 = color6;
+      color15 = base07;
+    };
+  };
+}