Update bootstrapping s3 resources for aws provider v4

bootstrap/.terraform-version

@@ -1 +1 @@
-0.14.7
+1.2.1

bootstrap/s3_bucket.tf

@@ -1,41 +1,7 @@
 resource "aws_s3_bucket" "bucket" {
-  bucket = var.bucket_name
-  acl    = "private"
-
+  bucket        = var.bucket_name
   force_destroy = "false"
 
-  lifecycle_rule {
-    prefix  = ""
-    enabled = "true"
-
-    noncurrent_version_transition {
-      days          = "30"
-      storage_class = "STANDARD_IA"
-    }
-
-    noncurrent_version_transition {
-      days          = "60"
-      storage_class = "GLACIER"
-    }
-
-    noncurrent_version_expiration {
-      days = "90"
-    }
-  }
-
-  server_side_encryption_configuration {
-    rule {
-      apply_server_side_encryption_by_default {
-        kms_master_key_id = aws_kms_key.s3.arn
-        sse_algorithm     = "aws:kms"
-      }
-    }
-  }
-
-  versioning {
-    enabled = "true"
-  }
-
   # This does not use default tag map merging because bootstrapping is special
   # You should use default tag map merging elsewhere
   tags = {

bootstrap/s3_bucket_acl.tf

@@ -0,0 +1,4 @@
+resource "aws_s3_bucket_acl" "bucket" {
+  bucket = aws_s3_bucket.bucket.id
+  acl    = "private"
+}

bootstrap/s3_bucket_lifecycle_configuration.tf

@@ -0,0 +1,27 @@
+resource "aws_s3_bucket_lifecycle_configuration" "bucket" {
+  bucket                = aws_s3_bucket.bucket.id
+  expected_bucket_owner = var.aws_account_id
+
+  rule {
+    id     = "default"
+    status = "Enabled"
+
+    filter {
+      prefix = ""
+    }
+
+    noncurrent_version_transition {
+      noncurrent_days = "30"
+      storage_class   = "STANDARD_IA"
+    }
+
+    noncurrent_version_transition {
+      noncurrent_days = "60"
+      storage_class   = "GLACIER"
+    }
+
+    noncurrent_version_expiration {
+      noncurrent_days = "90"
+    }
+  }
+}

bootstrap/s3_bucket_server_side_encryption_configuration.tf

@@ -0,0 +1,10 @@
+resource "aws_s3_bucket_server_side_encryption_configuration" "bucket" {
+  bucket = aws_s3_bucket.bucket.bucket
+
+  rule {
+    apply_server_side_encryption_by_default {
+      kms_master_key_id = aws_kms_key.s3.arn
+      sse_algorithm     = "aws:kms"
+    }
+  }
+}

bootstrap/s3_bucket_versioning.tf

@@ -0,0 +1,7 @@
+resource "aws_s3_bucket_versioning" "bucket" {
+  bucket = aws_s3_bucket.bucket.id
+
+  versioning_configuration {
+    status = "Enabled"
+  }
+}

bootstrap/versions.tf

@@ -2,9 +2,9 @@ terraform {
   required_providers {
     aws = {
       source  = "hashicorp/aws"
-      version = "~> 3.31.0"
+      version = "~> 4.15.1"
     }
   }
 
-  required_version = ">= 0.14.7"
+  required_version = ">= 1.2.1"
 }