init version

.github/workflows/build-workflow.yml

@@ -0,0 +1,40 @@
+name: build and test
+run-name: build and test
+on:
+  push:
+    branches:
+      - main
+  pull_request:
+jobs:
+  test:
+    runs-on: ubuntu-latest
+    strategy:
+      fail-fast: false
+      matrix:
+        perl-version:
+          - '5.38'
+          - '5.36'
+          - '5.34'
+          - '5.32'
+          - '5.30'
+
+    container:
+      image: perldocker/perl-tester:${{ matrix.perl-version }}
+
+    steps:
+      - uses: actions/checkout@main
+      - run: perl -V
+      - run: |
+          cpm install -g --no-test Dist::Zilla Dist::Zilla::App::Command::cover ExtUtils::MakeMaker
+        name: Install Dzil
+      - name: Install dzil author dependencies
+        run: |
+            cpm install --no-test -g \
+            -w 2 \
+            --mirror=http://cpan.cpantesters.org/ $(dzil authordeps --missing)
+      - name: Install dist deps
+        run: |
+          cpanm -n --installdeps .
+          dzil listdeps --author --missing --cpanm-versions | xargs cpanm -n
+
+      - run: dzil smoke --release --author && dzil cover -test -report codecov && dzil xtest

.gitignore

@@ -0,0 +1,24 @@
+docker-compose.yml
+
+id_dsa
+id_rsa
+/blib/
+/.build/
+_build/
+cover_db/
+inc/
+Build
+!Build/
+Build.bat
+.last_cover_stats
+/Makefile
+/Makefile.old
+/MANIFEST.bak
+/META.yml
+/META.json
+/MYMETA.*
+nytprof.out
+/pm_to_blib
+*.o
+*.bs
+*.swp

Changes

@@ -0,0 +1,7 @@
+{{$NEXT}}
+  - Initial release
+  - load features
+  - get feature value
+  - is_on
+  - is_off
+

README.md

@@ -1 +1,72 @@
-# WebService-GrowthBook
+# NAME
+
+WebService::GrowthBook - sdk of growthbook
+
+# SYNOPSIS
+
+    use WebService::GrowthBook;
+    my $instance = WebService::GrowthBook->new(client_key => 'my key');
+    $instance->load_features;
+    if($instance->is_on('feature_name')){
+        # do something
+    }
+    else {
+        # do something else
+    }
+    my $string_feature = $instance->get_feature_value('string_feature');
+    my $number_feature = $instance->get_feature_value('number_feature');
+    # get decoded json
+    my $json_feature = $instance->get_feature_value('json_feature');
+
+# DESCRIPTION
+
+    This module is a sdk of growthbook, it provides a simple way to use growthbook features.
+
+# METHODS
+
+## load\_features
+
+load features from growthbook API
+
+    $instance->load_features;
+
+## is\_on
+
+check if a feature is on
+
+    $instance->is_on('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+## is\_off
+
+check if a feature is off
+
+    $instance->is_off('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+## get\_feature\_value
+
+get the value of a feature
+
+    $instance->get_feature_value('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+## set\_features
+
+set features
+
+    $instance->set_features($features);
+
+## eval\_feature
+
+evaluate a feature to get the value
+
+    $instance->eval_feature('feature_name');
+
+# SEE ALSO
+
+- [https://docs.growthbook.io/](https://docs.growthbook.io/)
+- [PYTHON VERSION](https://github.com/growthbook/growthbook-python)

cpanfile

@@ -0,0 +1,21 @@
+requires 'indirect',    '>= 0.37';
+requires 'Object::Pad', '>= 0.805';
+requires 'JSON::MaybeUTF8';
+requires 'Scalar::Util';
+requires 'HTTP::Tiny';
+requires 'Log::Any';
+requires 'Syntax::Keyword::Try';
+
+
+on test => sub {
+    requires 'Test::More', '>= 0.98';
+    requires 'Test::Exception';
+    requires 'Test::MockModule';
+    requires 'Path::Tiny';
+    requires 'FindBin';
+};
+
+on develop => sub {
+    requires 'Devel::Cover', '>= 1.23';
+    requires 'Devel::Cover::Report::Codecov', '>= 0.14';
+};

dist.ini

@@ -0,0 +1,12 @@
+name    = WebService-GrowthBook
+author  = DERIV <[email protected]>
+license = Perl_5
+copyright_holder = Deriv Services Ltd
+copyright_year   = 2022
+
+[@Author::DERIV]
+allow_dirty = lib/WebService/GrowthBook.pm
+[PerlTidy]
+perltidyrc = t/rc/perltidyrc
+[Test::Perl::Critic]
+critic_config = t/rc/perlcriticrc

examples/feature.pl

@@ -0,0 +1,14 @@
+use strict;
+use warnings;
+use WebService::GrowthBook;
+use WebService::GrowthBook::FeatureRepository;
+use Data::Dumper;
+use Log::Any::Adapter qw(Stdout);
+
+my $key = $ENV{GROWTHBOOK_KEY};
+my $gb = WebService::GrowthBook->new(client_key => $key);
+$gb->load_features();
+print "bool feature is on:", $gb->is_on('bool-feature'), "\n";
+print "string feature:", $gb->get_feature_value('string-feature'),"\n";
+print "number feature:", $gb->get_feature_value('number-feature'),"\n";
+print "json feature:", Dumper($gb->get_feature_value('json-feature')),"\n";

lib/WebService/GrowthBook.pm

@@ -0,0 +1,174 @@
+package WebService::GrowthBook;
+# ABSTRACT: ...
+
+use strict;
+use warnings;
+no indirect;
+use feature qw(state);
+use Object::Pad;
+use JSON::MaybeUTF8 qw(decode_json_text);
+use Scalar::Util qw(blessed);
+use Log::Any qw($log);
+use WebService::GrowthBook::FeatureRepository;
+use WebService::GrowthBook::Feature;
+use WebService::GrowthBook::FeatureResult;
+use WebService::GrowthBook::InMemoryFeatureCache;
+
+our $VERSION = '0.001';
+
+=head1 NAME
+
+WebService::GrowthBook - sdk of growthbook
+
+=head1 SYNOPSIS
+
+    use WebService::GrowthBook;
+    my $instance = WebService::GrowthBook->new(client_key => 'my key');
+    $instance->load_features;
+    if($instance->is_on('feature_name')){
+        # do something
+    }
+    else {
+        # do something else
+    }
+    my $string_feature = $instance->get_feature_value('string_feature');
+    my $number_feature = $instance->get_feature_value('number_feature');
+    # get decoded json
+    my $json_feature = $instance->get_feature_value('json_feature');
+
+=head1 DESCRIPTION
+
+    This module is a sdk of growthbook, it provides a simple way to use growthbook features.
+
+=cut
+
+# singletons
+
+class WebService::GrowthBook {
+    field $url :param //= 'https://api.growthbook.io/api/v1';
+    field $client_key :param //= '';
+    field $features :param //= {};
+    field $cache_ttl :param //= 60;
+    field $cache //= WebService::GrowthBook::InMemoryFeatureCache->singleton;
+    method load_features {
+        if(!$client_key) {
+            die "Must specify 'client_key' to refresh features";
+        }
+        my $feature_repository = WebService::GrowthBook::FeatureRepository->new(cache => $cache);
+        my $loaded_features = $feature_repository->load_features($url, $client_key, $cache_ttl);
+        if($loaded_features){
+            $self->set_features($loaded_features);
+        }
+        return 1;
+    }
+    method set_features($features_set) {
+        $features = {};
+        for my $feature ($features_set->@*) {
+            if(blessed($feature) && $feature->isa('WebService::GrowthBook::Feature')){
+                $features->{$feature->id} = $feature;
+            }
+            else {
+                $features->{$feature->{id}} = WebService::GrowthBook::Feature->new(id => $feature->{id}, default_value => $feature->{defaultValue}, value_type => $feature->{valueType});
+            }
+        }
+    }
+
+    method is_on($feature_name) {
+        my $result = $self->eval_feature($feature_name);
+        return undef unless defined($result);
+        return $result->on;
+    }
+
+    method is_off($feature_name) {
+        my $result = $self->eval_feature($feature_name);
+        return undef unless defined($result);
+        return $result->off;
+    }
+
+    method eval_feature($feature_name){
+        if(!exists($features->{$feature_name})){
+            $log->errorf("No such feature: %s", $feature_name);
+            return undef;
+        }
+        my $feature = $features->{$feature_name};
+        my $default_value = $feature->default_value;
+        if($feature->value_type eq 'json'){
+            $default_value = decode_json_text($default_value);
+        }
+        elsif($feature->value_type eq 'number'){
+            $default_value = 0 + $default_value;
+        }
+        elsif($feature->value_type eq 'boolean'){
+            $default_value = $default_value eq 'true' ? 1 : 0;
+        }
+
+        return WebService::GrowthBook::FeatureResult->new(
+            value => $default_value);
+    }
+
+    method get_feature_value($feature_name){
+        my $result = $self->eval_feature($feature_name);
+        return undef unless defined($result);
+        return $result->value;
+    }
+}
+
+=head1 METHODS
+
+=head2 load_features
+
+load features from growthbook API
+
+    $instance->load_features;
+
+=head2 is_on
+
+check if a feature is on
+
+    $instance->is_on('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+=head2 is_off
+
+check if a feature is off
+
+    $instance->is_off('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+=head2 get_feature_value
+
+get the value of a feature
+
+    $instance->get_feature_value('feature_name');
+
+Please note it will return undef if the feature does not exist.
+
+=head2 set_features
+
+set features
+
+    $instance->set_features($features);
+
+=head2 eval_feature
+
+evaluate a feature to get the value
+
+    $instance->eval_feature('feature_name');
+
+=cut
+
+1;
+
+
+=head1 SEE ALSO
+
+=over 4
+
+=item * L<https://docs.growthbook.io/>
+
+=item * L<PYTHON VERSION|https://github.com/growthbook/growthbook-python>
+
+=back
+