Looting rewrite #120
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| Original file line number | Diff line number | Diff line change |
|---|---|---|
| @@ -1,131 +1,199 @@ | ||
| private _selectedUnits = groupSelectedUnits player; | ||
| { | ||
| player groupSelectUnit [_x, false]; | ||
| } forEach (_selectedUnits); | ||
|
|
||
| // If at least one selected unit is a driver of a recovery truck, do truck recovery instead | ||
| private _unitInRecoveryTruck = _selectedUnits findIf {objectParent _x isKindOf "OT_I_Truck_recovery" && driver objectParent _x isEqualTo _x}; | ||
| if (_unitInRecoveryTruck > -1) exitWith { | ||
| [_selectedUnits # _unitInRecoveryTruck] spawn OT_fnc_recover; | ||
| }; | ||
|
|
||
| private _sortedTargets = nearestObjects [_selectedUnits # 0, ["Car", "ReammoBox_F", "Air", "Ship"], 20] select {alive _x}; | ||
| if (count _sortedTargets isEqualTo 0) exitWith { | ||
| "Cannot find any containers or vehicles within 20m of first selected unit" call OT_fnc_notifyMinor; | ||
| }; | ||
| private _target = _sortedTargets # 0; | ||
|
|
||
| { | ||
| [_x, _target] spawn { | ||
| params ["_looter", "_target"]; | ||
|
|
||
| private _range = 100; | ||
|
|
||
| _looter globalChat format["Looting bodies and item piles within %1m into the %2", _range, (typeOf _target) call OT_fnc_vehicleGetName]; | ||
|
|
||
| _looter setBehaviour "SAFE"; | ||
| if (!isNull objectParent _looter) then { | ||
| doGetOut _looter; | ||
| waitUntil {sleep 1; (isNull objectParent _looter) || (!alive _looter)}; | ||
| }; | ||
|
|
||
| _looter doMove ASLtoAGL (getPosASL _target); | ||
|
|
||
| // Wait until looter reaches the target container | ||
| private _timeout = time + 30; | ||
| waitUntil {sleep 1; (_looter distance _target < 12) || (!alive _looter) || (!alive _target) || (_timeout < time)}; | ||
| if ((!alive _looter) || (!alive _target) || (_timeout < time)) exitWith { | ||
| if (alive _looter) then {_looter globalChat format ["Can't get to the %1, cancelling loot order", (typeOf _target) call OT_fnc_vehicleGetName]}; | ||
| }; | ||
|
|
||
| // Looter has reached the target container. Dump his loadout to it. | ||
| if !([_looter, _target] call OT_fnc_canDumpUnitLoadout) exitWith { | ||
| _looter globalChat "This vehicle is full, cancelling loot order"; | ||
| }; | ||
|
|
||
| private _looterOwnUniform = uniform _looter; | ||
|
|
||
| [_looter, _target] call OT_fnc_dumpUnitLoadout; | ||
| _looter setUnitLoadout [[], [], [], [_looterOwnUniform, []], [], [], "", "", [], ["", "", "", "", "", ""]]; | ||
|
|
||
| while {true} do { | ||
| private _sortedBodies = []; | ||
| { | ||
| // Some bodies are inside vehicles, so we search through the crew of every vehicle | ||
| // we find. Luckily every man is crew of itself so the same code also works for | ||
| // bodies on the ground. | ||
| private _vehicleOrMan = _x; | ||
| { | ||
| private _body = _x; | ||
| if (!alive _body && !(_body getVariable ["OT_looterReserved", false])) then { | ||
| _sortedBodies pushBack _x; | ||
| }; | ||
| } forEach crew _vehicleOrMan; | ||
| } forEach (nearestObjects [_target, ["AllVehicles"], _range]); | ||
|
|
||
| if (_sortedBodies isNotEqualTo []) then { | ||
| // There are bodies to be looted. Loot the nearest body. | ||
|
|
||
| _looter globalChat format ["%1 bodies to loot", count _sortedBodies]; | ||
| private _body = _sortedBodies # 0; | ||
|
|
||
| _body setVariable ["OT_looterReserved", true, false]; | ||
| _looter doMove ASLtoAGL (getPosASL _body); | ||
| [_looter, 1] call OT_fnc_experience; | ||
|
|
||
| // Wait until looter reaches the body | ||
| _timeout = time + 30; | ||
| waitUntil {sleep 1; (_looter distance2D _body < 12) || (isNull _body) || (!alive _looter) || (!alive _target) || (_timeout < time)}; | ||
|
There was a problem hiding this comment.
There was a problem hiding this comment. Seems reasonable. The timeout may not be needed if moveToCompleted always returns true when moving fails. |
||
| if ((!alive _looter) || (!alive _target) || (_timeout < time)) then { | ||
| if (alive _looter) then {_looter globalChat "Can't get to a body, cancelling loot order"}; | ||
| _body setVariable ["OT_looterReserved", false, false]; | ||
| break; | ||
| }; | ||
| if (isNull _body) then { | ||
| _looter globalChat "Body has vanished, skipping"; | ||
| continue; | ||
| }; | ||
|
|
||
| // Looter has reached the body. Transfer its loadout to the looter. | ||
| private _lootedLoadout = getUnitLoadout _body; | ||
|
|
||
| // If the looter has his own uniform, keep it. | ||
| if (_looterOwnUniform isNotEqualTo "") then { | ||
| private _bodyUniformContent = _lootedLoadout # 3 param [1, []]; | ||
| _lootedLoadout set [3, [_looterOwnUniform, _bodyUniformContent]]; | ||
| }; | ||
|
|
||
| // Also take the dropped weapons belonging to the body. The body may have dropped | ||
| // its weapons outside of the search range and they would get deleted when the body | ||
| // is deleted, so search for dropped weapons 10m further than bodies. It is still | ||
| // possible that the weapon has flown more than 10m outside the range, in which case | ||
| // it is lost. This code can be simplified in Arma 3 version 2.18 with the new | ||
| // command getCorpseWeaponholders. | ||
| // https://community.bistudio.com/wiki/getCorpseWeaponholders | ||
| private _droppedWeaponHolders = (_target nearEntities ["WeaponHolderSimulated", (_range + 10)]); | ||
| { | ||
| if (getCorpse _x isEqualTo _body) then { | ||
| private _weapon = weaponsItemsCargo _x # 0; | ||
| if (_weapon # 0 isKindOf ["Launcher", configFile >> "CfgWeapons"]) then { | ||
| _lootedLoadout set [1, _weapon]; | ||
| } else { | ||
| _lootedLoadout set [0, _weapon]; | ||
| }; | ||
| }; | ||
| } forEach _droppedWeaponHolders; | ||
|
|
||
| _looter setUnitLoadout _lootedLoadout; | ||
| [_body] call OT_fnc_cleanupUnit; | ||
|
|
||
| sleep 2; | ||
|
There was a problem hiding this comment. Why wait 2 seconds here, the unit could already start running. In my opinion the looter should be almost constantly moving, small stops are ok but 2 seconds is too long in my opinion. There was a problem hiding this comment. This is not my code so I don't know the original idea, but I think it's meant to simulate the looter spending time to pick up the items. |
||
| _looter doMove ASLtoAGL (getPosASL _target); | ||
|
|
||
| // Wait until looter reaches the target container | ||
| _timeout = time + 30; | ||
| waitUntil {sleep 1; (_looter distance _target < 12) || (!alive _looter) || (!alive _target) || (_timeout < time)}; | ||
| if ((!alive _looter) || (!alive _target) || (_timeout < time)) then { | ||
| if (alive _looter) then {_looter globalChat format ["Can't get back to the %1, cancelling loot order", (typeOf _target) call OT_fnc_vehicleGetName]}; | ||
| break; | ||
| }; | ||
|
|
||
| // Looter has reached the target container. Dump his loadout to it. | ||
| if !([_looter, _target] call OT_fnc_canDumpUnitLoadout) then { | ||
| _looter globalChat "This vehicle is full, cancelling loot order"; | ||
| break; | ||
| }; | ||
|
|
||
| [_looter, _target] call OT_fnc_dumpUnitLoadout; | ||
| _looter setUnitLoadout [[], [], [], [_looterOwnUniform, []], [], [], "", "", [], ["", "", "", "", "", ""]]; | ||
| } else { | ||
| // There are no longer any bodies to loot. Loot the nearest item pile. | ||
|
|
||
| private _sortedWeaponHolders = nearestObjects [_target, ["WeaponHolder", "WeaponHolderSimulated"], _range] select {!(_x getVariable ["OT_looterReserved", false])}; | ||
|
|
||
| if (_sortedWeaponHolders isEqualTo []) then { | ||
| _looter globalChat "All done!"; | ||
| break; | ||
| }; | ||
|
|
||
| _looter globalChat format ["%1 item piles to loot", count _sortedWeaponHolders]; | ||
| private _weaponHolder = _sortedWeaponHolders # 0; | ||
|
|
||
| _weaponHolder setVariable ["OT_looterReserved", true, false]; | ||
| _looter doMove ASLtoAGL (getPosASL _weaponHolder); | ||
| [_looter, 1] call OT_fnc_experience; | ||
|
|
||
| // Wait until looter reaches the item pile | ||
| _timeout = time + 30; | ||
| waitUntil {sleep 1; (_looter distance2D _weaponHolder < 12) || (isNull _weaponHolder) || (!alive _looter) || (!alive _target) || (_timeout < time)}; | ||
| if ((!alive _looter) || (!alive _target) || (_timeout < time)) then { | ||
| if (alive _looter) then {_looter globalChat "Can't get to an item pile, cancelling loot order"}; | ||
| _weaponHolder setVariable ["OT_looterReserved", false, false]; | ||
| break; | ||
| }; | ||
|
|
||
| // Looter has reached the item pile. Its contents may not fit in the looter's | ||
| // inventory, so fake the looting trip by running back empty handed and dumping the | ||
| // contents directly to the target container once there. | ||
|
|
||
| sleep 2; | ||
| _looter doMove ASLtoAGL (getPosASL _target); | ||
|
|
||
| // Wait until looter reaches the target container | ||
| _timeout = time + 30; | ||
| waitUntil {sleep 1; (_looter distance _target < 12) || (isNull _weaponHolder) || (!alive _looter) || (!alive _target) || (_timeout < time)}; | ||
| if ((!alive _looter) || (!alive _target) || (_timeout < time)) then { | ||
| if (alive _looter) then {_looter globalChat format ["Can't get back to the %1, cancelling loot order", (typeOf _target) call OT_fnc_vehicleGetName]}; | ||
| _weaponHolder setVariable ["OT_looterReserved", false, false]; | ||
| break; | ||
| }; | ||
| if (isNull _weaponHolder) then { | ||
| _looter globalChat "Item pile has vanished, skipping"; | ||
| continue; | ||
| }; | ||
|
|
||
| // Looter has reached the target container. | ||
| if !([_weaponHolder, _target] call OT_fnc_canDumpContainer) then { | ||
| _looter globalChat "This vehicle is full, cancelling loot order"; | ||
| _weaponHolder setVariable ["OT_looterReserved", false, false]; | ||
| break; | ||
| }; | ||
|
|
||
| [_weaponHolder, _target] call OT_fnc_dumpContainer; | ||
| deleteVehicle _weaponHolder; | ||
| }; | ||
|
|
||
| sleep 1; | ||
| }; | ||
| }; | ||
| } forEach (_selectedUnits); | ||
Oops, something went wrong.
Add this suggestion to a batch that can be applied as a single commit.
This suggestion is invalid because no changes were made to the code.
Suggestions cannot be applied while the pull request is closed.
Suggestions cannot be applied while viewing a subset of changes.
Only one suggestion per line can be applied in a batch.
Add this suggestion to a batch that can be applied as a single commit.
Applying suggestions on deleted lines is not supported.
You must change the existing code in this line in order to create a valid suggestion.
Outdated suggestions cannot be applied.
This suggestion has been applied or marked resolved.
Suggestions cannot be applied from pending reviews.
Suggestions cannot be applied on multi-line comments.
Suggestions cannot be applied while the pull request is queued to merge.
Suggestion cannot be applied right now. Please check back later.
There was a problem hiding this comment.
Choose a reason for hiding this comment
The reason will be displayed to describe this comment to others. Learn more.
We might want to experiment with using
moveTorather thandoMove. I believe that withmoveTothe unit will attempt to return to formation automatically after moving (or failing to move), whereas withdoMovethe unit must be explicitly ordered to return. Read notes on the biki page fordoMovefor more info.There was a problem hiding this comment.
Choose a reason for hiding this comment
The reason will be displayed to describe this comment to others. Learn more.
This is not my code so I don't know the original idea, but is the looter supposed to return to formation after moving? Now it stays wherever it was ordered to go in "ready" state. Both results make sense.