Port build to Meson

.github/workflows/test.yml

@@ -16,37 +16,36 @@ jobs:
           apt-get upgrade -y
           apt-get build-dep -y xdg-desktop-portal-gtk
           apt-get build-dep -y xdg-desktop-portal
-          apt-get install -y git libfuse3-dev
+          apt-get install -y git gsettings-desktop-schemas-dev libfuse3-dev libgnome-desktop-3-dev meson ninja-build
 
       # Build from git so we can test against the newest portals
       - name: Build xdg-desktop-portal dependency
         run: |
-          git clone -b 1.14.0 https://github.com/flatpak/xdg-desktop-portal.git ./xdg-desktop-portal
+          git clone -b 1.18.0 https://github.com/flatpak/xdg-desktop-portal.git ./xdg-desktop-portal
           cd ./xdg-desktop-portal
-          ./autogen.sh --sysconfdir=/etc --disable-dependency-tracking --disable-libportal
-          make -j $(getconf _NPROCESSORS_ONLN)
-          make install
+          meson setup -Dsysconfdir=/etc -Dprefix=/usr -Dlibportal=disabled _build .
+          meson compile -C _build
+          meson install -C _build
           cd ..
 
       - uses: actions/checkout@v4
 
       - name: Configure
-        run: ./autogen.sh --disable-dependency-tracking
+        run: meson setup -Dsysconfdir=/etc -Dprefix=/usr _build .
 
       - name: Build
-        run: make -j $(getconf _NPROCESSORS_ONLN)
+        run: meson compile -C _build
 
       - name: Check
-        run: make check -j $(getconf _NPROCESSORS_ONLN)
+        run: meson test -C _build
 
       - name: Install
-        run: make install
+        run: meson install -C _build
 
       - name: Upload test logs
         uses: actions/upload-artifact@v3
         if: failure() || cancelled()
         with:
           name: test logs
           path: |
-            tests/*.log
-            test-suite.log
+            _build/meson-logs/*

data/meson.build

@@ -0,0 +1,96 @@
+portal_dbus_interfaces = [
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Request.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Session.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.FileChooser.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Print.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Notification.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Inhibit.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Access.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Account.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Email.xml',
+  desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.DynamicLauncher.xml',
+]
+
+fdo_dbus_interfaces = files(
+  'org.freedesktop.ScreenSaver.xml',
+  'org.freedesktop.Accounts.xml',
+  'org.freedesktop.Accounts.User.xml',
+)
+
+gtk_dbus_interfaces = files('org.gtk.Notifications.xml')
+
+gnome_dbus_interfaces = files(
+  'org.gnome.SessionManager.xml',
+  'org.gnome.ScreenSaver.xml',
+)
+
+gtk_portal = configuration_data()
+
+if get_option('wallpaper').allowed()
+  portal_dbus_interfaces += desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Wallpaper.xml'
+  gtk_portal.set('wallpaper_iface', 'org.freedesktop.impl.portal.Wallpaper;')
+else
+  gtk_portal.set('wallpaper_iface', '')
+endif
+
+if get_option('settings').allowed()
+  portal_dbus_interfaces += desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Settings.xml'
+  gtk_portal.set('settings_iface', 'org.freedesktop.impl.portal.Settings;')
+else
+  gtk_portal.set('settings_iface', '')
+endif
+
+if get_option('appchooser').allowed()
+  portal_dbus_interfaces += desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.AppChooser.xml'
+  gtk_portal.set('appchooser_iface', 'org.freedesktop.impl.portal.AppChooser;')
+else
+  gtk_portal.set('appchooser_iface', '')
+endif
+
+if get_option('lockdown').allowed()
+  portal_dbus_interfaces += desktop_portal_interfaces_dir / 'org.freedesktop.impl.portal.Lockdown.xml'
+  gtk_portal.set('lockdown_iface', 'org.freedesktop.impl.portal.Lockdown;')
+else
+  gtk_portal.set('lockdown_iface', '')
+endif
+
+configure_file(
+  input: 'gtk.portal.in',
+  output: 'gtk.portal',
+  configuration: gtk_portal,
+  install: true,
+  install_dir: datadir / 'xdg-desktop-portal/portals',
+)
+
+service_conf = configuration_data()
+service_conf.set('libexecdir', libexecdir)
+configure_file(
+  input: 'org.freedesktop.impl.portal.desktop.gtk.service.in',
+  output: 'org.freedesktop.impl.portal.desktop.gtk.service',
+  configuration: service_conf,
+  install: true,
+  install_dir: dbus_service_dir,
+)
+configure_file(
+  input: 'xdg-desktop-portal-gtk.service.in',
+  output: 'xdg-desktop-portal-gtk.service',
+  configuration: service_conf,
+  install: true,
+  install_dir: systemd_userunit_dir,
+)
+
+desktop_conf = configuration_data()
+desktop_conf.set('libexecdir', libexecdir)
+i18n.merge_file(
+  type: 'desktop',
+  input: configure_file(
+    input: 'xdg-desktop-portal-gtk.desktop.in.in',
+    output: 'xdg-desktop-portal-gtk.desktop.in',
+    configuration: desktop_conf,
+  ),
+  output: 'xdg-desktop-portal-gtk.desktop',
+  po_dir: '../po',
+  install: true,
+  install_dir: datadir / 'applications',
+)
+