Re-write plugin scripts as ApplicationCommand (#920)

* Rewrite s2-quickstart as the ApplicationCommand

* Rewrite s2-quickstart as the ApplicationCommand

* Update S2QuickstartCommand.groovy

* Rewrite s2-create-persistent-token as ApplicationCommand

* Re-write s2-create-role-hierarchy-entry as ApplicationCommand

* Update Gradle Enterprise publishAlwaysIf condition

plugin/grails-app/commands/grails.plugin.springsecurity/CommandLineHelper.groovy

@@ -0,0 +1,34 @@
+package grails.plugin.springsecurity
+
+import grails.dev.commands.ExecutionContext
+import io.micronaut.core.naming.NameUtils
+import org.grails.build.parsing.CommandLine
+
+trait CommandLineHelper {
+
+    static final boolean SUCCESS = true
+    static final boolean FAILURE = false
+
+    abstract ExecutionContext getExecutionContext()
+
+    boolean isFlagPresent(String name) {
+        final CommandLine commandLine = executionContext.commandLine
+        if (commandLine.hasOption(name)) {
+            return commandLine.optionValue(name) ? true : false
+        } else {
+            def value = commandLine?.undeclaredOptions?.get(name)
+            return value ? true : false
+        }
+    }
+
+    String flagValue(String name) {
+        final CommandLine commandLine = executionContext.commandLine
+        if (commandLine.hasOption(name)) {
+            return commandLine.optionValue(name)
+        } else {
+            def value = commandLine?.undeclaredOptions?.get(name)
+            return value
+        }
+    }
+
+}

plugin/grails-app/commands/grails.plugin.springsecurity/S2CreatePersistentTokenCommand.groovy

@@ -0,0 +1,69 @@
+/*
+ * Copyright 2023 Puneet Behl.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+package grails.plugin.springsecurity
+
+import grails.build.logging.ConsoleLogger
+import grails.build.logging.GrailsConsole
+import grails.codegen.model.Model
+import grails.dev.commands.GrailsApplicationCommand
+import groovy.transform.CompileStatic
+
+/**
+ * Creates a persistent token domain class for the Spring Security Core plugin.
+ * Usage: <code>./gradlew runCommand "-Pargs=s2-create-persistent-token [DOMAIN CLASS NAME]"</code>
+*
+ * For example: <code>./gradlew runCommand "-Pargs=s2-create-persistent-token com.yourapp.PersistentLogin"</code>
+ *
+ * @author Puneet Behl
+ * @since 6.0.0
+ */
+@CompileStatic
+class S2CreatePersistentTokenCommand implements GrailsApplicationCommand, CommandLineHelper, SkipBootstrap {
+
+    @Delegate
+    ConsoleLogger consoleLogger = GrailsConsole.getInstance()
+
+    private final static USAGE_MESSAGE = '''
+./gradlew runCommand "-Pargs=s2-create-persistent-token [DOMAIN CLASS NAME]"
+
+For example: ./gradlew runCommand "-Pargs=s2-create-persistent-token com.yourapp.PersistentLogin"
+'''
+
+    @Override
+    boolean handle() {
+
+        if (args.size() == 0) {
+            consoleLogger.error("Usage: " + USAGE_MESSAGE)
+            return FAILURE
+        }
+
+        final String domainClass = args[0]
+        final Model domainModel = model(domainClass)
+        consoleLogger.addStatus ("\nCreating persistent token class $domainClass")
+        render(template: template("PersistentLogin.groovy.template"),
+                destination: file("grails-app/domain/$domainModel.packagePath/${domainModel.simpleName}.groovy"),
+                model: domainModel,
+                overrite: false
+        )
+        file('grails-app/conf/application.groovy').withWriterAppend { BufferedWriter writer ->
+            writer.newLine()
+            writer.writeLine 'grails.plugin.springsecurity.rememberMe.persistent = true'
+            writer.writeLine "grails.plugin.springsecurity.rememberMe.persistentToken.domainClassName = '$domainClass'"
+            writer.newLine()
+        }
+        return SUCCESS
+    }
+}

plugin/grails-app/commands/grails.plugin.springsecurity/S2CreateRoleHierarchyEntryCommand.groovy

@@ -0,0 +1,68 @@
+/*
+ * Copyright 2023 Puneet Behl.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+package grails.plugin.springsecurity
+
+import grails.build.logging.ConsoleLogger
+import grails.build.logging.GrailsConsole
+import grails.codegen.model.Model
+import grails.dev.commands.GrailsApplicationCommand
+import groovy.transform.CompileStatic
+
+/**
+ * Creates a domain class for a persistent role hierarchy for the Spring Security Core plugin
+ * Usage: <code>./gradlew runCommand "-Pargs=s2-create-role-hierarchy-entry [DOMAIN CLASS NAME]"
+ * For example: <code>./gradlew runCommand "-Pargs=s2-create-role-hierarchy-entry com.yourapp.RoleHierarchyEntry"</code>
+ *
+ * @author Puneet Behl
+ * @since 6.0.0
+ */
+@CompileStatic
+class S2CreateRoleHierarchyEntryCommand implements GrailsApplicationCommand, CommandLineHelper, SkipBootstrap {
+
+    private static final String USAGE_MESSAGE = '''
+./gradlew runCommand "-Pargs=s2-create-role-hierarchy-entry [DOMAIN CLASS NAME]" 
+ 
+ For example: ./gradlew runCommand "-Pargs=s2-create-role-hierarchy-entry com.yourapp.RoleHierarchyEntry"
+'''
+
+    @Delegate
+    ConsoleLogger consoleLogger = GrailsConsole.getInstance()
+
+    @Override
+    boolean handle() {
+
+        if (args.size() == 0) {
+            consoleLogger.error("Usage: " + USAGE_MESSAGE)
+            return FAILURE
+        }
+
+        final String domainClass = args[0]
+        final Model domainModel = model(domainClass)
+
+        consoleLogger.addStatus("\nCreating role hierarchy entry class $domainClass")
+        render(template: template('RoleHierarchyEntry.groovy.template'),
+                destination: file("grails-app/domain/$domainModel.packagePath/${domainModel.simpleName}.groovy"),
+                model: domainModel, overwrite: false)
+
+        file('grails-app/conf/application.groovy').withWriterAppend { BufferedWriter writer ->
+            writer.newLine()
+            writer.writeLine "grails.plugin.springsecurity.roleHierarchyEntryClassName = '$domainClass'"
+            writer.newLine()
+        }
+
+        return SUCCESS
+    }
+}