lbl-srg · JayHuLBL · Sep 28, 2023 · Sep 29, 2023 · Sep 29, 2023 · Sep 29, 2023
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/SpeedCorrectionLatent.mo b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/SpeedCorrectionLatent.mo
@@ -0,0 +1,53 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses;
+model SpeedCorrectionLatent "Enthalpy wheels"
+  extends Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible;
+  Buildings.Controls.OBC.CDL.Interfaces.RealOutput epsLatCor(
+    final unit="1")
+    "Latent heat exchanger effectiveness correction" annotation (Placement(
+        transformation(extent={{100,-100},{140,-60}}), iconTransformation(
+          extent={{100,-100},{140,-60}})));
+equation
+  epsLatCor = Buildings.Utilities.Math.Functions.smoothInterpolation(
+                x=uSpe,
+                xSup=per.latHeatExchangeEffectiveness.uSpe,
+                ySup=per.latHeatExchangeEffectiveness.epsCor)
+                "Calculate the latent heat exchanger effectiveness correction";
+
+  annotation (
+  defaultComponentName="speCor",
+  Documentation(info="<html>
+<p>
+This model calculates the power consumption, and the corrections
+due to different rotational speeds for the sensible
+heat exchange effectiveness and the latent
+heat exchange effectiveness of an enthalpy wheel.
+</p>
+<p>
+The calculation of the power consumption and the sensible
+heat exchange effectiveness correction is described in
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible</a>.
+</p>
+<p>
+The latent heat exchange effectiveness correction is calculated using
+a cubic hermite spline interpolation of the latent heat exchange
+effectiveness dataset (see
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.HeatExchangerEffectiveness\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.HeatExchangerEffectiveness</a>).
+</p>
+</html>", revisions="<html>
+<ul>
+<li>
+May 28, 2024, by Sen Huang:<br/>
+First implementation.
+</li>
+</ul>
+</html>"),
+    Icon(graphics={
+        Line(points={{10,86},{4,74}}, color={0,140,72},
+          thickness=0.5),
+        Line(points={{-26,50},{10,86},{-2,78},{10,86}}, color={0,140,72},
+          thickness=0.5),
+        Ellipse(extent={{-42,64},{52,-58}}, lineColor={0,140,72},
+          lineThickness=0.5)}));
+end SpeedCorrectionLatent;
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/SpeedCorrectionSensible.mo b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/SpeedCorrectionSensible.mo
@@ -0,0 +1,117 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses;
+model SpeedCorrectionSensible "Sensible heat wheels"
+  extends Modelica.Blocks.Icons.Block;
+
+  final parameter Real xSpe[:] = if per.useDefaultMotorEfficiencyCurve
+    then per.motorEfficiency_default.y else per.motorEfficiency.uSpe
+    "x-axis support points of the power efficiency curve"
+    annotation (Dialog(group="Efficiency"));
+  final parameter Real[size(xSpe,1)] yEta = if per.useDefaultMotorEfficiencyCurve
+    then per.motorEfficiency_default.eta else per.motorEfficiency.eta
+    "y-axis support points of the power efficiency curve"
+    annotation (Dialog(group="Efficiency"));
+  parameter Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Generic per
+    "Record with performance data"
+    annotation (Placement(transformation(extent={{60,60},{80,80}})));
+  Buildings.Controls.OBC.CDL.Interfaces.RealInput uSpe(
+    final unit="1",
+    final max=1)
+    "Wheel speed ratio"
+    annotation (Placement(transformation(extent={{-140,-20},{-100,20}}),
+        iconTransformation(extent={{-140,-20},{-100,20}})));
+  Buildings.Controls.OBC.CDL.Interfaces.RealOutput P(final unit="W")
+    "Electric power consumption"
+    annotation (Placement(transformation(extent={{100,60},{140,100}}),
+        iconTransformation(extent={{100,60},{140,100}})));
+  Buildings.Controls.OBC.CDL.Interfaces.RealOutput epsSenCor(final unit="1")
+    "Sensible heat exchanger effectiveness correction"
+    annotation (Placement(transformation(extent={{100,-20},{140,20}}),
+    iconTransformation(extent={{100,-20},{140,20}})));
+
+protected
+  parameter Integer nSpe = size(yEta,1)
+    "Number of the points in the power efficiency curve";
+  parameter Real s = max(xSpe[i]/yEta[i] for i in 1:size(yEta,1)-1)
+    "Maximum ratio of x-axis to y-axis in the power efficiency curve";
+
+
+initial equation
+  assert(s < 1 + 1E-4,
+         "In " + getInstanceName() + ": The motor efficiency curve is wrong.
+         The ratio of the speed ratio to the motor percent
+         full-load efficiency must be less than 1.",
+         level=AssertionLevel.error)
+         "Check if the motor efficiency curve is correct";
+  assert(abs(yEta[nSpe]-1) < 1E-4,
+          "In " + getInstanceName() + ": The motor efficiency curve is wrong.
+          The motor percent full-load efficiency at the full seepd must be 1.",
+          level=AssertionLevel.error)
+          "Check if the motor efficiency curve is consistent with the nominal condition";
+equation
+  P = per.P_nominal*uSpe/Buildings.Utilities.Math.Functions.smoothInterpolation(
+        x=uSpe,
+        xSup=xSpe,
+        ySup=yEta)
+        "Calculate the wheel power consumption";
+  epsSenCor = Buildings.Utilities.Math.Functions.smoothInterpolation(
+                x=uSpe,
+                xSup=per.senHeatExchangeEffectiveness.uSpe,
+                ySup=per.senHeatExchangeEffectiveness.epsCor)
+                "Calculate the sensible heat exchanger effectiveness correction";
+   annotation (
+   defaultComponentName="speCor",
+   Documentation(info="<html>
+<p>
+This model calculates the power consumption and the sensible heat exchanger
+effectiveness correction due to different rotational speed of a sensible heat wheel.
+</p>
+<ul>
+<li>
+The power consumption of this wheel is calculated as
+<p align=\"center\" style=\"font-style:italic;\">
+P = P_nominal * uSpe / eta,
+</p>
+<p>
+where <code>P_nominal</code> is the nominal wheel power consumption,
+<code>uSpe</code> is the wheel speed ratio,
+and <code>eta</code> is the motor percent full-load efficiency,
+which is calculated as
+<p align=\"center\" style=\"font-style:italic;\">
+eta = eff(uSpe=x) / eff(uSpe=1),
+</p>
+<p>
+where <code>eff(uSpe=x)</code> is the motor efficiency when the speed ratio is <code>x</code>.
+The efficiency <code>eta</code> is obtained based on a cubic hermite spline interpolation of
+the motor percent full-load efficiency dataset (see
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.MotorEfficiency\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.MotorEfficiency</a>).
+Please note that <code>uSpe/eta</code> must be less or equal to 1.
+</p>
+</li>
+<li>
+The sensible heat exchanger effectiveness correction is calculated based
+on a cubic hermite spline interpolation of the sensible heat exchanger effectiveness
+dataset (see <a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.HeatExchangerEffectiveness\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics.HeatExchangerEffectiveness</a>).
+</li>
+</ul>
+</html>", revisions="<html>
+<ul>
+<li>
+May 28, 2024, by Sen Huang:<br/>
+First implementation.
+</li>
+</ul>
+</html>"),
+    Icon(graphics={
+        Ellipse(extent={{-42,64},{52,-58}}, lineColor={28,108,200},
+          lineThickness=0.5),
+        Line(points={{-26,50},{10,86},{-2,78},{10,86}}, color={28,108,200},
+          thickness=0.5),
+        Line(points={{10,86},{4,74}}, color={28,108,200},
+          thickness=0.5),
+        Text(
+          extent={{-38,96},{-8,56}},
+          textColor={0,0,88},
+          textString="u")}));
+end SpeedCorrectionSensible;
diff --git a/...s/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/VariableSpeedThermalWheels.mo b/...s/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/VariableSpeedThermalWheels.mo
@@ -0,0 +1,98 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.Validation;
+model VariableSpeedThermalWheels
+  "Model that tests the variable-speed thermal wheels"
+  extends Modelica.Icons.Example;
+  parameter Buildings.Fluid.HeatExchangers.ThermalWheels.Data.ASHRAE
+    perSenWhe(
+    motorEfficiency(uSpe={0.1,0.6,0.8,1}, eta={0.3,0.8,0.85,1}),
+    haveLatentHeatExchange=false,
+    useDefaultMotorEfficiencyCurve=false)
+    "Performance record for the sensible heat wheel"
+    annotation (Placement(transformation(extent={{-80,74},{-60,94}})));
+  parameter Buildings.Fluid.HeatExchangers.ThermalWheels.Data.ASHRAE perLatWhe(
+    motorEfficiency(uSpe={0.1,0.6,0.8,1}, eta={0.3,0.8,0.85,1}),
+    haveLatentHeatExchange=true,
+    useDefaultMotorEfficiencyCurve=false)
+    "Performance record for the enthalpy wheel"
+    annotation (Placement(transformation(extent={{-40,74},{-20,94}})));
+  parameter Buildings.Fluid.HeatExchangers.ThermalWheels.Data.ASHRAE perLatWheDefMotCur(
+    haveLatentHeatExchange=true,
+    useDefaultMotorEfficiencyCurve=true)
+    "Performance record for the enthalpy wheel with default motor dataset"
+    annotation (Placement(transformation(extent={{0,74},{20,94}})));
+  Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible
+    senWhe(per=perSenWhe)
+    "Sensible heat wheel"
+    annotation (Placement(transformation(extent={{-10,40},{10,60}})));
+
+  Modelica.Blocks.Sources.Ramp uSpe(
+    duration=1,
+    startTime=0,
+    offset=0,
+    height=1)
+    "Speed ratio"
+    annotation (Placement(transformation(extent={{-60,-10},{-40,10}})));
+  Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionLatent latWhe(
+    per=perLatWhe)
+    "Enthalpy wheel"
+    annotation (Placement(transformation(extent={{-10,-10},{10,10}})));
+  Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionLatent latWheDefMotCur(
+    per=perLatWheDefMotCur)
+    "Enthalpy wheel with default motor curve"
+    annotation (Placement(transformation(extent={{-10,-60},{10,-40}})));
+
+equation
+  connect(uSpe.y, senWhe.uSpe)
+    annotation (Line(points={{-39,0},{-28,0},{-28,50},
+          {-12,50}}, color={0,0,127}));
+  connect(latWhe.uSpe, uSpe.y)
+    annotation (Line(points={{-12,0},{-39,0}}, color={0,0,127}));
+  connect(latWheDefMotCur.uSpe, uSpe.y)
+    annotation (Line(points={{-12,-50},{-28,
+          -50},{-28,0},{-39,0}}, color={0,0,127}));
+  annotation (
+    __Dymola_Commands(file=
+        "modelica://Buildings/Resources/Scripts/Dymola/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/VariableSpeedThermalWheels.mos"
+        "Simulate and plot"),
+    experiment(
+      StopTime=1,
+      Tolerance=1e-06),
+    Documentation(info="<html>
+<p>
+Example for the model
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionSensible</a> and the model
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.SpeedCorrectionLatent\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses.latent</a>.
+</p>
+<p>
+The input signals are configured as follows:
+</p>
+<ul>
+<li>
+The wheel speed <code>uSpe</code> changes from <i>0</i> to <i>1</i>
+during the period from 0 to 1 second.
+</li>
+</ul>
+<p>
+The expected outputs are:
+</p>
+<ul>
+<li>
+The power consumption of all three wheels increases over time
+and equals the nominal value when <code>uSpe=1</code>.
+</li>
+<li>
+The heat exchange effectiveness corrections increase by time
+and equal 1 when <code>uSpe=1</code>.
+</li>
+</ul>
+</html>", revisions="<html>
+<ul>
+<li>
+May 28, 2024, by Sen Huang:<br/>
+First implementation.
+</li>
+</ul>
+</html>"));
+end VariableSpeedThermalWheels;
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/package.mo b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/package.mo
@@ -0,0 +1,20 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses;
+package Validation "Collection of validation models"
+extends Modelica.Icons.ExamplesPackage;
+
+  annotation (Documentation(info="<html>
+<p>
+This package contains validation models for the classes in
+<a href=\"modelica://Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses\">
+Buildings.Fluid.HeatExchangers.ThermalWheels.BaseClasses</a>.
+</p>
+<p>
+Note that most validation models contain simple input data
+which may not be realistic, but for which the correct
+output can be obtained through an analytic solution.
+The examples plot various outputs, which have been verified against these
+solutions. These model outputs are stored as reference data and
+used for continuous validation whenever models in the library change.
+</p>
+</html>"));
+end Validation;
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/package.order b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/Validation/package.order
@@ -0,0 +1 @@
+VariableSpeedThermalWheels
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/package.mo b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/package.mo
@@ -0,0 +1,12 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels;
+package BaseClasses "Models of variable-speed thermal wheels"
+  extends Modelica.Icons.BasesPackage;
+
+annotation (Documentation(info="<html>
+<p>
+This package contains models for capturing the impacts of
+the wheel speed ratio on the power consumption and the heat
+exchange effectiveness of thermal wheels.
+</p>
+</html>"));
+end BaseClasses;
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/package.order b/Buildings/Fluid/HeatExchangers/ThermalWheels/BaseClasses/package.order
@@ -0,0 +1,3 @@
+SpeedCorrectionLatent
+SpeedCorrectionSensible
+Validation
diff --git a/Buildings/Fluid/HeatExchangers/ThermalWheels/Data/ASHRAE.mo b/Buildings/Fluid/HeatExchangers/ThermalWheels/Data/ASHRAE.mo
@@ -0,0 +1,35 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.Data;
+record ASHRAE = Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Generic(
+  senHeatExchangeEffectiveness(
+    uSpe={0,0.1,0.2,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1},
+    epsCor={0,0.40,0.71,0.83,0.90,0.93,0.96,0.97,0.98,0.99,1}),
+  latHeatExchangeEffectiveness(
+    uSpe={0,0.15,0.3,0.4,0.5,0.6,0.7,0.8,0.9,1},
+    epsCor={0,0.26,0.37,0.58,0.72,0.81,0.86,0.90,0.96,1}))
+      "ASHRAE data record for variable-speed thermal wheels"
+  annotation (
+  defaultComponentPrefixes = "parameter",
+  defaultComponentName = "per",
+  Documentation(revisions="<html>
+<ul>
+<li>
+May 28, 2024, by Sen Huang:<br/>
+First implementation.
+</li>
+</ul>
+</html>", info="<html>
+<p>
+ASHRAE performance dataset for the variable-speed wheel model.
+</p>
+<p>
+It is developed based on Figure 7 in ASHRAE (2024).
+However, the original data set was extrapolated to cover lower values
+of speed ratio, i.e. <code> &lt;= 0.2</code>, by setting the heat exchange effectiveness
+corrections to 0 when the speed ratio is 0.
+</p>
+<h4>References</h4>
+<p>
+ASHRAE (2024).
+<i>Chapter 26, Air-to-Air Energy Recovery Equipment, ASHRAE Handbook—HVAC Systems and Equipment.</i>
+</p>
+</html>"));
diff --git a/...ngs/Fluid/HeatExchangers/ThermalWheels/Data/Characteristics/HeatExchangerEffectiveness.mo b/...ngs/Fluid/HeatExchangers/ThermalWheels/Data/Characteristics/HeatExchangerEffectiveness.mo
@@ -0,0 +1,35 @@
+within Buildings.Fluid.HeatExchangers.ThermalWheels.Data.Characteristics;
+record HeatExchangerEffectiveness
+  "Parameters for defining heat exchanger effectiveness at different wheel speed ratios"
+  extends Modelica.Icons.Record;
+
+  parameter Real uSpe[:](
+    each final min=0,
+    each final unit="1")
+    "Wheel speed ratio";
+  parameter Real epsCor[:](
+    each final max=1,
+    each final unit="1")
+    "Correction of the heat exchange effectiveness for speed ratios between 0 and 1";
+  annotation (
+  defaultComponentPrefixes = "parameter",
+  defaultComponentName = "per",
+  Documentation(info="<html>
+<p>
+Data record that describes wheel speed ratio <code>uSpe</code> versus
+heat exchange effectiveness corrections <code>epsCor</code>, i.e., the ratio of the heat exchange effectiveness
+to that when the <code>uSpe</code> is <i>1</i>.
+The elements of the vector <code>uSpe</code> should be in ascending order,
+i.e.,<code>uSpe[i] &lt; uSpe[i+1]</code>.
+Both vectors, <code>uSpe</code> and <code>epsCor</code>
+must have the same size.
+</p>
+</html>", revisions="<html>
+<ul>
+<li>
+May 28, 2024, by Sen Huang:<br/>
+First implementation.
+</li>
+</ul>
+</html>"));
+end HeatExchangerEffectiveness;