Add support for node selectors and tolerations.

Fixes #4

VERSION.txt

@@ -1 +1 @@
-3.2.1
+3.3.0

main.tf

@@ -108,6 +108,37 @@ resource "kubernetes_deployment" "this" {
       }
 
       spec {
+
+        dynamic "affinity" {
+          for_each = length(var.node_selectors) > 0 ? ["placeholder"] : []
+          content {
+            node_affinity {
+              required_during_scheduling_ignored_during_execution {
+                dynamic "node_selector_term" {
+                  for_each = var.node_selectors
+                  content {
+                    match_expressions {
+                      key      = node_selector_term.key
+                      operator = "In"
+                      values   = [node_selector_term.value]
+                    }
+                  }
+                }
+              }
+            }
+          }
+        }
+
+        dynamic "toleration" {
+          for_each = var.tolerations
+          content {
+            key      = toleration.value["key"]
+            operator = toleration.value["operator"]
+            value    = toleration.value["value"]
+            effect   = toleration.value["effect"]
+          }
+        }
+
         automount_service_account_token = true
 
         dynamic "volume" {

variables.tf

@@ -82,3 +82,15 @@ variable "tiller_tls" {
   }
   description = "TLS configuration for Tiller."
 }
+
+variable "tolerations" {
+  type        = list(map(string))
+  default     = []
+  description = "Tolerations to apply to Tiller deployment"
+}
+
+variable "node_selectors" {
+  type        = map(string)
+  default     = {}
+  description = "Map of {label: value} to use as node selector for Tiller deployment"
+}