Implement DnD reordering

src/Launcher.vala

@@ -33,9 +33,36 @@ public class Dock.Launcher : Gtk.Button {
         };
         image.get_style_context ().add_provider (css_provider, Gtk.STYLE_PROVIDER_PRIORITY_APPLICATION);
 
-        child = image;
+        // Needed to work around DnD bug where it
+        // would stop working once the button got clicked
+        var box = new Gtk.Box (VERTICAL, 0);
+        box.append (image);
+
+        child = box;
         tooltip_text = app_info.get_display_name ();
 
+        var drag_source = new Gtk.DragSource () {
+            actions = MOVE
+        };
+        box.add_controller (drag_source);
+
+        drag_source.prepare.connect (() => {
+            var val = Value (typeof (Launcher));
+            val.set_object (this);
+            var content_provider = new Gdk.ContentProvider.for_value (val);
+            return content_provider;
+        });
+
+        drag_source.drag_cancel.connect ((drag, reason) => {
+            if (reason == NO_TARGET) {
+                ((MainWindow)get_root ()).remove_launcher (this);
+            }
+        });
+
+        var drop_target = new Gtk.DropTarget (typeof (Launcher), MOVE);
+        box.add_controller (drop_target);
+        drop_target.drop.connect (on_drop);
+
         clicked.connect (() => {
             try {
                 add_css_class ("bounce");
@@ -82,4 +109,28 @@ public class Dock.Launcher : Gtk.Button {
             return null;
         }
     }
+
+    private bool on_drop (Value val, double x, double y) {
+        Launcher source;
+        Launcher? target = this;
+
+        var obj = val.get_object ();
+        if (obj == null || !(obj is Launcher)) {
+            return false;
+        } else {
+            source = (Launcher)obj;
+        }
+
+        if (source == this) {
+            return false;
+        }
+
+        if (x < get_allocated_width () / 2) {
+            target = (Launcher)get_prev_sibling ();
+        }
+
+        ((MainWindow)get_root ()).move_launcher_after (source, target);
+
+        return true;
+    }
 }

src/MainWindow.vala

@@ -6,6 +6,7 @@
 public class Dock.MainWindow : Gtk.ApplicationWindow {
     private static Gtk.CssProvider css_provider;
 
+    private Settings settings;
     private Gtk.Box box;
     private Dock.DesktopIntegration desktop_integration;
     private GLib.HashTable<unowned string, Dock.Launcher> app_to_launcher;
@@ -34,7 +35,7 @@ public class Dock.MainWindow : Gtk.ApplicationWindow {
         resizable = false;
         set_titlebar (empty_title);
 
-        var settings = new Settings ("io.elementary.dock");
+        settings = new Settings ("io.elementary.dock");
 
         GLib.Bus.get_proxy.begin<Dock.DesktopIntegration> (
             GLib.BusType.SESSION,
@@ -120,4 +121,58 @@ public class Dock.MainWindow : Gtk.ApplicationWindow {
             return false;
         });
     }
+
+    public void remove_launcher (Launcher launcher) {
+        box.remove (launcher);
+
+        if (launcher.pinned) {
+            var old_pinned_ids = settings.get_strv ("launchers");
+            string[] new_pinned_ids = {};
+
+            var to_remove_id = launcher.app_info.get_id ();
+            foreach (string app_id in old_pinned_ids) {
+                if (app_id != to_remove_id) {
+                    new_pinned_ids += app_id;
+                }
+            }
+
+            settings.set_strv ("launchers", new_pinned_ids);
+        }
+    }
+
+    public void move_launcher_after (Launcher source, Launcher? target) {
+        box.reorder_child_after (source, target);
+
+        if (!source.pinned) {
+            return;
+        }
+
+        var old_pinned_ids = settings.get_strv ("launchers");
+        string[] new_pinned_ids = {};
+
+        string source_id = source.app_info.get_id ();
+        string? target_id = null;
+
+        if (target == null) {
+            new_pinned_ids += source_id;
+        } else {
+            target_id = target.app_info.get_id ();
+        }
+
+        foreach (string app_id in old_pinned_ids) {
+            if (app_id != source_id) {
+                new_pinned_ids += app_id;
+
+                if (target_id != null && app_id == target_id) {
+                    new_pinned_ids += source_id;
+                }
+            }
+        }
+
+        if (target != null && !target.pinned) {
+            new_pinned_ids += source_id;
+        }
+
+        settings.set_strv ("launchers", new_pinned_ids);
+    }
 }