Add support for NeoComplete

README.rst

@@ -170,8 +170,10 @@ vim-ipython from defining any of the default mappings.
 By default, vim-ipython activates the custom completefunc globally.
 Sometimes, having a completefunc breaks other plugins' completions. Putting
 the line ``let g:ipy_completefunc = 'local'`` in one's vimrc will activate the
-IPython-based completion only for current buffer. Setting `g:ipy_completefunc`
-to anything other than `'local'` or `'global'` disables it altogether.
+IPython-based completion only for current buffer. Putting ``let
+g:ipy_completefunc = 'omni'`` will set the omnifunc option for the current
+buffer. Setting `g:ipy_completefunc` to anything other than `'local'` or
+`'global'` disables it altogether.
 
 **NEW since IPython 0.13**
 

autoload/unite/sources/history_ipython.vim

@@ -0,0 +1,197 @@
+if exists('g:loaded_history_ipython')
+  finish
+endif
+let g:loaded_history_ipython = 1
+
+let s:save_cpo = &cpo
+set cpo&vim
+
+function! unite#sources#history_ipython#define()
+  return s:source
+endfunction
+
+let s:source = {
+    \ 'name' : 'history/ipython',
+    \ 'description' : 'candidates from IPython history',
+    \ 'action_table' : {},
+    \ 'hooks' : {},
+    \ 'default_action' : 'send',
+    \ 'default_kind' : 'word',
+    \ 'syntax' : 'uniteSource__Python',
+    \ 'max_candidates' : 100,
+    \}
+
+function! s:source.hooks.on_syntax(args, context)
+  let save_current_syntax = get(b:, 'current_syntax', '')
+  unlet! b:current_syntax
+
+  try
+    silent! syntax include @Python syntax/python.vim
+    syntax region uniteSource__IPythonPython
+        \ start=' ' end='$' contains=@Python containedin=uniteSource__IPython
+    let &l:iskeyword = substitute(&l:iskeyword, ',!$\|!,', '', '')
+  finally
+    let b:current_syntax = save_current_syntax
+  endtry
+endfunction
+
+function! s:source.hooks.on_init(args, context)
+  if !exists('*IPythonHistory')
+    call unite#print_source_error(
+          \ 'IPythonHistory() does not exist', s:source.name)
+    return
+  endif
+
+  let args = unite#helper#parse_source_args(a:args)
+  let a:context.source__session = get(a:context, 'source__session', -1)
+  if a:context.source__session == -1
+    let a:context.source__session = get(args, 0, -1)
+  endif
+  let a:context.source__input = a:context.input
+  if a:context.source__input == '' || a:context.unite__is_restart
+    let a:context.source__input = unite#util#input('Pattern: ',
+        \ a:context.source__input,
+        \ 'customlist,IPythonCmdComplete')
+  endif
+
+  call unite#print_source_message('Pattern: '
+      \ . a:context.source__input, s:source.name)
+endfunction
+
+function! s:source.gather_candidates(args, context)
+  if !exists('*IPythonHistory')
+    return []
+  endif
+
+  return map(IPythonHistory(a:context.source__input,
+      \                     a:context.source__session), '{
+      \ "word" : v:val.code,
+      \ "abbr" : printf("'''''' %d/%d '''''' %s", v:val.session, v:val.line,
+      \   v:val.code =~ "\n" ?
+      \     "\n" . join(split(v:val.code, "\n")[:50], "\n") : v:val.code),
+      \ "is_multiline" : 1,
+      \ "source__session" : v:val.session,
+      \ "source__line" : v:val.line,
+      \ "source__context" : a:context,
+      \ "action__regtype" : "V",
+      \ }')
+endfunction
+
+let s:source.action_table.send = {
+    \ 'description' : 'run in IPython',
+    \ 'is_selectable' : 1,
+    \ }
+function! s:source.action_table.send.func(candidates)
+  for candidate in a:candidates
+    let g:ipy_input = candidate.word
+    Python2or3 run_ipy_input()
+    silent! unlet g:ipy_input
+  endfor
+endfunction
+
+let s:source.action_table.session = {
+    \ 'description' : "get history for candidate's session",
+    \ 'is_quit' : 0,
+    \ 'is_invalidate_cache' : 1,
+    \ }
+function! s:source.action_table.session.func(candidate)
+  let context = a:candidate.source__context
+  let context.source__input = unite#util#input('Pattern: ',
+      \ context.source__input,
+      \ 'customlist,IPythonCmdComplete')
+  let context.source__session = a:candidate.source__session
+endfunction
+
+let s:source.action_table.session_info = {
+    \ 'description' : "print information about a session",
+    \ 'is_quit' : 0,
+    \ }
+function! s:source.action_table.session_info.func(candidate)
+  let store_history = get(g:, 'ipython_store_history', 1)
+  try
+    let g:ipython_store_history = 0
+    let session_info = [
+        \ "from IPython import get_ipython",
+        \ "def _session_info(session=0):",
+        \ "    def date(d):",
+        \ "        return d.strftime('%a %d%b%Y %T')",
+        \ "    session_id, start, end, cmds, remark = " .
+        \ "        get_ipython().history_manager.get_session_info(session)",
+        \ "    val = 'start: {0}'.format(date(start))",
+        \ "    if end:",
+        \ "        val += '; end: {0}; {1} commands'.format(date(end), cmds)",
+        \ "    return val",
+        \ ]
+    let g:ipy_input = join(session_info, "\n")
+    silent Python2or3 run_ipy_input(silent=True)
+    let g:ipy_input = printf('_session_info(%d)', a:candidate.source__session)
+    silent! unlet g:ipy_result
+    Python2or3 eval_ipy_input('g:ipy_result')
+    echomsg printf('session %d: %s',
+        \          a:candidate.source__session, g:ipy_result)
+  finally
+    let g:ipython_store_history = store_history
+  endtry
+endfunction
+
+let s:source.action_table.macro = {
+    \ 'description' : 'create IPython macro',
+    \ 'is_selectable' : 1,
+    \ }
+function! s:source.action_table.macro.func(candidates)
+  let g:ipy_input = printf('%%macro %s %s',
+      \ unite#util#input('Macro name: '),
+      \ join(map(a:candidates,
+      \ 'printf("%s/%s", v:val.source__session, v:val.source__line)'))
+      \ )
+  Python2or3 run_ipy_input()
+  silent! unlet g:ipy_input
+endfunction
+
+let s:source.action_table.yank = {
+    \ 'description' : 'yank candidates',
+    \ 'is_selectable' : 1,
+    \ 'is_quit' : 1,
+    \ }
+function! s:source.action_table.yank.func(candidates)
+  if len(a:candidates) == 1 && a:candidates[0].word !~ "\n"
+    let text = a:candidates[0].word
+    let mode = 'v'
+  else
+    let text = join(map(copy(a:candidates), 'v:val.word'), "\n\n")
+    let mode = 'V'
+  endif
+  call setreg('"', text, mode)
+  if has('clipboard')
+    if &clipboard =~# '\<unnamed\>'
+      call setreg('*', text, mode)
+    endif
+    if &clipboard =~# '\<unnamedplus\>'
+      call setreg('+', text, mode)
+    endif
+  endif
+
+  echohl Question | echo 'Yanked:' | echohl Normal
+  echo text
+endfunction
+
+let s:source.action_table.append = {
+    \ 'description' : 'append candidates',
+    \ 'is_selectable' : 1,
+    \ }
+function! s:source.action_table.append.func(candidates)
+  put = join(map(copy(a:candidates), 'v:val.word'), \"\n\n\")
+endfunction
+
+let s:source.action_table.insert = {
+    \ 'description' : 'insert candidates',
+    \ 'is_selectable' : 1,
+    \ }
+function! s:source.action_table.insert.func(candidates)
+  put! = join(map(copy(a:candidates), 'v:val.word'), \"\n\n\")
+endfunction
+
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+" vim:set et ts=2 sts=2 sw=2:

doc/ipython.txt

@@ -0,0 +1,159 @@
+*ipython.txt*
+
+==============================================================================
+Contents                                *vim-ipython-contents*
+
+1. Completion Metadata                     |vim-ipython-metadata|
+2. IPython Monitor                         |vim-ipython-monitor|
+3. IPython History Unite Source            |vim-ipython-history|
+4. Variables                               |vim-ipython-variables|
+    4.1. g:ipy_autostart                   |g:ipy_autostart|
+    4.2. g:ipy_completefunc                |g:ipy_completefunc|
+    4.3. g:ipy_input                       |g:ipy_input|
+    4.4. g:ipy_perform_mappings            |g:ipy_perform_mappings|
+    4.5. g:ipython_completion_timeout      |g:ipython_completion_timeout|
+    4.6. g:ipython_dictionary_completion   |g:ipython_dictionary_completion|
+    4.7. g:ipython_greedy_matching         |g:ipython_greedy_matching|
+    4.8. g:ipython_history_len             |g:ipython_history_len|
+    4.9. g:ipython_history_raw             |g:ipython_history_raw|
+    4.10. g:ipython_history_timeout        |g:ipython_history_timeout|
+    4.11. g:ipython_history_unique         |g:ipython_history_unique|
+    4.12. g:ipython_run_flags              |g:ipython_run_flags|
+    4.13. g:ipython_store_history          |g:ipython_store_history|
+    4.14. g:ipython_timeout                |g:ipython_timeout|
+
+==============================================================================
+1. Completion Metadata                   *vim-ipython-metadata*
+
+vim-ipython supports user-supplied metadata associated with completions from
+the IPython shell. The plugin fetches the metadata from the IPython kernel
+using the user-defined function `completion_metadata` which takes one
+parameter - the result of `get_ipython()`. If the function does not exist in
+IPython's namespace, completion will still work but without any menu/info
+entries in the completion menu. Each completion match should have a
+corresponding metadata dictionary with "word", "menu", and "info" fields. A
+basic (and slow) implementation of such a function follows: >
+
+    def completion_metadata(ip):
+        import inspect
+        import six
+        metadata = [dict(word=m) for m in ip.Completer.matches]
+        for m in metadata:
+            try:
+                obj = eval(m['word'], ip.user_ns)
+            except Exception:
+                continue
+            m['menu'] = six.moves.reprlib.repr(obj)
+            info = inspect.getdoc(obj)
+            if info:
+                m['info'] = info
+        return metadata
+
+==============================================================================
+2. IPython Monitor                       *vim-ipython-monitor*
+
+The included `monitor.py` script listens in on message from Vim to the IPython
+kernel to echo inputs and outputs to the kernel in real-time. The script must
+be started before connecting Vim to the IPython kernel so that it can
+differentiate between Vim and the Jupyter shell clients. The `:IPython`
+command can be executed multiple times without ill effect in case the monitor
+is started later on.
+
+Basic usage: >
+
+    $ python monitor.py &; jupyter console
+    :IPython
+
+Note: Currently the script looks for a connection file automatically and will
+connect to the first connection file it finds matching the glob pattern
+"kernel-[0-9]*.json'. This means the script will not connect to IPython
+notebook kernels by design.
+
+==============================================================================
+3. IPython History Unite Source          *vim-ipython-history*
+
+Note: Requires unite.vim: https://github.com/Shougo/unite.vim
+
+The plugin includes a Unite source named "history/ipython" providing an
+interface to the history messaging in IPython. The source will prompt for a
+glob pattern to search for. If no pattern is provided, the search results in
+up to |g:ipython_history_len| of the most recent IPython commands. If the
+pattern begins or ends with a '*', the other end of the pattern is anchored at
+the start or end of the match. For example, >
+
+    Pattern: def *
+
+will return results that start with a function definition and >
+
+    Pattern: *)
+
+will return results ending with ')'. Otherwise a '*' is both prepended
+and appended to the pattern, so >
+
+    Pattern: sys
+
+will return results containing "sys" anywhere.
+
+The input prompt allows completion from the IPython namespace.
+
+After selecting a history entry, the available actions are (in addition to
+Unite's common actions):
+
+    - `append` (insert the entry after the cursor line)
+    - `insert` (insert the entry before the cursor line)
+    - `macro` (prompt for a macro name and create an IPython macro to repeat
+      the commands)
+    - `send` (repeat the command in IPython)
+    - `session` (restart the history/ipython source showing entries only from
+      the same session as the selected entry)
+    - `session_info` (print session date and start time)
+    - `yank` (yank entries to unnamed and clipboard if 'clipboard' is set)
+
+Multiple history entries may be selected for all of the actions.
+
+==============================================================================
+4. Variables                             *vim-ipython-variables*
+
+------------------------------------------------------------------------------
+4.1. `g:ipy_autostart`                   *g:ipy_autostart*
+
+------------------------------------------------------------------------------
+4.2. `g:ipy_completefunc`                *g:ipy_completefunc*
+
+------------------------------------------------------------------------------
+4.3. `g:ipy_input`                       *g:ipy_input*
+
+------------------------------------------------------------------------------
+4.4. `g:ipy_perform_mappings`            *g:ipy_perform_mappings*
+
+------------------------------------------------------------------------------
+4.5. `g:ipython_completion_timeout`      *g:ipython_completion_timeout*
+
+------------------------------------------------------------------------------
+4.6. `g:ipython_dictionary_completion`   *g:ipython_dictionary_completion*
+
+------------------------------------------------------------------------------
+4.7. `g:ipython_greedy_matching`         *g:ipython_greedy_matching*
+
+------------------------------------------------------------------------------
+4.8. `g:ipython_history_len`             *g:ipython_history_len*
+
+------------------------------------------------------------------------------
+4.9. `g:ipython_history_raw`             *g:ipython_history_raw*
+
+------------------------------------------------------------------------------
+4.10. `g:ipython_history_timeout`        *g:ipython_history_timeout*
+
+------------------------------------------------------------------------------
+4.11. `g:ipython_history_unique`         *g:ipython_history_unique*
+
+------------------------------------------------------------------------------
+4.12. `g:ipython_run_flags`              *g:ipython_run_flags*
+
+------------------------------------------------------------------------------
+4.13. `g:ipython_store_history`          *g:ipython_store_history*
+
+------------------------------------------------------------------------------
+4.14. `g:ipython_timeout`                *g:ipython_timeout*
+
+ vim: textwidth=78 et filetype=help:norightleft: