Core - Add PhysX Ropes as "connector wires" for Infantry-Phone/GSA/External

addons/sys_core/CfgVehicles.hpp

@@ -0,0 +1,25 @@
+class CfgNonAIVehicles {
+    class GVAR(connectorWireSegment) {
+        scope = 2;
+        displayName = "Connector Wire";
+        simulation = "ropesegment";
+        autocenter = 0;
+        animated = 0;
+        model = QPATHTOF(data\wire.p3d);
+    };
+};
+
+class CfgVehicles {
+    class Rope;
+    class GVAR(connectorWire): Rope {
+        segmentType = QGVAR(connectorWireSegment);
+        model = QPATHTOF(data\wire.p3d);
+    };
+
+    class Car;
+    class GVAR(connectorHelper): Car {
+        displayName = "Connector Rope Helper";
+        model = "core\default\default.p3d";
+        scope = 2;
+    };
+};

addons/sys_core/XEH_PREP.hpp

@@ -18,6 +18,7 @@ PREP(getLanguageName);
 PREP(getPlayersInVehicle);
 PREP(getSpeakingLanguageId);
 PREP(getSpokenLanguages);
+PREP(handleConnectorRope);
 PREP(handleGetClientID);
 PREP(handleGetHeadVector);
 PREP(handleGetPluginVersion);

addons/sys_core/XEH_preInit.sqf

@@ -9,6 +9,17 @@ PREP_RECOMPILE_END;
 // CBA Settings
 #include "initSettings.inc.sqf"
 
+if (isServer) then {
+    [QGVAR(hideConnectorRopeHelpers), {
+        params ["_ropeHelpers"];
+        { hideObjectGlobal _x; } forEach _ropeHelpers;
+    }] call CBA_fnc_addEventHandler;
+};
+
+[QGVAR(handleConnectorRopeEvent), {
+    _this call FUNC(handleConnectorRope);
+}] call CBA_fnc_addEventHandler;
+
 if (!hasInterface) exitWith {
     ADDON = true;
 };
@@ -46,6 +57,9 @@ DGVAR(pttKeyDown) = false;
 
 DGVAR(speaking_cache_valid) = false;
 
+DGVAR(connectorRope) = objNull;
+DGVAR(connectorRopeHelpers) = [];
+
 DVAR(ACRE_SPIT_VERSION) = false;
 DVAR(ACRE_IS_SYNCING) = false;
 DVAR(ACRE_SPECTATORS_LIST) = [];

addons/sys_core/config.cpp

@@ -14,6 +14,7 @@ class CfgPatches {
 };
 #include "CfgEventHandlers.hpp"
 #include "CfgSounds.hpp"
+#include "CfgVehicles.hpp"
 
 class CfgAcreWorlds {
 

addons/sys_core/data/wire.cfg

@@ -0,0 +1,7 @@
+class CfgModels {
+    class wire {
+        sectionsInherit = "";
+        sections[] = {"rope"};
+        skeletonName = "";
+    };
+};

addons/sys_core/fnc_handleConnectorRope.sqf

@@ -0,0 +1,94 @@
+#include "script_component.hpp"
+/*
+ * Author: mrschick
+ * Handles PhysX Ropes to represent "connector wires" for infantry phone, GSA, radio sharing, etc.
+ *
+ * Arguments:
+ * 0: State: true to create rope, false to remove <BOOLEAN>
+ * 1: Type of object to connect to: 0 = Infantry Phone, 1 = GSA, 2 = Shared radio <NUMBER> (default: 0)
+ * 2: Vehicle or object the rope starts from <OBJECT> (default: objNull)
+ * 3: Unit the rope should be attached to <OBJECT> (default: objNull)
+ * 4: Relative position offset for where the rope starts from <POSITION> (default: [0,0,0])
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [true, _vehicle, _player, _infantryPhonePosition] call acre_sys_intercom_fnc_handleConnectorRope
+ * [false] call acre_sys_intercom_fnc_handleConnectorRope
+ *
+ * Public: No
+ */
+
+params ["_state", ["_type", 0], ["_fromObject", objNull], ["_toObject", objNull], ["_fromPoint", [0, 0, 0]]];
+
+if (!EGVAR(sys_gestures,showConnectorRopes)) exitWith {};
+
+private _helper = QGVAR(connectorHelper);
+
+if (_state) then {
+    private _connectorRopeHelpers = [];
+    private _connectorRope = "";
+
+    switch (_type) do {
+        case 0: { // Connect rope to Infantry Phone
+            // Create Rope
+            _connectorRope = ropeCreate [_fromObject, _fromPoint, 3, nil, nil, QGVAR(connectorWire)];
+
+            // Create helper object on player pelvis
+            _connectorRopeHelpers set [0, _helper createVehicle position _toObject];
+            [_connectorRopeHelpers select 0, [0, 0, 0]] ropeAttachTo _connectorRope;
+            (_connectorRopeHelpers select 0) attachTo [_toObject, [-0.1, 0.1, 0.25], "Pelvis"];
+            (_connectorRopeHelpers select 0) allowDamage false;
+
+            // Hide Helper Object
+            [QGVAR(hideConnectorRopeHelpers), [_connectorRopeHelpers]] call CBA_fnc_serverEvent;
+        };
+        case 1: { // Connect rope to Ground Spike Antenna
+            // Create helper object on GSA
+            _connectorRopeHelpers set [0, _helper createVehicle position _fromObject];
+            (_connectorRopeHelpers select 0) disableCollisionWith _fromObject;
+            (_connectorRopeHelpers select 0) setPos (position _fromObject);
+            (_connectorRopeHelpers select 0) allowDamage false;
+
+            // Create helper object on player pelvis
+            _connectorRopeHelpers set [1, _helper createVehicle position _toObject];
+            (_connectorRopeHelpers select 1) attachTo [_toObject, [-0.1, 0.1, 0.15], "Pelvis"];
+            (_connectorRopeHelpers select 1) allowDamage false;
+
+            // Hide Helper Objects
+            [QGVAR(hideConnectorRopeHelpers), [_connectorRopeHelpers]] call CBA_fnc_serverEvent;
+
+            // Create Rope between helper objects
+            _connectorRope = ropeCreate [_connectorRopeHelpers select 0, _fromPoint, 5, nil, nil, QGVAR(connectorWire)];
+            [(_connectorRopeHelpers select 1), [0, 0, 0]] ropeAttachTo _connectorRope;
+        };
+        case 2: { // Connect rope to shared backpack radio owner
+            // Create helper object on radio owner
+            _connectorRopeHelpers set [0, _helper createVehicle position _fromObject];
+            (_connectorRopeHelpers select 0) attachTo [_fromObject, [-0.1, 0.1, 0.15], "Pelvis"];
+            (_connectorRopeHelpers select 0) allowDamage false;
+
+            // Create helper object on player pelvis
+            _connectorRopeHelpers set [1, _helper createVehicle position _toObject];
+            (_connectorRopeHelpers select 1) attachTo [_toObject, [-0.1, 0.1, 0.15], "Pelvis"];
+            (_connectorRopeHelpers select 1) allowDamage false;
+
+            // Hide Helper Objects
+            [QGVAR(hideConnectorRopeHelpers), [_connectorRopeHelpers]] call CBA_fnc_serverEvent;
+
+            // Create Rope between helper objects
+            _connectorRope = ropeCreate [_connectorRopeHelpers select 0, _fromPoint, 1.2, nil, nil, QGVAR(connectorWire)];
+            [_connectorRopeHelpers select 1, [0, 0, 0]] ropeAttachTo _connectorRope;
+        };
+    };
+
+    GVAR(connectorRope) = _connectorRope;
+    GVAR(connectorRopeHelpers) = _connectorRopeHelpers;
+} else {
+    // Destroy rope
+    ropeDestroy GVAR(connectorRope);
+    GVAR(connectorRope) = objNull;
+    { deleteVehicle _x } forEach GVAR(connectorRopeHelpers);
+    GVAR(connectorRopeHelpers) = [objNull, objNull];
+};

addons/sys_external/fnc_startUsingExternalRadio.sqf

@@ -37,4 +37,7 @@ ACRE_ACTIVE_EXTERNAL_RADIOS pushBackUnique _radioId;
 // Set it as active radio.
 [_radioId] call EFUNC(api,setCurrentRadio);
 
+// Visualize the connection with a connector rope
+[QEGVAR(sys_core,handleConnectorRopeEvent), [true, 2, _owner, _endUser]] call CBA_fnc_localEvent;
+
 [[ICON_RADIO_CALL], [format [localize LSTRING(hintTake), _displayName, name _owner]], true] call CBA_fnc_notify;

addons/sys_external/fnc_stopUsingExternalRadio.sqf

@@ -28,6 +28,9 @@ private _baseRadio =  [_radioId] call EFUNC(api,getBaseRadio);
 private _displayName = getText (ConfigFile >> "CfgWeapons" >> _baseRadio >> "displayName");
 [[ICON_RADIO_CALL], [format [localize LSTRING(hintReturn), _displayName, name _owner]], true] call CBA_fnc_notify;
 
+// Destroy Rope
+[QEGVAR(sys_core,handleConnectorRopeEvent), [false]] call CBA_fnc_localEvent;
+
 if (_target == _owner) then {
     // Handle remote owner
     private _message = format [localize LSTRING(hintReturnOwner), name ([_radioId] call FUNC(getExternalRadioUser)), _displayName];

addons/sys_gestures/initSettings.inc.sqf

@@ -19,3 +19,14 @@
     {},
     true
 ] call CBA_fnc_addSetting;
+
+[
+    QGVAR(showConnectorRopes),
+    "CHECKBOX",
+    [LLSTRING(showConnectorRopes), LLSTRING(showConnectorRopes_description)],
+    LLSTRING(category),
+    true,
+    true,
+    {},
+    true
+] call CBA_fnc_addSetting;

addons/sys_gestures/stringtable.xml

@@ -46,5 +46,15 @@
             <Turkish>Telsiz kullanırken nişan almayı engeller</Turkish>
             <Portuguese>Usar rádios irá impedir a mira</Portuguese>
         </Key>
+        <Key ID="STR_ACRE_sys_gestures_showConnectorRopes">
+            <English>Show connector wires</English>
+            <German>Zeige verbindungskabel</German>
+            <Italian>Mostra cavi di collegamento</Italian>
+        </Key>
+        <Key ID="STR_ACRE_sys_gestures_showConnectorRopes_description">
+            <English>Connections to infantry phones, GSAs and shared radios will be visualized with connector wires.</English>
+            <German>Verbindungen zu Gegensprechanlage, BBA und Geteilten Funkgeräten werden mit Kabeln visualisiert.</German>
+            <Italian>Connessioni a telefoni di fanteria, antenne a pavimento e radio condivise verranno visualizzate con cavi.</Italian>
+        </Key>
     </Package>
 </Project>

addons/sys_gsa/fnc_connectServer.sqf

@@ -38,6 +38,7 @@ _gsa setVariable [QGVAR(connectedRadio), _radioId, true];
 [_radioId, "setState", ["externalAntennaConnected", [true, _gsa]]] call EFUNC(sys_data,dataEvent);
 
 [QGVAR(notifyPlayer), [localize LSTRING(connected)], _player] call CBA_fnc_targetEvent;
+[QEGVAR(sys_core,handleConnectorRopeEvent), [true, 1, _gsa, _player], _player] call CBA_fnc_targetEvent;
 
 // Support for having several radios connected to GSA
 private _pfh = [DFUNC(externalAntennaPFH), 1.0, [_gsa, _radioId]] call CBA_fnc_addPerFrameHandler;

addons/sys_gsa/fnc_disconnectServer.sqf

@@ -60,9 +60,11 @@ private _parentComponentClass = configFile >> "CfgAcreComponents" >> BASE_CLASS_
             if (_connectedUnit isKindOf "CAManBase" || {crew _connectedUnit isNotEqualTo []}) then {
                 if (_connectedUnit isKindOf "CAManBase") then {
                     [QGVAR(notifyPlayer), [localize LSTRING(disconnected)], _connectedUnit] call CBA_fnc_targetEvent;
+                    [QEGVAR(sys_core,handleConnectorRopeEvent), [false], _connectedUnit] call CBA_fnc_targetEvent;
                 } else {
                     {
                         [QGVAR(notifyPlayer), [localize LSTRING(disconnected)], _connectedUnit] call CBA_fnc_targetEvent;
+                        [QEGVAR(sys_core,handleConnectorRopeEvent), [false], _connectedUnit] call CBA_fnc_targetEvent;
                     } forEach (crew _connectedUnit);
                 };
             };
@@ -71,6 +73,7 @@ private _parentComponentClass = configFile >> "CfgAcreComponents" >> BASE_CLASS_
                 // The unit that disconnected the antenna is different from the unit that was connected to it
                 private _text = format [localize LSTRING(disconnectedUnit), name _connectedUnit];
                 [QGVAR(notifyPlayer), [_text], _unit] call CBA_fnc_targetEvent;
+                [QEGVAR(sys_core,handleConnectorRopeEvent), [false], _unit] call CBA_fnc_targetEvent;
             };
         };
     };

addons/sys_gsa/fnc_externalAntennaPFH.sqf

@@ -35,4 +35,5 @@ if (
 || {(_unit distance _gsa) > ANTENNA_MAXDISTANCE}
 ) then {
     [QGVAR(disconnectGsa), [_gsa, _unit, _radioId]] call CBA_fnc_localEvent;
+    [QEGVAR(sys_core,handleConnectorRopeEvent), [false]] call CBA_fnc_localEvent;
 };

addons/sys_gsa/fnc_handleMast.sqf

@@ -21,9 +21,11 @@ if (_connectedRadio isEqualTo "") then {
     _connectedRadio = _gsa getVariable [QGVAR(connectedRadio), ""];
 };
 
+private _connectedPlayer = [_connectedRadio] call EFUNC(sys_radio,getRadioObject);
+
 // Temporarily disconnect the GSA from the radio
 if (_connectedRadio != "") then {
-    [_player, _gsa] call FUNC(disconnect);
+    [_connectedPlayer, _gsa] call FUNC(disconnect);
 };
 
 // Delete the antenna
@@ -43,5 +45,5 @@ if (_mountMast) then {
 
 // Reconnect the GSA to the radio
 if (_connectedRadio != "") then {
-    [_gsa, _connectedRadio] call FUNC(connect);
+    [QGVAR(connectGsa), [_gsa, _connectedRadio, _connectedPlayer]] call CBA_fnc_serverEvent;
 };

addons/sys_intercom/XEH_postInit.sqf

@@ -69,9 +69,9 @@ if (!hasInterface) exitWith {};
 }, true] call CBA_fnc_addPlayerEventHandler;
 
 [QGVAR(giveInfantryPhone), {
-    params ["_vehicle", "_unit", "_action", "_message", ["_intercomNetwork", INTERCOM_DISCONNECTED]];
+    params ["_vehicle", "_unit", "_action", "_message", ["_intercomNetwork", INTERCOM_DISCONNECTED], ["_position", objNull]];
     [[ICON_RADIO_CALL], [_message]] call CBA_fnc_notify;
-    [_vehicle, _unit, _action, _intercomNetwork] call FUNC(updateInfantryPhoneStatus);
+    [_vehicle, _unit, _action, _intercomNetwork, objNull, _position] call FUNC(updateInfantryPhoneStatus);
 }] call CBA_fnc_addEventHandler;
 
 #ifdef DRAW_INFANTRYPHONE_INFO

addons/sys_intercom/fnc_infantryPhoneChildrenActions.sqf

@@ -15,11 +15,12 @@
  * Public: No
  */
 
-params ["_target"];
+params ["_target", "_unit", "_position"];
 
 private _actions = [];
 
 (acre_player getVariable [QGVAR(vehicleInfantryPhone), [objNull, INTERCOM_DISCONNECTED]]) params ["_vehicleInfantryPhone", "_infantryPhoneNetwork"];
+(_target getVariable [QGVAR(unitInfantryPhone), [objNull, INTERCOM_DISCONNECTED]]) params ["_unitInfantryPhone", "_unitInfantryPhoneNetwork"];
 
 private _intercomNames = _target getVariable [QGVAR(intercomNames), []];
 
@@ -36,7 +37,7 @@ if (_target isKindOf "CAManBase") then {
                 _params params ["_intercomNetwork"];
 
                 //USES_VARIABLES ["_target", "_player"];
-                [_player getVariable [QGVAR(vehicleInfantryPhone), [objNull, INTERCOM_DISCONNECTED]] select 0, _target, 2, _intercomNetwork, _player] call FUNC(updateInfantryPhoneStatus)
+                [_player getVariable [QGVAR(vehicleInfantryPhone), [objNull, INTERCOM_DISCONNECTED]] select 0, _target, 2, _intercomNetwork, _player, _position] call FUNC(updateInfantryPhoneStatus)
             },
             {true},
             {},
@@ -47,16 +48,16 @@ if (_target isKindOf "CAManBase") then {
 } else {
     if (vehicle acre_player != _target) then {
         // Pointing at a vehicle. Get or return the infantry telephone
-        if (isNull _vehicleInfantryPhone) then {
+        if (isNull _vehicleInfantryPhone && (isNull _unitInfantryPhone)) then {
             {
                 private _action = [
                     format [QGVAR(takeInfantryPhone_%1), _x],
                     format [localize LSTRING(takeInfantryPhone), format ["(%1)", (_intercomNames select _forEachIndex) select 2]],
                     "",
                     {
                         params ["_target", "_player", "_params"];
-                        _params params ["_intercomNetwork"];
-                        [_target, _player, 1, _intercomNetwork] call FUNC(updateInfantryPhoneStatus)
+                        _params params ["_intercomNetwork", "_position"];
+                        [_target, _player, 1, _intercomNetwork, objNull, _position] call FUNC(updateInfantryPhoneStatus);
                     },
                     {
                         params ["_target", "_player", "_params"];
@@ -65,7 +66,7 @@ if (_target isKindOf "CAManBase") then {
                         !(_isCalling select 0) || ((_isCalling select 0) && ((_isCalling select 1) == _intercomNetwork))
                     },
                     {},
-                    _forEachIndex
+                    [_forEachIndex, _position]
                 ] call ace_interact_menu_fnc_createAction;
                 _actions pushBack [_action, [], _target];
             } forEach (_intercomNames select {_x in (_target getVariable [QGVAR(infantryPhoneIntercom), []])});
@@ -79,7 +80,7 @@ if (_target isKindOf "CAManBase") then {
                     {
                         params ["_target", "_player", ""];
                         //USES_VARIABLES ["_target", "_player"];
-                        [_target, _player, 0, INTERCOM_DISCONNECTED] call FUNC(updateInfantryPhoneStatus)
+                        [_target, _player, 0, INTERCOM_DISCONNECTED] call FUNC(updateInfantryPhoneStatus);
                     },
                     {true},
                     {},
@@ -111,6 +112,18 @@ if (_target isKindOf "CAManBase") then {
                     ] call ace_interact_menu_fnc_createAction;
                     _actions pushBack [_action, [], _target];
                 } forEach (_intercomNames select {_x in (_target getVariable [QGVAR(infantryPhoneIntercom), []])});
+            } else {
+                // Generate empty action to show that the infantry phone is being used by someone else
+                private _action = [
+                    QGVAR(infantryPhoneUnavailable),
+                    format [localize LSTRING(infantryPhoneUnavailable)],
+                    "",
+                    {true},
+                    {true},
+                    {},
+                    {}
+                ] call ace_interact_menu_fnc_createAction;
+                _actions pushBack [_action, [], _target];
             };
         };
     } else {