Simplify code and test genserver directly

lib/plausible/ingestion/scroll_depth_visible_at.ex

@@ -1,85 +1,55 @@
 defmodule Plausible.Ingestion.ScrollDepthVisibleAt do
-  @moduledoc false
+  @moduledoc """
+  GenServer that updates the `scroll_depth_visible_at` column for a site when needed.
+
+  This is called in a hot loop in ingestion, so it:
+  1. Only updates the database once per site (if SiteCache doesn't know about visibility yet)
+  2. Does not retry the update if it fails, to be retried on server restart
+  """
 
   use GenServer
   require Logger
   alias Plausible.Repo
 
   import Ecto.Query
 
-  @initial_state %{
-    updated_sites: MapSet.new(),
-    pending: MapSet.new()
-  }
-
-  def start_link(opts) do
+  def start_link(opts \\ []) do
     opts = Keyword.merge(opts, name: __MODULE__)
-    GenServer.start_link(__MODULE__, @initial_state, opts)
+    GenServer.start_link(__MODULE__, opts, opts)
   end
 
   def mark_scroll_depth_visible(site_id) do
     GenServer.cast(__MODULE__, {:update_site, site_id})
   end
 
   @impl true
-  def init(state) do
-    {:ok, state}
+  def init(_opts) do
+    {:ok, MapSet.new()}
   end
 
   @impl true
-  def handle_cast({:update_site, site_id}, state) do
-    cond do
-      MapSet.member?(state.updated_sites, site_id) ->
-        {:noreply, state}
-
-      MapSet.member?(state.pending, site_id) ->
-        {:noreply, state}
-
-      true ->
-        Task.start(fn -> attempt_update_repo(site_id) end)
-
-        {:noreply,
-         %{
-           updated_sites: state.updated_sites,
-           pending: MapSet.put(state.pending, site_id)
-         }}
+  def handle_cast({:update_site, site_id}, touched_sites) do
+    # When receiving multiple update requests for a site, only process the first one
+    if MapSet.member?(touched_sites, site_id) do
+      {:noreply, touched_sites}
+    else
+      Task.start(fn -> attempt_update_repo(site_id) end)
+
+      {:noreply, MapSet.put(touched_sites, site_id)}
     end
   end
 
-  @impl true
-  def handle_cast({:mark_updated, site_id}, state) do
-    {:noreply,
-     %{
-       updated_sites: MapSet.put(state.updated_sites, site_id),
-       pending: MapSet.delete(state.pending, site_id)
-     }}
-  end
-
-  @impl true
-  def handle_cast({:mark_update_failed, site_id}, state) do
-    {:noreply,
-     %{
-       updated_sites: state.updated_sites,
-       pending: MapSet.delete(state.pending, site_id)
-     }}
-  end
-
   defp attempt_update_repo(site_id) do
     Repo.update_all(
       from(s in Plausible.Site, where: s.id == ^site_id),
       set: [
         scroll_depth_visible_at: DateTime.utc_now()
       ]
     )
-
-    # Call genserver with {:mark_updated, site_id}
-    GenServer.cast(__MODULE__, {:mark_updated, site_id})
   rescue
     error ->
       Logger.error(
-        "Error updating scroll depth visible at for site #{site_id}: #{inspect(error)}. Will retry later."
+        "Error updating scroll_depth_visible_at for site #{site_id}: #{inspect(error)}. This will not be retried until server restart."
       )
-
-      GenServer.cast(__MODULE__, {:mark_update_failed, site_id})
   end
 end

test/plausible/ingestion/scroll_depth_visible_at_test.exs

@@ -0,0 +1,14 @@
+defmodule Plausible.Ingestion.ScrollDepthVisibleAtTest do
+  use Plausible.DataCase
+  use Plausible.Teams.Test
+
+  test "mark_scroll_depth_visible" do
+    site = new_site()
+    Plausible.Ingestion.ScrollDepthVisibleAt.mark_scroll_depth_visible(site.id)
+
+    Plausible.TestUtils.eventually(fn ->
+      site = Plausible.Repo.reload!(site)
+      {not is_nil(site.scroll_depth_visible_at), site.scroll_depth_visible_at}
+    end)
+  end
+end