Add Nix Flake

flake.nix

@@ -0,0 +1,85 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    textual-autocomplete = {
+      # TODO: update to darrenburns once flake PRr gets merged
+      url = "github:justdeeevin/textual-autocomplete/flake";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs = inputs @ {flake-parts, ...}:
+    flake-parts.lib.mkFlake {inherit inputs;} rec {
+      imports = [flake-parts.flakeModules.modules];
+
+      systems = ["x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin"];
+
+      flake.overlays.default = final: prev: (
+        inputs.textual-autocomplete.overlays.default final prev
+        // {
+          posting = prev.callPackage ./package.nix {};
+        }
+      );
+
+      flake.modules.homeManager.default = {
+        config,
+        lib,
+        pkgs,
+        ...
+      }: let
+        inherit (lib) mkOption mkIf mkEnableOption mkPackageOption types;
+        cfg = config.programs.posting;
+      in {
+        options.programs.posting = {
+          enable = mkEnableOption "Posting API client";
+          package = mkPackageOption pkgs "posting" {};
+          settings = mkOption {
+            type = (pkgs.formats.yaml {}).type;
+            default = {};
+            example = {
+              theme = "galaxy";
+              layout = "horizontal";
+              response.prettify_json = false;
+              heading = {
+                visible = true;
+                show_host = false;
+              };
+            };
+            description = "Posting configuration settings. See <https://github.com/darrenburns/posting/blob/main/docs/guide/configuration.md>";
+          };
+          themes = mkOption {
+            type = types.listOf ((pkgs.formats.yaml {}).type);
+            default = {};
+            description = "List of user-defined themes. See <https://github.com/darrenburns/posting/blob/main/docs/guide/themes.md>";
+          };
+        };
+
+        config = mkIf cfg.enable {
+          home.packages = [cfg.package];
+          home.file =
+            {".config/posting/config.yaml".text = builtins.toJSON cfg.settings;}
+            // builtins.listToAttrs (map (theme: {
+                name = ".local/share/posting/themes/${theme.name}.yaml";
+                value = {text = builtins.toJSON theme;};
+              })
+              cfg.themes);
+          nixpkgs.overlays = [flake.overlays.default];
+        };
+      };
+
+      perSystem = {
+        pkgs,
+        system,
+        ...
+      }: {
+        _module.args.pkgs = import inputs.nixpkgs {
+          inherit system;
+          overlays = [
+            inputs.textual-autocomplete.overlays.default
+          ];
+        };
+        packages.default = pkgs.callPackage ./package.nix {};
+      };
+    };
+}

package.nix

@@ -0,0 +1,82 @@
+{
+  pkgs,
+  lib,
+  ...
+}: let
+  package = builtins.fromTOML (builtins.readFile ./pyproject.toml);
+in
+  pkgs.python312Packages.buildPythonPackage {
+    pname = package.project.name;
+    version = package.project.version;
+    pyproject = true;
+    src = ./.;
+    build-system = [pkgs.python312Packages.hatchling];
+    dependencies = with pkgs.python312Packages; [
+      click
+      xdg-base-dirs
+      click-default-group
+      httpx
+      pyperclip
+      pydantic
+      pyyaml
+      pydantic-settings
+      python-dotenv
+      (pkgs.textual-autocomplete.overridePythonAttrs
+        (old: rec {
+          version = "3.0.0a12";
+          src = pkgs.fetchPypi {
+            pname = "textual_autocomplete";
+            inherit version;
+            hash = "sha256-HSyeTSTH9XWryMYSy2q//0cG9qqrm5OVBrldroRUkwk=";
+          };
+
+          postPatch = ''
+            sed -i "/^requires-python =.*/a version = '${version}'" pyproject.toml
+          '';
+        }))
+      (textual.overridePythonAttrs (old: rec {
+        version = "0.85.0";
+        src = pkgs.fetchFromGitHub {
+          owner = "Textualize";
+          repo = "textual";
+          rev = "refs/tags/v${version}";
+          hash = "sha256-ROq/Pjq6XRgi9iqMlCzpLmgzJzLl21MI7148cOxHS3o=";
+        };
+
+        postPatch = ''
+          sed -i "/^requires-python =.*/a version = '${version}'" pyproject.toml
+        '';
+      }))
+      (watchfiles.overridePythonAttrs (old: rec {
+        version = "0.24.0";
+
+        src = pkgs.fetchFromGitHub {
+          owner = "samuelcolvin";
+          repo = "watchfiles";
+          rev = "refs/tags/v${version}";
+          hash = "sha256-uc4CfczpNkS4NMevtRxhUOj9zTt59cxoC0BXnuHFzys=";
+        };
+
+        cargoDeps = pkgs.rustPlatform.importCargoLock {
+          lockFile = pkgs.fetchurl {
+            url = "https://raw.githubusercontent.com/samuelcolvin/watchfiles/refs/tags/v${version}/Cargo.lock";
+            hash = "sha256-rA6K0bjivOGhoGUYUk5OubFaMh3duEMaDgGtCqbY26g=";
+          };
+          outputHashes = {
+            "notify-6.1.1" = "sha256-lT3R5ZQpjx52NVMEKTTQI90EWT16YnbqphqvZmNpw/I=";
+          };
+        };
+
+        postPatch = ''
+          sed -i "/^requires-python =.*/a version = '${version}'" pyproject.toml
+          substituteInPlace Cargo.toml \
+            --replace-fail 'version = "0.0.0"' 'version = "${version}"'
+        '';
+      }))
+    ];
+    meta = {
+      description = package.project.description;
+      homepage = package.project.urls.homepage;
+      license = lib.licenses.asl20;
+    };
+  }