librespot: init module

Librespot is a Spotify client. While there is already a module for
spotifyd, which uses Librespot as a library, this adds one for the
upstream frontend.

modules/modules.nix

@@ -327,6 +327,7 @@ let
     ./services/kdeconnect.nix
     ./services/keybase.nix
     ./services/keynav.nix
+    ./services/librespot.nix
     ./services/lieer.nix
     ./services/listenbrainz-mpd.nix
     ./services/lorri.nix

modules/services/librespot.nix

@@ -0,0 +1,89 @@
+{ config, lib, nixosConfig, pkgs, ... }:
+
+let
+  inherit (lib) types;
+
+  cfg = config.services.librespot;
+in {
+  options.services.librespot = {
+    enable = lib.mkEnableOption "Librespot (Spotify Connect speaker daemon)";
+
+    package = lib.mkPackageOption pkgs "librespot" { };
+
+    settings = lib.mkOption {
+      description = ''
+        Command-line arguments to pass to librespot.
+
+        Boolean values render as a flag if true, and nothing if false.
+        Null values are ignored.
+        All other values are rendered as options with an argument.
+      '';
+      type = types.submodule {
+        freeformType = let t = types;
+        in t.attrsOf (t.nullOr (t.oneOf [ t.bool t.str t.int t.path ]));
+
+        options = {
+          cache = lib.mkOption {
+            default = "${config.xdg.cacheHome}/librespot";
+            defaultText = "$XDG_CACHE_HOME/librespot";
+            type = types.nullOr types.path;
+            description =
+              "Path to a directory where files will be cached after downloading.";
+          };
+
+          system-cache = lib.mkOption {
+            default = "${config.xdg.stateHome}/librespot";
+            defaultText = "$XDG_STATE_HOME/librespot";
+            type = types.nullOr types.path;
+            description =
+              "Path to a directory where system files (credentials, volume) will be cached.";
+          };
+        };
+      };
+      default = { };
+    };
+
+    generatedArgs = lib.mkOption {
+      type = types.listOf types.str;
+      visible = true;
+      readOnly = true;
+      description = ''
+        Generated command line for the librespot service.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.librespot = {
+      generatedArgs = lib.pipe cfg.settings [
+        builtins.attrNames
+        (builtins.concatMap (k:
+          let v = cfg.settings.${k};
+          in if v == null || v == false then
+            [ ]
+          else if v == true then
+            [ "--${k}" ]
+          else
+            [ "--${k}=${toString v}" ]))
+      ];
+    };
+
+    home.packages = [ cfg.package ];
+
+    systemd.user.services.librespot = {
+      Unit = { Description = "Librespot (an open source Spotify client)"; };
+
+      Install.WantedBy = [ "default.target" ];
+
+      Service = {
+        ExecStart = pkgs.writeShellScript "librespot" ''
+          exec '${cfg.package}/bin/librespot' ${
+            lib.escapeShellArgs cfg.generatedArgs
+          }
+        '';
+        Restart = "always";
+        RestartSec = 12;
+      };
+    };
+  };
+}