Build for windows

.github/workflows/build.yaml

@@ -29,6 +29,9 @@ jobs:
       - name: Build for aarch64-unknown-linux-gnu
         run: nix build .#holochain_aarch64-linux
 
+      - name: Build for x86_64-pc-windows-gnu
+        run: nix build .#holochain_x86_64-windows
+
   build-apple:
     runs-on: macos-latest
     steps:

flake.nix

@@ -19,6 +19,11 @@
       };
     };
 
+    fenix = {
+      url = "github:nix-community/fenix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
     holochain = {
       url = "github:holochain/holochain/bump-influxive";
       flake = false;
@@ -43,6 +48,11 @@
             crossSystem = "x86_64-linux";
             rustTargetTriple = "x86_64-unknown-linux-gnu";
           };
+          holochain_x86_64-windows = import ./modules/holochain-windows.nix {
+            inherit localSystem inputs;
+            crate = "holochain";
+            package = "holochain";
+          };
         } // (if localSystem == "aarch64-darwin" then {
           holochain_aarch64-apple = import ./modules/holochain-cross.nix {
             inherit localSystem inputs;

modules/holochain-cross.nix

@@ -1,12 +1,14 @@
 {
   # Flake inputs
   inputs
+
 , # The system that we are compiling on
   localSystem
 
   # The crate to build, from the Holochain workspace. Must match the path to the Cargo.toml file.
 , crate
 
+  # The name of the package to build, from the selected crate.
 , package
 
 , #

modules/holochain-windows.nix

@@ -0,0 +1,73 @@
+{ inputs, localSystem, crate, package }:
+let
+  inherit (inputs) nixpkgs crane fenix;
+
+  pkgs = nixpkgs.legacyPackages.${localSystem};
+
+  toolchain = with fenix.packages.${localSystem};
+    combine [
+      minimal.rustc
+      minimal.cargo
+      targets.x86_64-pc-windows-gnu.latest.rust-std
+    ];
+
+  craneLib = (crane.mkLib pkgs).overrideToolchain toolchain;
+
+  # Crane filters out all non-cargo related files. Define include filter with files needed for build.
+  nonCargoBuildFiles = path: _type: builtins.match ".*(json|sql|wasm.gz)$" path != null;
+  includeFilesFilter = path: type:
+    (craneLib.filterCargoSources path type) || (nonCargoBuildFiles path type);
+
+  # Crane doesn't know which version to select from a workspace, so we tell it where to look
+  crateInfo = craneLib.crateNameFromCargoToml { cargoToml = inputs.holochain + "/crates/${crate}/Cargo.toml"; };
+
+  libsodium = pkgs.stdenv.mkDerivation {
+    name = "libsodium";
+    src = builtins.fetchurl {
+      url = "https://download.libsodium.org/libsodium/releases/libsodium-1.0.20-mingw.tar.gz";
+      sha256 = "sha256:09npqqrialraf2v4m6cicvhnj52p8jaya349wnzlklp31b0q3yq1";
+    };
+    unpackPhase = "true";
+    postInstall = ''
+      tar -xvf $src
+      mkdir -p $out
+      cp -r libsodium-win64/* $out
+    '';
+  };
+in
+craneLib.buildPackage {
+  pname = package;
+  version = crateInfo.version;
+  src = pkgs.lib.cleanSourceWith {
+    src = inputs.holochain;
+    filter = includeFilesFilter;
+  };
+
+  strictDeps = true;
+  doCheck = false;
+
+  CARGO_BUILD_TARGET = "x86_64-pc-windows-gnu";
+
+  # fixes issues related to libring
+  TARGET_CC = "${pkgs.pkgsCross.mingwW64.stdenv.cc}/bin/${pkgs.pkgsCross.mingwW64.stdenv.cc.targetPrefix}cc";
+
+  # Otherwise tx5-go-pion-sys picks up the host linker instead of the cross linker
+  RUSTC_LINKER = "${pkgs.pkgsCross.mingwW64.stdenv.cc}/bin/${pkgs.pkgsCross.mingwW64.stdenv.cc.targetPrefix}cc";
+
+  SODIUM_LIB_DIR = "${libsodium}/lib";
+
+  # OPENSSL_NO_VENDOR = "1";
+
+  nativeBuildInputs = with pkgs; [
+    go
+    perl
+  ];
+
+  depsBuildBuild = with pkgs; [
+    pkgsCross.mingwW64.stdenv.cc
+    pkgsCross.mingwW64.windows.pthreads
+  ];
+
+  cargoExtraArgs = "--package ${package}";
+}
+