Add nix-on-droid configuration

flake.nix

@@ -13,6 +13,12 @@
       inputs.nixpkgs.follows = "nixpkgs-unstable";
     };
 
+    nix-on-droid = {
+      url = "github:t184256/nix-on-droid";
+      inputs.home-manager.follows = "home-manager";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
     pre-commit-hooks = {
       url = "github:cachix/pre-commit-hooks.nix";
       inputs = {
@@ -93,6 +99,10 @@
         (mkNixos x86_64-linux "nixos-vm")
       ];
 
+      nixOnDroidConfigurations = listToAttrs [
+        (mkNixOnDroid "aarch64-linux" "nix-on-droid")
+      ];
+
       apps = mkForEachSystem [
         (mkApp "setup" {
           file = "setup.sh";

home/base/default.nix

@@ -1,8 +1,8 @@
-{ config, ... }:
+{ config, lib, ... }:
 
 {
   home = {
-    homeDirectory = "/home/${config.home.username}";
+    homeDirectory = lib.mkDefault "/home/${config.home.username}";
 
     sessionPath = [
       "$HOME/bin"

home/roles/mobile/default.nix

@@ -0,0 +1,29 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.custom.roles.mobile;
+  username = "nix-on-droid";
+
+in
+
+{
+  options = {
+    custom.roles.mobile = {
+      enable = mkEnableOption "Mobile";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home = {
+      inherit username;
+    };
+
+    custom.base.non-nixos = {
+      enable = true;
+      installNix = false;
+    };
+  };
+}

hosts/nix-on-droid/home-nix-on-droid.nix

@@ -0,0 +1,8 @@
+{
+  custom.roles = {
+    homeage.enable = true;
+    mobile.enable = true;
+  };
+
+  home.stateVersion = "23.05";
+}

hosts/nix-on-droid/nix-on-droid.nix

@@ -0,0 +1,46 @@
+{ config, lib, pkgs, homeModules, inputs, ... }:
+
+let
+
+  mkUserConfigPath = host: "${inputs.self}/hosts/${host}/home-nix-on-droid.nix";
+
+in
+
+{
+  environment = {
+    #etcBackupExtension = ".nod-bak";
+    #motd = null;
+
+    packages = with pkgs; [
+      git
+    ];
+  };
+
+  home-manager = {
+    backupFileExtension = "hm-bak";
+    useGlobalPkgs = true;
+    useUserPackages = true;
+    extraSpecialArgs = { inherit inputs; };
+    sharedModules = homeModules;
+
+    config = mkUserConfigPath "nix-on-droid";
+  };
+
+  nix.package = pkgs.nix;
+
+  # FIXME: update when released
+  system.stateVersion = "22.11";
+
+  terminal.font =
+    let
+      fontPackage = pkgs.nerdfonts.override {
+        fonts = [ "UbuntuMono" ];
+      };
+      fontPath = "/share/fonts/truetype/NerdFonts/UbuntuMonoNerdFont-Regular.ttf";
+    in
+    fontPackage + fontPath;
+
+  time.timeZone = "Europe/Zurich";
+
+  user.shell = "${pkgs.zsh}/bin/zsh";
+}

lib/builders/mkNixOnDroid.nix

@@ -0,0 +1,33 @@
+{ inputs, system, pkgs, customLib, homeModules, name, ... }:
+
+let
+
+  inherit (pkgs) lib;
+  rootPath = inputs.self;
+
+in
+
+inputs.nix-on-droid.lib.nixOnDroidConfiguration {
+  modules = [
+    "${rootPath}/hosts/${name}/nix-on-droid.nix"
+
+    {
+      _file = ./mkNixOnDroid.nix;
+
+      options.lib = lib.mkOption {
+        type = lib.types.attrsOf lib.types.attrs;
+        default = { };
+        description = ''
+          This option allows modules to define helper functions,
+          constants, etc.
+        '';
+      };
+
+      config.lib.custom = customLib;
+    }
+  ];
+
+  extraSpecialArgs = {
+    inherit inputs pkgs homeModules;
+  };
+}

lib/default.nix

@@ -78,4 +78,5 @@ in
   mkGeneric = nameValuePairWrapper;
   mkHome = simpleWrapper ./builders/mkHome.nix;
   mkNixos = simpleWrapper ./builders/mkNixos.nix;
+  mkNixOnDroid = simpleWrapper ./builders/mkNixOnDroid.nix;
 }